Shocking The Web CD-ROM/SHOCK_CD.ISO/pc/tutorial/casestdy/ch11_sfx/esnavbar.dir/00002.ls

Text File | 1996-11-12 | 1.7 KB | 77 lines

on localInit
  global gBaseURL, gNextPage
  repeat with i = 16 to 19
    set the visible of sprite i to 0
  end repeat
  repeat with i = 22 to 33
    set the visible of sprite i to 0
  end repeat
  set gNextPage to EMPTY
end

on enterFrame
  checkRollovers()
end

on checkRollovers
  global gLastRollTime, gLastRollover, gBubbleSprite, gBubble
  repeat with i = 6 to 9
    if rollOver(i) and the visible of sprite i then
      if i = gLastRollover then
        if the mouseUp and ((gLastRollTime + 50) < the timer) and not gBubble then
          set gLastRollTime to 0
          puppetSound("switches1")
          set gBubbleSprite to 22 + ((i - 6) * 3)
          doBubbles(1, gBubbleSprite)
        end if
        exit
      else
        if gBubble then
          doBubbles(0, gBubbleSprite)
        end if
        set gLastRollTime to the timer
      end if
      set gLastRollover to i
      exit
    end if
  end repeat
  set gLastRollover to 0
  if gBubble then
    doBubbles(0, gBubbleSprite)
  end if
end

on doBubbles op, startSprite
  global gBubble
  repeat with j = startSprite to startSprite + 2
    set the visible of sprite j to op
  end repeat
  updateStage()
  set gBubble to op
end

on hiliteLoc
  global gNextPage
  repeat with i = 6 to 9
    if gNextPage contains the name of cast the castNum of sprite i then
      set the visible of sprite (i + 10) to 1
      next repeat
    end if
    set the visible of sprite (i + 10) to 0
  end repeat
end

on setBGColor
  set theLabel to getCurrLabel()
  if theLabel contains "about" then
    set bgColor to 0
  else
    if theLabel contains "sampl" then
      set bgColor to 157
    else
      set bgColor to 5
    end if
  end if
  set the stageColor to bgColor
end