home *** CD-ROM | disk | FTP | other *** search
/ Quake 'em / QUAKEEM.BIN / quake / programs / relarmor / combat.qc next >
Encoding:
Text File  |  1996-08-29  |  6.6 KB  |  292 lines
  1.  
  2. void() T_MissileTouch;
  3. void() info_player_start;
  4. void(entity targ, entity attacker) ClientObituary;
  5.  
  6. void() monster_death_use;
  7.  
  8. //============================================================================
  9.  
  10. /*
  11. ============
  12. CanDamage
  13.  
  14. Returns true if the inflictor can directly damage the target.  Used for
  15. explosions and melee attacks.
  16. ============
  17. */
  18. float(entity targ, entity inflictor) CanDamage =
  19. {
  20. // bmodels need special checking because their origin is 0,0,0
  21.     if (targ.movetype == MOVETYPE_PUSH)
  22.     {
  23.         traceline(inflictor.origin, 0.5 * (targ.absmin + targ.absmax), TRUE, self);
  24.         if (trace_fraction == 1)
  25.             return TRUE;
  26.         if (trace_ent == targ)
  27.             return TRUE;
  28.         return FALSE;
  29.     }
  30.     
  31.     traceline(inflictor.origin, targ.origin, TRUE, self);
  32.     if (trace_fraction == 1)
  33.         return TRUE;
  34.     traceline(inflictor.origin, targ.origin + '15 15 0', TRUE, self);
  35.     if (trace_fraction == 1)
  36.         return TRUE;
  37.     traceline(inflictor.origin, targ.origin + '-15 -15 0', TRUE, self);
  38.     if (trace_fraction == 1)
  39.         return TRUE;
  40.     traceline(inflictor.origin, targ.origin + '-15 15 0', TRUE, self);
  41.     if (trace_fraction == 1)
  42.         return TRUE;
  43.     traceline(inflictor.origin, targ.origin + '15 -15 0', TRUE, self);
  44.     if (trace_fraction == 1)
  45.         return TRUE;
  46.  
  47.     return FALSE;
  48. };
  49.  
  50.  
  51. /*
  52. ============
  53. Killed
  54. ============
  55. */
  56. void(entity targ, entity attacker) Killed =
  57. {
  58.     local entity oself;
  59.  
  60.     oself = self;
  61.     self = targ;
  62.     
  63.     if (self.health < -99)
  64.         self.health = -99;              // don't let sbar look bad if a player
  65.  
  66.     if (self.movetype == MOVETYPE_PUSH || self.movetype == MOVETYPE_NONE)
  67.     {       // doors, triggers, etc
  68.         self.th_die ();
  69.         self = oself;
  70.         return;
  71.     }
  72.  
  73.     self.enemy = attacker;
  74.  
  75. // bump the monster counter
  76.     if (self.flags & FL_MONSTER)
  77.     {
  78.         killed_monsters = killed_monsters + 1;
  79.         WriteByte (MSG_ALL, SVC_KILLEDMONSTER);
  80.     }
  81.  
  82.     ClientObituary(self, attacker);
  83.     
  84.     self.takedamage = DAMAGE_NO;
  85.     self.touch = SUB_Null;
  86.  
  87.     monster_death_use();
  88.     self.th_die ();
  89.     
  90.     self = oself;
  91. };
  92.  
  93.  
  94. /*
  95. ============
  96. T_Damage
  97.  
  98. The damage is coming from inflictor, but get mad at attacker
  99. This should be the only function that ever reduces health.
  100. ============
  101. */
  102. /* Reptilian: changed part of the system of armor absorption. */
  103.  
  104. void(entity targ, entity inflictor, entity attacker, float damage) T_Damage=
  105. {
  106.     local   vector  dir;
  107.     local   entity  oldself;
  108.     local   float   save;
  109.     local   float   take;
  110.     local   float   peezle;
  111.     local   float   ratspoo;
  112.  
  113.     if (!targ.takedamage)
  114.         return;
  115.  
  116. // used by buttons and triggers to set activator for target firing
  117.     damage_attacker = attacker;
  118.  
  119. // check for quad damage powerup on the attacker
  120.     if (attacker.super_damage_finished > time)
  121.         damage = damage * 4;
  122.  
  123. // save damage based on the target's armor level
  124.     
  125.     peezle = ceil(targ.armorvalue*damage);
  126.     ratspoo = ceil(peezle/100);
  127.     save = ratspoo;
  128.     if (save >= targ.armorvalue)
  129.     {
  130.         save = targ.armorvalue;
  131.         targ.armortype = 0;     // lost all armor
  132.         targ.items = targ.items - (targ.items & (IT_ARMOR1 | IT_ARMOR2 | IT_ARMOR3));
  133.     }
  134.     
  135.     targ.armorvalue = targ.armorvalue - save;
  136.     take = ceil(damage-save);
  137.  
  138. // add to the damage total for clients, which will be sent as a single
  139. // message at the end of the frame
  140. // FIXME: remove after combining shotgun blasts?
  141.     if (targ.flags & FL_CLIENT)
  142.     {
  143.         targ.dmg_take = targ.dmg_take + take;
  144.         targ.dmg_save = targ.dmg_save + save;
  145.         targ.dmg_inflictor = inflictor;
  146.     }
  147.  
  148. // figure momentum add
  149.     if ( (inflictor != world) && (targ.movetype == MOVETYPE_WALK) )
  150.     {
  151.         dir = targ.origin - (inflictor.absmin + inflictor.absmax) * 0.5;
  152.         dir = normalize(dir);
  153.         targ.velocity = targ.velocity + dir*damage*8;
  154.     }
  155.  
  156. // check for godmode or invincibility
  157.     if (targ.flags & FL_GODMODE)
  158.         return;
  159.     if (targ.invincible_finished >= time)
  160.     {
  161.         if (self.invincible_sound < time)
  162.         {
  163.             sound (targ, CHAN_ITEM, "items/protect3.wav", 1, ATTN_NORM);
  164.             self.invincible_sound = time + 2;
  165.         }
  166.         return;
  167.     }
  168.  
  169. // team play damage avoidance
  170.     if ( (teamplay == 1) && (targ.team > 0)&&(targ.team == attacker.team) )
  171.         return;
  172.         
  173. // do the damage
  174.     targ.health = targ.health - take;
  175.             
  176.     if (targ.health <= 0)
  177.     {
  178.         Killed (targ, attacker);
  179.         return;
  180.     }
  181.  
  182. // react to the damage
  183.     oldself = self;
  184.     self = targ;
  185.  
  186.     if ( (self.flags & FL_MONSTER) && attacker != world)
  187.     {
  188.     // get mad unless of the same class (except for soldiers)
  189.         if (self != attacker && attacker != self.enemy)
  190.         {
  191.             if ( (self.classname != attacker.classname) 
  192.             || (self.classname == "monster_army" ) )
  193.             {
  194.                 if (self.enemy.classname == "player")
  195.                     self.oldenemy = self.enemy;
  196.                 self.enemy = attacker;
  197.                 FoundTarget ();
  198.             }
  199.         }
  200.     }
  201.  
  202.     if (self.th_pain)
  203.     {
  204.         self.th_pain (attacker, take);
  205.     // nightmare mode monsters don't go into pain frames often
  206.         if (skill == 3)
  207.             self.pain_finished = time + 5;          
  208.     }
  209.  
  210.     self = oldself;
  211. };
  212.  
  213. /*
  214. ============
  215. T_RadiusDamage
  216. ============
  217. */
  218. void(entity inflictor, entity attacker, float damage, entity ignore) T_RadiusDamage =
  219. {
  220.     local   float   points;
  221.     local   entity  head;
  222.     local   vector  org;
  223.  
  224.     head = findradius(inflictor.origin, damage+40);
  225.     
  226.     while (head)
  227.     {
  228.         if (head != ignore)
  229.         {
  230.             if (head.takedamage)
  231.             {
  232.                 org = head.origin + (head.mins + head.maxs)*0.5;
  233.                 points = 0.5*vlen (inflictor.origin - org);
  234.                 if (points < 0)
  235.                     points = 0;
  236.                 points = damage - points;
  237.                 if (head == attacker)
  238.                     points = points * 0.5;
  239.                 if (points > 0)
  240.                 {
  241.                     if (CanDamage (head, inflictor))
  242.                     {       // shambler takes half damage from all explosions
  243.                         if (head.classname == "monster_shambler")                                               
  244.                             T_Damage (head, inflictor, attacker, points*0.5);
  245.                         else
  246.                             T_Damage (head, inflictor, attacker, points);
  247.                     }
  248.                 }
  249.             }
  250.         }
  251.         head = head.chain;
  252.     }
  253. };
  254.  
  255. /*
  256. ============
  257. T_BeamDamage
  258. ============
  259. */
  260. void(entity attacker, float damage) T_BeamDamage =
  261. {
  262.     local   float   points;
  263.     local   entity  head;
  264.     
  265.     head = findradius(attacker.origin, damage+40);
  266.     
  267.     while (head)
  268.     {
  269.         if (head.takedamage)
  270.         {
  271.             points = 0.5*vlen (attacker.origin - head.origin);
  272.             if (points < 0)
  273.                 points = 0;
  274.             points = damage - points;
  275.             if (head == attacker)
  276.                 points = points * 0.5;
  277.             if (points > 0)
  278.             {
  279.                 if (CanDamage (head, attacker))
  280.                 {
  281.                     if (head.classname == "monster_shambler")                                               
  282.                         T_Damage (head, attacker, attacker, points*0.5);
  283.                     else
  284.                         T_Damage (head, attacker, attacker, points);
  285.                 }
  286.             }
  287.         }
  288.         head = head.chain;
  289.     }
  290. };
  291.  
  292.