home *** CD-ROM | disk | FTP | other *** search
/ Play and Learn 2 / 19941.ZIP / 19941 / EDUCNOMY / ASTROSET / ANGSEP.BAS < prev    next >
Encoding:
BASIC Source File  |  1994-02-04  |  768 b   |  35 lines
  1.  
  2.  
  3. 10 REM   ANGULAR SEPARATION
  4. 12 REM
  5. 14 P=3.14159265: C=P/180
  6. 16 PRINT "FIRST STAR --"
  7. 18 INPUT "R A (H,M,S) ";A$,A2,A3
  8. 20 GOSUB 60    : R1=A*15*C
  9. 22 INPUT "DEC (D,M,S) ";A$,A2,A3
  10. 24 GOSUB 60    : D1=A*C
  11. 26 PRINT
  12. 28 PRINT "SECOND STAR --"
  13. 30 INPUT "R A (H,M,S) ";A$,A2,A3
  14. 32 GOSUB 60    : R2=A*15*C
  15. 34 INPUT "DEC (D,M,S) ";A$,A2,A3
  16. 36 GOSUB 60    : D2=A*C
  17. 38 REM
  18. 40 D=SIN((D1-D2)/2): H1=D*D
  19. 42 A=SIN((R1-R2)/2): H2=A*A
  20. 44 H3=H1+COS(D1)*COS(D2)*H2
  21. 46 S1=SQR(H3): C1=SQR(1-S1*S1)
  22. 48 S=2*ATN(S1/C1)/C
  23. 50 PRINT
  24. 52 PRINT "SEPARATION --"
  25. 54 PRINT "IN DEGREES:  ";S
  26. 56 PRINT "IN ARC SEC:  ";S*3600
  27. 58 END
  28. 60 REM   SEXAGESIMAL TO DECIMAL
  29. 62 REM
  30. 64 F=1: A1=ABS(VAL(A$))
  31. 66 IF LEFT$(A$,1)="-" THEN F=-1
  32. 68 A=F*(A1+A2/60+A3/3600)
  33. 70 RETURN
  34.  
  35.