BBS in a Box 11/AMUG BBS in a Box Volume XI (April 1994) (MacWizards).iso/Files/Tele/I-L/LineShare Demo2.0.sit/LineShare Demo2.0/LineShare Files/LineShare Scripts/EXAR Fax&ARA&TeleFinder

Text File | 1993-07-12 | 6.1 KB | 293 lines | [TEXT/sLiN]

!$ Use with EXAR-based (GVC, Best, etc) fax-modems.
!$ This script supports: Fax, ARA, and TeleFinder.

!$ Set the TeleFinder "Host Options":
!$ "Adjust BPS" - Off, "Hardware handshake" - On, "Use Break Reset" - On.

!$ This script disables MNP for incoming data calls, but V.42 is supported.

!$ Version 1.5

^2 Speaker On:        = Enum("Never" = "0" ,  "When Connecting" = "1", "Always"="2") "1"
^3 Speaker Volume:    = Enum("Low"="1","Medium"="2","High"="3") "2"
^4 Answer On:         = Enum("1 Ring"="1","2 Rings"="2","3 Rings"="3","5 Rings"="5","7 Rings"="7") "2"
^5 Fax Identifier:    = Text "Stalker_GmbH"

! ------------------------------------------
! Resetting the modem:
! ------------------------------------------
@Hangup
  SetTries 2
  Flush
  HsReset 0,0,17,19,0,0
!
! Try to catch the "OK" answer, use the Escape seq and DTR transitions
! to enter the command mode
!
@Label 1
  matchclr
  matchstr 1 2 "OK\r\n"
  write "ATH0&F\r"
  matchread 20
  Write "+++"
  DtrClear
  pause 10
  DtrSet
!
  DecTries
  IfTries 0 1
!
! OSErr -6019 "Modem error - the modem is not responding"
!
  exit -6019
@Label 2
  write "AT+FCLASS=0\r"
  Jsr 100
  write "AT+FAA=0\r"
  Jsr 100
  exit 0
! ------------------------------------------
!    Receiving incoming calls
! ------------------------------------------
@ANSWER
@Label 10
  SerReset 19200,0,8,1
  Jsr 80
!
! Set the common options
  Jsr 70
!
! Set the communication options:
! • X4:  Extended response set
! • \N5: V42bis/Normal connection (but not MNP!)
! • \Q2: Uni-directional hardware flow control
! • \JO: Disable bps adjust
! • \V1: Enable enhanced CONNECT messages
!
@Label 11
  Write "ATX4\\N5\\Q3\\J0\\V1\r"
  Jsr 100
!
! Set Fax parameters: LID, DCC,BOR
!
  Write "AT+FCLASS=2\r"
  Jsr 100
  Write "AT+FLID=\"^5\"\r"
  Pause 10
  Flush
  Write "AT+FDCC=1,3,0,2,0,0,0,0\r"
  Jsr 100
  Write "AT+FBOR=1\r"
  Jsr 100
!
! Allow modem to receive fax messages
!
  Write "AT+FCR=1\r"
  Jsr 100
!
! Tell the modem to determine the type of the incoming call
! Fetch the tube after ^4 rings
!
  Write "ATS0=^4+FAA=1\r"
  Jsr 100
  Note "Waiting for Fax/ARA/TeleFinder calls…"
!
! Everything is ready - let's sit and wait for a call
! We'll wait for 2 minutes, then reinitiate the modem
!
@Label 12
  MatchClr
  matchstr 1 13 "RING\r\n"
  matchstr 2 21 "\r\nCONNECT ^$/V"
  matchstr 3 15 "\r\nCONNECT ^$\r\n"
  matchstr 9 40 "\r\n+FCON"
  matchstr 10 10 "\r\nNO "
  matchstr 11 10 "\r\nBUSY"
  Matchread 1200
  Jump 10
@Label 13
  Note "Ring…"
  Jump 12
!
! Data connection has been established (we read "CONNECT XXX\r\n")
! Put the "CONNECT" back to the buffer and attach the "Data" subPort
! if it was an incoming call, put the "RING" before the "CONNECT"
!
@Label 15
  SetVar A "^$"
  Note "Non-V.42 Call at ^A bps. Waiting for an ARA frame."
  MatchClr
  MatchStr 1 20 "\r"
  MatchStr 2 30 "\08\01\03\14\04\03\00\08\250\16\03"
  MatchRead 40

@Label 20
  Note "Non-ARA call"
  Flush
  Jump 24
!
! V.42 call detected
!
@Label 21
  SetVar A "^$"
  Note "V.42 Call at ^A bps"
  MatchClr
  MatchStr 1 24 "\r\n"
  MatchRead 5
@Label 24
  QueueInput "\r\27CONNECT ^A\r\27"
@Label 25
  Attach "TF" (DTR,Break,Escape,TimeLimit=0)

!
! The ARA (MNP 4) frame detected
!
@Label 30
  Note "ARA call at ^A bps."
  Flush
  QueueInput "\r\nRING\r\n\r\nCARRIER ^A\r\n"
@Label 32
  Attach "ARA" (DTR,Escape,TimeLimit=0)

!
! Fax connection has been established (we read "+FCON")
! Put the +FCON back to the buffer,
! if it was an incoming call, put the "RING" before the "+FCON"
! Attach the "Fax" subPort
!
@Label 40
  QueueInput "\r\n+FCON"
  ifOriginate 41
  QueueInput "\r\nRING\r\n"
@Label 41
  Attach "Fax" (DTR,Reset,Escape,IdleLimit=30)

! ------------------------------------------
! Originating a call through the "ARA" subport
! ------------------------------------------
@ORIGINATE "ARA"
  SerReset 19200,0,8,1
  Jsr 80
!
! Set the common options
!
  Jsr 70
!
! Set the Data mode:
! • X4:  Extended response set
! • \N0: Normal connection (no compression, no correction, speed buffering - for ARA)
! • \Q2: Unidirectional Hardware handshake
! • \J0: Don't adjust the speed
! • S7:  time-out (90 sec) for long-distance call (if you use them)
!
  Write "ATX4\\N0\\Q2\\J0S7=90\r"
  Jsr 100
!
! Prepare to receive all error result codes
!
  Jsr 90
  MatchStr 1 45 "\r\nCONNECT "
  MatchRead 900
  Write "\r"
  Exit -6019

@Label 45
  QueueInput "\r\nCARRIER "
  Jump 32


! ------------------------------------------
! Originating a call through the "Fax" subPort
! ------------------------------------------
@ORIGINATE "Fax" ("\r\nLineShare Line is Busy\r\nBUSY\r\n")
  SerReset 19200,0,8,1
  Jsr 80
!
! Set the common options
!
  Jsr 70
!
! Set the Fax mode
!
  Write "AT+FCLASS=2\r"
  Jsr 100
!
! Now emit all commands that the application has sent to that port,
! Prepare to receive all error result codes
!
  Jsr 60
  Jsr 90
  MatchStr 1 40 "\r\n+FCON"
  MatchRead 700
  Write "\r"
  Exit -6019

!
! This section emits all modem commands sent from the client application
! For each set of commands the "OK" answer is awaited
!
@Label 60
  EmitStart
@Label 61
  EmitCommand 62
  Jsr 100
  Jump 61
@Label 62
  return
!
! This section initiates the modem before ANSWER and ORIGINATEs:
! factory settings + speaker control +
! ignore Dtr drop + DCD valid
! Verbal responses mode, no echo
! Disable extended codes
!
@Label 70
  Write "ATM^2L^3&D0&C1V1E0\\V0\r"
  Jsr 100
  return
!
! This section syncronize the modem after the serial port speed switching
!
@Label 80
  ChrDelay 1
  Write "AT\r"
  ChrDelay 0
  Jsr 100
  return
!
! Prepare to receive error result codes
!
@Label 90
  MatchClr
  MatchStr 2 91 "NO DIALTONE\r\n"
  MatchStr 3 92 "BUSY\r\n"
  MatchStr 4 93 "NO CARRIER\r\n"
  MatchStr 5 94 "NO ANSWER\r\n"
  Write "ATD^1\r"
  HsReset *
  return

@Label 91
  exit -6020
@Label 92
  exit -6022
@Label 93
  exit -6021
@Label 94
  exit -6023
!
! Processing the AT command:
! OK -> proceed
! ERROR or TimeOut ->exit -6019
! It can be called AFTER the "Write" command, since LineShare buffers input
!
@Label 100
  MatchClr
  MatchStr 1 102 "\r\nOK\r\n"
  MatchStr 2 101 "\r\nERROR\r\n"
  MatchRead 20
@Label 101
  Exit -6019
@Label 102
  return