home *** CD-ROM | disk | FTP | other *** search
/ Amiga Elysian Archive / AmigaElysianArchive.iso / newc_dev / rmlib111.lha / remlib.asm < prev    next >
Assembly Source File  |  1991-01-13  |  27KB  |  712 lines
  1. *****************************************************************************
  2. *
  3. * RemLib.asm    by      HEIKO RATH 
  4. *                       copyright 1987/88 by the Software Brewery
  5. *
  6. * The purpose of this program is to remove a library from the librarylist.
  7. * To be save, it only removes librarys with an OpenCnt of 0.
  8. * To get a list of all librarys use RemLib without an argument.
  9. *                                                               Heiko Rath
  10. * Version 1.00 - printed all libraries with one Write (with many libs -> GURU)
  11. * Version 1.01 - prints every row with an extra Write
  12. * Version 1.05 - now features positive and negative size of library
  13. * Version 1.10 - now stops on CTRL-C
  14. * Version 1.11 - worked on error texts
  15. *
  16. *
  17. * This program is
  18. *  
  19. * Copyright (c) 1988 by Heiko Rath and the Software Brewery.
  20. * 
  21. * It may be freely distributed for non-profit only.
  22. * The distribution must contain ALL parts, in this case the following
  23. * files:
  24. * 
  25. * RemLib
  26. * RemLib.asm
  27. * 
  28. * Putting it on a commercial product is usually as easy as sending
  29. * a letter to the author.
  30. *
  31. *****************************************************************************
  32. *______  /          
  33. *______\O                     - The Software Brewery - 
  34. *      \\ 
  35. *       o           Sparkling, fresh software from West-Germany
  36. *
  37. *     @@@@@             Straight from the bar to your Amiga
  38. *     |~~~|\ 
  39. *     | | |/ 
  40. *     |___|        With our regards to the Software Distillery
  41. *
  42. *Christian Balzer alias <CB>, Lattice C, user interfaces, beer addict. 
  43. *Heiko Rath alias <HR>, Assembler, ROM-Kernal stuff, Marabou & beer addict. 
  44. *Ralf Woitinas alias RAF, Assembler, anything, Ray-Tracing addict.
  45. *Andrew Kopp alias Charlie, Aztec C, Hardware & communications, beer addict.
  46. *Armin Sparr alias MARVIN, Aztec C, ARexx macros, Campari addict.
  47. *Christof Bonnkirch alias KEY, Aztec C, Hardware & Devices, beer addict.
  48. *
  49. *Beverages: Altenmuenster Brauer Bier, Urfraenkisches Landbier, Jever.
  50. *
  51. *Send exotic drinks, mail, comments and flames to:
  52. *
  53. *The Software Brewery
  54. *Christian Balzer               UUCP: decwrl!frambo.dec.com!schabacker
  55. *Im Wingertsberg 45             ARPA: schabacker@frambo.dec.com
  56. *D-6108 Weiterstadt             CIS : 71001,210 (be brief!)
  57. *WEST GERMANY (F.R.G.)          Fone: +49 6150 4151 (18:00-21:00 CET!)
  58. *
  59. *
  60. *Send the above stuff, beautiful girls and of course MARABOU-CHOCOLATE to:
  61. *
  62. *Heiko Rath (HHHEEELLLPPP, I'm running out of MARABOU chocolate!!!!!!!)
  63. *Raiffeisenstr.10a
  64. *D-6108 Weiterstadt
  65. *WEST GERMANY (F.R.G.)
  66. *
  67.  
  68. Version         MACRO
  69.                 dc.b    '1.11'
  70.                 ENDM
  71.  
  72. ExecBase        Equ     4
  73.  
  74. ***
  75. *** Exec Offsets:
  76. ***
  77. OpenLibrary     Equ     -552            ;OpenLibrary (LibName,version)(a1,d0)
  78. CloseLibrary    Equ     -414            ;CloseLibrary (Library)(a1)
  79. Forbid          Equ     -132            ;Forbid ()()
  80. Permit          Equ     -138            ;Permit ()()
  81. AllocMem        Equ     -198            ;AllocMem (bytesize,requirement)(d0,d1)
  82. FreeMem         Equ     -210            ;FreeMem (memoryblock,bytesize)(a1,d0)
  83. FindName        Equ     -276            ;FindName (list,name) (a0,a1)
  84. RemLibrary      Equ     -402            ;RemLibrary (library)(a1)
  85. SetSignal       Equ     -306            ;SetSignal (newSignals,signalMask)(d0,d1)
  86.  
  87. ***
  88. *** DOS Offsets:
  89. ***
  90. OutPut          Equ     -60             ;OutPut ()
  91. Input           Equ     -54             ;Input ()
  92. Write           Equ     -48             ;Write (file,buffer,length)(d1,d2,d3)
  93.  
  94. ***
  95. *** I use these Macros to make things easier for me
  96. ***
  97.  
  98. doit:   MACRO
  99.         move.l  #HeadLine,d2            ;address of HeadLine to d2
  100.         bsr     TextOutPut              ;output HeadLine
  101.         move.l  \1,d0                   ;offset of listhead to d0
  102.         bsr     Showlib                 ;output library-list
  103.         ENDM
  104.  
  105. ***
  106. *** Here we go:
  107. ***
  108.         move.l  sp,d6                   ;store stack pointer on stack
  109.         move.l  a0,a2                   ;save cmdline address
  110.         sub.w   #1,d0
  111.         clr.b   0(a2,d0.w)              ;make the cmdline null terminated
  112.  
  113.         move.l  ExecBase,a6             ;Execaddress to a6 (only to be sure)
  114.         move.l  #DOSNAME,a1             ;Librarynamepointer to a1
  115.         moveq   #0,d0                   ;any version
  116.         jsr     OpenLibrary(a6)         ;try to open DOS-Libary
  117.         tst.l   d0                      ;is d0 = NULL?
  118.         beq     ErrorExit               ;exit if call wasn't successfull
  119.         move.l  d0,DOSBase              ;save DOSBasepointer
  120.         move.l  d0,a6                   ;move DOSBasepointer to a6
  121.         jsr     OutPut(a6)              ;identify the initial output handle
  122.         move.l  d0,stdout               ;save stdout
  123.  
  124.         move.l  #Text,d2
  125.         bsr     TextOutPut
  126.  
  127. SkipSP: 
  128.         move.b  (a2)+,d1                ;skip spaces
  129.         beq     ShowTheLibs             ;if NULL-String then /* show librarys */
  130.         cmp.b   #' ',d1                 ;is it a Space ?
  131.         beq.b   SkipSP                  ;yes -> SkipSP
  132.  
  133.         cmp.b   #'?',d1                 ;is it '?' ?
  134.         beq     ShowHow                 ;yes -> ShowHow
  135.  
  136.         cmp.b   #'"',d1                 ;is it '"' ?
  137.         bne.b   001$                    ;yes -> 001$
  138.         add.l   #1,a2
  139.         move.l  a2,a1
  140. 002$:
  141.         move.b  (a1)+,d1
  142.         beq     NoSuchLibrary
  143.         cmp.b   #'"',d1
  144.         beq.b   003$
  145.         bra.b   002$
  146. 003$:
  147.         sub.l   #1,a1
  148.         move.b  #0,(a1)
  149. 001$:
  150.         sub.l   #1,a2                   ;decrement address by one
  151.         move.l  ExecBase,a6             ;ExecBase to a6
  152.         move.l  a6,a0                   ;ExecBase to a0
  153.         add.l   liblist,a0              ;address of librarylist to a0
  154.         move.l  a2,a1                   ;address of string to a1
  155.         jsr     FindName(a6)            ;search for the given name
  156.         tst.l   d0                      ;is there a library with the given name
  157.  
  158.         beq.b   NoSuchLibrary           ;no -> NoSuchLibrary
  159.  
  160.         move.l  d0,a1                   ;copy address of library to a1
  161.         move.w  32(a1),d0               ;get OpenCnt
  162.         tst.w   d0                      ;is the OpenCnt = 0?
  163.         bne.b   NotZero                 ;no -> say that the library is still open
  164.         jsr     RemLibrary(a6)          ;try to close the library
  165.         tst.l   d0
  166.         bne.b   Success                 ;->Success
  167.  
  168.         move.l  #FailedToRemove,d2
  169.         bsr     TextOutPut
  170.         bra.b   CloseDOS
  171.  
  172. Success:
  173.         move.l  #Successfull,d2
  174.         bsr     TextOutPut
  175.         bra.b   CloseDOS
  176.  
  177. NoSuchLibrary:
  178.         move.l  #NotFound,d2
  179.         bsr     TextOutPut
  180.         bra.b   CloseDOS
  181.  
  182. NotZero:
  183.         move.l  #NotAbleToClose,d2
  184.         bsr     TextOutPut
  185.         bra.b   CloseDOS
  186.  
  187. ShowTheLibs:
  188.         doit    liblist                 ;output Librarylist
  189.  
  190. CloseDOS:
  191.         move.l  ExecBase,a6             ;ExecBase to a6
  192.         move.l  DOSBase,a1              ;DOS-pointer to a1
  193.         move.l  ExecBase,a6             ;Exec-pointer to a6
  194.         jsr     CloseLibrary(a6)        ;close DOS
  195. ErrorExit:
  196.         move.l  d6,sp                   ;restore stack pointer
  197.         rts                             ;CLI here we go again!!!!
  198.  
  199. ShowHow:
  200.         move.l  #HelpText,d2
  201.         bsr     TextOutPut
  202.         bra.b   CloseDOS
  203.  
  204. *****************************************************************************
  205. *
  206. *       Showlib II                              11.1.87 modified on 18.10.88
  207. *                       by      Heiko Rath
  208. *                               Raiffeisenstr.10a
  209. *                               D-6108 Weiterstadt
  210. *                               WEST GERMANY (F.R.G.)
  211. *
  212. *
  213. * PURPOSE:                      print out Librarylist (address of Node,
  214. *                               type, priority, name of Node, version, revision,
  215. *                               opencount, negative size, positive size)
  216. *
  217. * ROUTINETYPE:                  subroutine
  218. *
  219. * SYNTAX:                       bsr Showlib     (Exec-offset to librarylist)(d0)
  220. *
  221. * ENTRY CONDITIONS:             needs DOSlibrary opened and stdout defined
  222. *                               also needs DOS-'Write' offset -48 defined.
  223. *                               It also needs binhex subroutine.
  224. *
  225. * RETURNS:                      none
  226. *
  227. * BUGS:                         none
  228. *
  229. * NOTE:                         none
  230. *
  231. * CHANGED:                      nothing
  232. *
  233. * USAGE:                        move.l  LibraryListOffset,d0
  234. *                               bsr     Showlib
  235. *
  236. *****************************************************************************
  237. Showlib:
  238.         movem.l d0-d7/a0-a6,-(sp)       ;save registers
  239.  
  240.         move.l  ExecBase,a6             ;ExecBase to a6
  241.         jsr     Forbid(a6)              ;forbid taskswitching (very important,
  242.                                         ; 'cause we are accessing Systemdata)
  243.  
  244.         move.l  a6,a0                   ;Execpointer to a0
  245.         add.l   d0,a0                   ; + librarylistoffset=address of listhead
  246.         move.l  a0,ListHead             ;save address of listheader -=> ListHead
  247.         move.l  (a0),a1                 ;get address of 1.Node to a1
  248.         move.l  a1,Node                 ;save address of 1.Node -=> Node
  249.         addq.l  #4,a0
  250.         cmp.l   a1,a0                   ;list empty?
  251.                                         ;(test if listhead points to listhead+4)
  252.         beq     PrintLF                 ;yes -=> send LF and exit
  253.  
  254.         moveq.l #1,d1                   ;set counter to 1 'cause there is at least
  255.                                         ; one node in the list
  256. MyCountLoop:
  257.         move.l  (a1),a1                 ;get address of next node to a1
  258.         tst.l   (a1)                    ;see if contents of (a1) is NULL
  259.         beq.b   EndCount                ;leave counting loop
  260.         addq.l  #1,d1                   ;increment counter by one
  261.         bra.b   MyCountLoop             ;do this once more
  262.  
  263. EndCount:
  264.         move.l  d1,NodeCount            ;save number of Nodes
  265.  
  266.         move.l  #71,d0                  ;number of bytes per node
  267.         mulu    d1,d0                   ;bytes per node * NodeCount
  268.         addq.l  #1,d0                   ;add one for the bufferterminating Null
  269.         move.l  d0,MyMemoryLength       ;save lenght of Memoryblock
  270.         move.l  #$10001,d1              ;requirements:MEMF_Public & Clear
  271.         jsr     AllocMem(a6)            ;get memory from system
  272.         move.l  d0,MyMemoryBlock        ;save address of Memoryblock
  273.         move.l  d0,MyMemoryOffset       ;save address of Memoryblock 2.time
  274.         tst.l   d0                      ;see if call was successfull
  275.         bne     MoveNodeToBuffer        ;yes -=> MoveNodeToBuffer
  276.  
  277.         move.l  #Err,d2                 ;this code is only here, to inform the
  278.         bsr     TextOutPut              ; user that the AllocMem call wasn't
  279.         bra     PrintLF                 ; successfull
  280.  
  281. MoveNodeToBuffer:
  282.         move.l  d0,a0                   ;get address of MemoryBlock to a0
  283.         move.l  MyMemoryLength,d1       ;get length to d1
  284.  
  285. fill:
  286.         move.b  #' ',(a0)+              ;fill MyMemoryBlock with spaces
  287.         dbeq.b  d1,fill                 ;is d1=NULL? (no-=>d1=d1-1-=>fill)
  288.  
  289. TheLoop:
  290.         move.l  MyMemoryOffset,a0       ;get address of MyMemoryOffset to a0
  291.         move.l  Node,a1                 ;get address of current node to a1
  292.  
  293.         add.l   #10,a1                  ;address of namepointer to a1
  294.         move.l  (a1),a1                 ;get address of nodename to a1
  295.         moveq.l #0,d1                   ;this is faster than clr.l d1
  296.         moveq.l #0,d2                   ;set this to NULL for strlen
  297.  
  298. strlen:
  299.         cmp.b   (a1)+,d2                ;NULL?
  300.         beq.b   strlentest              ;yes -=>strlentest
  301.         addq.l  #1,d1                   ;increment d1 by one (stringlength)
  302.         bra.b   strlen                  ;do the loop once more
  303.  
  304. strlentest:
  305.         cmp.b   #20,d1                  ;see if string is greater #20
  306.         ble.b   DoCopy                  ;no (less or equal)-=>DoCopy
  307.         move.l  #20,d1                  ;set max.length to 20
  308.  
  309. DoCopy:
  310.         move.l  Node,a1                 ;get address of node to a1
  311.         add.l   #10,a1                  ;address of namepointer to a1
  312.         move.l  (a1),a1                 ;get address of nodename to a1
  313.         tst.l   d1                      ;see if d1=0
  314.         bne     DoTheCopy               ;jump only if d1<>0
  315.         move.l  #NoName,a1              ;get address of NoName to a1
  316.         moveq.l #7,d1                   ;set length to 7 (length of 'No Name')
  317.  
  318. DoTheCopy:
  319.         subq.l  #1,d1                   ;decrement d1 by 1
  320.  
  321. CopyLoop:
  322.         move.b  0(a1,d1),0(a0,d1)       ;copy source to destination
  323.         dbf     d1,CopyLoop             ;decrement d1, if d1<0 then out of loop
  324.  
  325.         move.l  MyMemoryOffset,a0       ;get address of MyMemoryOffset to a0
  326.         move.b  #'$',21(a0)             ;store '$'
  327.         move.b  #'$',35(a0)             ;store '$'
  328.         move.b  #10,69(a0)              ;store LF
  329.         move.b  #0,70(a0)               ;store end of string
  330.  
  331.         move.l  Node,a1                 ;get Nodeaddress to a1
  332.         addq.l  #8,a1                   ;add 8 to get address of Type
  333.         moveq.l #0,d0                   ;clear d0
  334.         move.b  (a1),d0                 ;get Type to d0
  335.         move.l  MyMemoryOffset,a0
  336.         add.l   #31,a0
  337.         bsr     bindecb                 ;convert to ASCII
  338.  
  339.         move.l  Node,a1                 ;get Nodeaddress to a1
  340.         add.l   #9,a1                   ;add 1 to get address of Priority
  341.         moveq.l #0,d0
  342.         move.b  (a1),d0
  343.         move.l  MyMemoryOffset,a0
  344.         add.l   #35,a0
  345.         bsr     bindecb
  346.  
  347.         move.l  Node,a1                 ;get Nodeaddress to a1
  348.         add.l   #32,a1                  ;add 32 to get address of OpenCnt
  349.         moveq.l #0,d0                   ;clear d0
  350.         move.w  (a1),d0                 ;get OpenCnt to d0
  351.         move.l  MyMemoryOffset,a0
  352.         add.l   #39,a0
  353.         bsr     bindecw                 ;convert OpenCnt to ASCII
  354.  
  355.         move.l  Node,a1                 ;get Nodeaddress to a1
  356.         add.l   #20,a1
  357.         moveq.l #0,d0
  358.         move.w  (a1),d0                 ;Version
  359.         move.l  MyMemoryOffset,a0
  360.         add.l   #45,a0
  361.         bsr     bindecw
  362.  
  363.         move.l  Node,a1
  364.         add.l   #22,a1
  365.         moveq.l #0,d0
  366.         move.w  (a1),d0                 ;Revision
  367.         move.l  MyMemoryOffset,a0
  368.         add.l   #51,a0
  369.         bsr     bindecw
  370.  
  371.         move.l  Node,a1
  372.         add.l   #16,a1
  373.         moveq.l #0,d0
  374.         move.w  (a1),d0                 ;NegSize
  375.         move.l  MyMemoryOffset,a0
  376.         add.l   #57,a0
  377.         bsr     bindecw
  378.  
  379.         move.l  Node,a1
  380.         add.l   #18,a1
  381.         moveq.l #0,d0
  382.         move.w  (a1),d0                 ;PosSize
  383.         move.l  MyMemoryOffset,a0
  384.         add.l   #63,a0
  385.         bsr     bindecw
  386.  
  387.         move.l  Node,d0                 ;get Nodeaddress to d2
  388.         move.l  MyMemoryOffset,a0       ;get address of MyMemoryOffset to a0
  389.         add.l   #22,a0                  ;add 22 to get storeaddress
  390.         bsr     binhex                  ;convert address to ASCII
  391.  
  392.         add.l   #71,MyMemoryOffset      ;do this for the next loop
  393.         move.l  Node,a1                 ;get nodeaddress to a1
  394.         move.l  (a1),Node               ;save address of next node
  395.         move.l  MyMemoryOffset,d0       ;get MyMemoryOffset to d0
  396.         addq.l  #1,d0
  397.         move.l  MyMemoryBlock,d1        ;get MyMemoryBlock to d1
  398.         add.l   MyMemoryLength,d1       ;add MyMemoryLength to d1
  399.         cmp.l   d0,d1                   ;see if we have to loop once more
  400.         bne     TheLoop                 ;if <> -=> TheLoop
  401.         move.l  MyMemoryBlock,a0        ;get address of MyMemoryBlock to a0
  402.         add.l   MyMemoryLength,a0       ;add length to MyMemoryBlock
  403.         subq.l  #1,a0                   ;decrement address by one
  404.         move.b  #0,(a0)                 ;set last byte of MyMemoryBlock to NULL
  405.  
  406.         move.l  NodeCount,d3            ;get number of nodes to d3
  407.         move.l  MyMemoryBlock,d2        ;get address of MyMemoryBlock to d2
  408. FinallyPrintIt:
  409.         bsr     TextOutPut              ;print one line
  410.         add.l   #71,d2                  ;increment string startaddress by 71
  411.         clr.l   d0                      ;clear newSignals
  412.         clr.l   d1                      ;clear signalMask
  413.         jsr     SetSignal(a6)           ;get the signalmask of our task
  414.         btst    #12,d0                  ;is the CTRL-C Bit set?
  415.         bne     CTRL_C_Break            ;if yes -> CTRL_C_Break
  416.         tst.l   d3                      ;get desired flag to CCR
  417.         dbeq    d3,FinallyPrintIt       ;is d3=NULL? (no-=>d3=d3-1-=>FinallyPrintIt
  418.  
  419.         move.l  MyMemoryBlock,a1        ;get address of MyMemoryBlock to a1
  420.         move.l  MyMemoryLength,d0       ;get length of MyMemoryBlock to d0
  421.         jsr     FreeMem(a6)             ;free the allocated RAM
  422.  
  423. PrintLF:
  424.         move.l  #LF,d2                  ;get address of LF-string to d2
  425.         bsr.b   TextOutPut              ;and get it out via DOS-Write & stdout
  426.         jsr     Permit(a6)              ;permit taskswitching (I think Dos enables
  427.                                         ; this for you, but I do this to be sure
  428.                                         ; that taskswitching is now allowed.)
  429.         movem.l (sp)+,d0-d7/a0-a6       ;restore Registers
  430.         rts
  431.  
  432. *****************************************************************************
  433. *
  434. *       TextOutPut
  435. *                       by      Heiko Rath
  436. *                               Raiffeisenstr.10a
  437. *                               D-6108 Weiterstadt
  438. *                               WEST GERMANY (F.R.G.)
  439. *
  440. * PURPOSE:              output a NULL-terminated string via stdout
  441. *
  442. * ROUTINE TYPE:         subroutine
  443. *
  444. * SYNTAX:               bsr     TextOutPut      (stringaddress)(d0)
  445. *
  446. * ENTRY CONDITIONS:     needs DOSlibrary opened and stdout defined
  447. *                       also needs DOS-'Write' offset -48 defined.
  448. *
  449. * RETURNS:              none
  450. *
  451. * NOTE:                 its better if the string is really NULL-terminated
  452. *
  453. * CHANGED:              nothing
  454. *
  455. * USAGE:                move.l  #Textaddress,d2
  456. *                       bsr     TextOutPut
  457. *
  458. *****************************************************************************
  459.  
  460. TextOutPut:
  461.         movem.l d0-d7/a0-a6,-(sp)       ;save registers
  462.         move.l  d2,a0                   ;address to a0
  463.         clr.l   d3                      ;count = 0
  464.  
  465. CountLoop:
  466.         tst.b   (a0)+                   ;is it NULL ?
  467.         beq.b   PMsg                    ;yes: -=> determine length
  468.         addq.l  #1,d3                   ;count = count+1
  469.         bra.b   CountLoop               ;test next byte
  470.  
  471. PMsg:
  472.         move.l  stdout,d1               ;get stdout to d1
  473.         move.l  DOSBase,a6              ;move DOSBase to a6
  474.         jsr     Write(a6)               ;write the Text
  475.         movem.l (sp)+,d0-d7/a0-a6       ;reserve registers
  476.         rts
  477.  
  478. ***********************************************************************
  479. *
  480. *        binhex
  481. *                       by Heiko Rath
  482. *
  483. * PURPOSE: Convert a binary value in a register to
  484. *           a hex ASCII string at the destination address
  485. *          
  486. * ROUTINE TYPE: SUBROUTINE
  487. *
  488. * SYNTAX: bsr   binhex  (source(long),destination) (d0.l,a0)
  489. *          bsr  binhexw (source(word),destination) (d0.w,a0)
  490. *          bsr  binhexb (source(byte),destination) (d0.b,a0)
  491. *
  492. * ENTRY CONDITIONS: None
  493. *
  494. * RETURNS: ASCII string in destination address
  495. * NOTE:         the destination place must contain 8 bytes for any
  496. *               length (byte, word, longword)
  497. *
  498. * CHANGED: Nothing
  499. *
  500. * USAGE:
  501. *
  502. *        move   #label,d0
  503. *        move.l address,a0      ;converts the address at label to
  504. *        bsr    binhex          ;string at address
  505. *                               
  506. *        move   label,d0
  507. *        move.l address,a0
  508. *        bsr    binhex          ;conv contents at label
  509. *
  510. *        move   #value,d0
  511. *        move.l address,a0
  512. *        bsr    binhex          ;convert immediate value
  513. *
  514. ****************************************************************
  515.  
  516. binhex: movem.l d0-d2/a0,-(sp)          ;save registers
  517.  
  518.         move.l  #7,d2                   ;get number of counts to d2
  519.         clr.l   d1                      ;clear work register
  520.  
  521. 001$:   rol.l   #4,d0                   ;move high nibble to low order
  522.         move.b  d0,d1                   ;get low order byte to d1
  523.         andi.b  #$f,d1                  ;isolate low order nibble
  524.         cmp.b   #$0a,d1                 ;is it a letter or a digit?
  525.         blt.b   002$                    ;if digit -=> 002$
  526.         add.b   #'A'-'0'-$0A,d1         ;offset for letters
  527.  
  528. 002$:   add.b   #'0',d1                 ;convert to ASCII
  529.         move.b  d1,(a0)+                ;store it and increment storeaddress
  530.         dbf.b   d2,001$                 ;do the converting 8 times
  531.  
  532.         movem.l (sp)+,d0-d2/a0          ;restore registers
  533.         rts
  534.  
  535. ***********************************************************************
  536. *
  537. *        bindec
  538. *                       by Heiko Rath
  539. *
  540. * PURPOSE: Convert a binary value in a register to
  541. *           a dec ASCII string at the destination address
  542. *          
  543. * ROUTINE TYPE: SUBROUTINE
  544. *
  545. * SYNTAX:
  546. *          bsr  bindecw (source(word),destination) (d0.w,a0)
  547. *          bsr  bindecb (source(byte),destination) (d0.b,a0)
  548. *
  549. * ENTRY CONDITIONS: None
  550. *
  551. * RETURNS: ASCII string in destination address
  552. * NOTE:         the destination place must contain 5 bytes for any
  553. *               length (byte, word). Don't use longwords!
  554. *
  555. * CHANGED: Nothing
  556. *
  557. * USAGE:
  558. *
  559. *        move   #label,d0
  560. *        move.l address,a0      ;converts the address at label to
  561. *        bsr    bindec          ;string at address
  562. *                               
  563. *        move   label,d0
  564. *        move.l address,a0
  565. *        bsr    bindec          ;conv contents at label
  566. *
  567. *        move   #value,d0
  568. *        move.l address,a0
  569. *        bsr    bindec          ;convert immediate value
  570. *
  571. ****************************************************************
  572.  
  573. bindecb:
  574.         movem.l d0-d2/a0,-(sp)          ;store registers
  575.         move.l  d0,d1
  576.         move.l  a0,a1
  577.         bra.b   ByteToDec
  578.  
  579. bindecw:
  580.         movem.l d0-d2/a0,-(sp)          ;save registers
  581.         move.l  d0,d1
  582.         move.l  a0,a1
  583.  
  584.         divu    #10000,d1
  585.         bsr.b   StoreOneByte
  586.         divu    #1000,d1
  587.         bsr.b   StoreOneByte
  588. ByteToDec:
  589.         divu    #100,d1
  590.         bsr.b   StoreOneByte
  591.         divu    #10,d1
  592.         bsr.b   StoreOneByte
  593.         bsr.b   StoreOneByte
  594.  
  595. 003$:                                   ;003$ is used to clear the
  596.         move.b  (a1)+,d0                ; leading zeros
  597.         cmp.b   #'0',d0
  598.         bne.b   002$
  599.         cmp.b   #' ',(a1)
  600.         beq.b   002$
  601.         move.b  #' ',-(a1)
  602.         add.l   #1,a1
  603.         bra.b   003$
  604. 002$:
  605.         movem.l (sp)+,d0-d2/a0          ;restore registers
  606.         rts
  607.  
  608. StoreOneByte:
  609.         add.b   #$30,d1
  610.         move.b  d1,(a0)+
  611.         clr.w   d1
  612.         swap    d1
  613.         rts
  614.  
  615. CTRL_C_Break:
  616.         move.l  MyMemoryBlock,a1        ;get address of MyMemoryBlock to a1
  617.         move.l  MyMemoryLength,d0       ;get length of MyMemoryBlock to d0
  618.         jsr     FreeMem(a6)             ;free the allocated RAM
  619.  
  620.         move.b  #1,BreakFlag            ;set our internal break flag
  621.         move.l  #BREAK,d2               ;get address of Break-string to d2
  622.         bsr     TextOutPut              ;and get it out via DOS-Write & stdout
  623.         jsr     Permit(a6)              ;permit taskswitching (I think Dos enables
  624.                                         ; this for you, but I do this to be sure
  625.                                         ; that taskswitching is now allowed.)
  626.         movem.l (sp)+,d0-d7/a0-a6       ;restore Registers
  627.         rts
  628.  
  629. ***
  630. *** Variables:
  631. ***
  632.  
  633. DOSBase:        dc.l    0               ;this contains the DOSlibraryaddress
  634. stdout:         dc.l    0               ;this contains stdout
  635. stdin:          dc.l    0               ;this contains stdin
  636. ListHead:
  637.         dc.l    0                       ;At runtime this contains the
  638.                                         ; address of the listheader
  639. Node:
  640.         dc.l    0                       ;At runtime this contains the
  641.                                         ; address of the current node
  642. NodeCount:
  643.         dc.l    0                       ;At runtime this contains the
  644.                                         ; number of nodes in the list
  645. MyMemoryLength:
  646.         dc.l    0                       ;At runtime this contains the
  647.                                         ; length of the memoryblock
  648. MyMemoryBlock:
  649.         dc.l    0                       ;At runtime this contains the
  650.                                         ; address of the memoryblock
  651. MyMemoryOffset:
  652.         dc.l    0                       ;At runtime this contains the
  653.                                         ; address of the memoryblock
  654.                                         ; + 71 Bytes per finished node
  655. BreakFlag:
  656.         dc.b    0                       ;This is set if we encounter a CTRL-C
  657.         cnop    0,2
  658.  
  659. ***
  660. ***Constants:
  661. ***
  662. liblist:        dc.l    $17a
  663.  
  664. DOSNAME:        cstring 'dos.library'
  665.                 cnop    0,2
  666. Err:            dc.b    '*** Out of Memory Error ***',0
  667.                 cnop    0,2
  668. NoName:         dc.b    'No Name',0
  669.                 cnop    0,2
  670. LF:             dc.b    10,0            ;LF
  671.                 cnop    0,2
  672. BREAK:          dc.b    '***BREAK',10,0
  673.                 cnop    0,2
  674. HeadLine:       dc.b    $9b,'4;32;40m'
  675.                 dc.b    'Name                  Address  Typ Pri OpenC'
  676.                 dc.b    ' Vers. Revs.  Neg.  Pos.'
  677.                 dc.b    $9b,'0;31;40m',10,0
  678.                 cnop    0,2
  679. Text:
  680.         dc.b    $9b,'0;33;40m','Lib-Remover',$9b,'0;31;40m '
  681.         dc.b    $9b,'3;31;40m','V'
  682.         Version
  683.         dc.b    $9b,'0;31;40m'
  684.         dc.b    ' by ',$9b,'0;32;40m','Heiko Rath',$9b,'0;31;40m',' - '
  685.         dc.b    $9b,'4;31;40m',169,'1988 by ',$9b,'1;31;40m'
  686.         dc.b    'The Software Brewery',$9b,'0;31;40m',10
  687.         dc.b    'Raiffeisenstr.10a,  D-6108 Weiterstadt,  '
  688.         dc.b    'WEST GERMANY  (F.R.G.)',10,0
  689.  
  690. Successfull:
  691.         dc.b    10,'Succeeded in removing the library.',10,0
  692.         cnop    0,2
  693. NotAbleToClose:
  694.         dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  695.         dc.b    ' This library can not be closed, cause OpenCnt > 0.',10,0
  696.         cnop    0,2
  697. FailedToRemove:
  698.         dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  699.         dc.b    ' Failed to remove the library.',10,0
  700.         cnop    0,2
  701. NotFound:
  702.         dc.b    10,$9b,'0;33;40m','Attention:',$9b,'0;31;40m'
  703.         dc.b    ' Library not found.',10,0
  704.         cnop    0,2
  705. HelpText:
  706.         dc.b    10,'Use ',$9b,'0;33;40m','Remlib',$9b,'0;31;40m'
  707.         dc.b    ' without argument to display all libraries.',10
  708.         dc.b    'Use ',$9b,'0;33;40m','Remlib',$9b,'0;31;40m'
  709.         dc.b    ' "name.library" to remove a library.',10
  710.         dc.b    'Note: It''s only possible to remove libraries with',10
  711.         dc.b    '      an opencount of 0.',10,0
  712.