home *** CD-ROM | disk | FTP | other *** search
/ Amiga Elysian Archive / AmigaElysianArchive.iso / newc_dev / ls32.lha / lssup.a < prev    next >
Text File  |  1989-08-09  |  34KB  |  1,343 lines
  1. * --------------------------------------------------------------------- *
  2. * LSSUP.A - Assembly support routines for ls.c
  3. * Written by Justin V. McCormick 89-07-24
  4. * --------------------------------------------------------------------- *
  5.     IFD    CAPE
  6.     CSYMFMT
  7.     BASEREG    B
  8.     SMALLOBJ
  9.     ADDSYM
  10.     OPTIMON
  11.     IDNT    "lssup.a"
  12.     ENDC
  13.  
  14.  
  15. SYS    MACRO    *
  16.     IFGT    NARG-2
  17.     FAIL    !!!
  18.     ENDC
  19.     IFEQ    NARG-2
  20.     MOVE.L    \2,a6
  21.     ENDC
  22.     JSR    LVO\1(a6)
  23.     ENDM
  24.  
  25. XLVO    MACRO    *
  26.     XREF    LVO\1
  27.     ENDM
  28.  
  29. ; Equates
  30. fib_DirEntryType EQU    $4 
  31. fib_FileName    EQU    $8
  32. fib_Size    EQU    $7C
  33. fib_NumBlocks    EQU    $80
  34. fib_DateStamp    EQU    $84
  35. fib_SIZEOF    EQU    $104 
  36.  
  37. ds_Days        EQU    $0
  38. ds_Minute    EQU    $4
  39. ds_Tick        EQU    $8
  40.  
  41. LH_HEAD        EQU    $0
  42. LN_PRED        EQU    $4
  43. LN_SUCC        EQU    $0
  44.  
  45. fe_Node    equ    0
  46. fe_Fib    equ    8
  47. pr_ConsoleTask        EQU    $A4
  48.  
  49. MEMF_CLEAR        EQU    $10000
  50. sp_Msg            EQU    $0
  51. sp_Pkt            EQU    $14
  52. sp_SIZEOF        EQU    $44
  53. dp_Link            EQU    $0
  54. dp_Port            EQU    $4
  55. dp_Arg1            EQU    $14
  56. dp_Type            EQU    $8
  57. ACTION_SCREEN_MODE    EQU    $3E2
  58. LN_NAME            EQU    $A
  59. LN_PRI            EQU    $9
  60. LN_TYPE            EQU    $8
  61. MP_FLAGS        EQU    $E
  62. MP_MSGLIST        EQU    $14
  63. MP_SIGBIT        EQU    $F
  64. MP_SIGTASK        EQU    $10
  65. MP_SIZE            EQU    $22
  66. NT_MSGPORT        EQU    $4
  67. PA_SIGNAL        EQU    $0
  68.  
  69. * Library offsets
  70.     XLVO    AddPort
  71.     XLVO    AddTail
  72.     XLVO    AllocMem
  73.     XLVO    AllocSignal
  74.     XLVO    CopyMem
  75.     XLVO    Debug
  76.     XLVO    Examine
  77.     XLVO    FindTask
  78.     XLVO    FreeMem
  79.     XLVO    FreeSignal
  80.     XLVO    GetMsg
  81.     XLVO    Input
  82.     XLVO    Insert
  83.     XLVO    IoErr
  84.     XLVO    IsInteractive
  85.     XLVO    Output
  86.     XLVO    ParentDir
  87.     XLVO    PutMsg
  88.     XLVO    RawDoFmt
  89.     XLVO    Read
  90.     XLVO    RemPort
  91.     XLVO    WaitForChar
  92.     XLVO    WaitPort
  93.     XLVO    Write
  94.     XLVO    UnLock
  95.  
  96. * External constants
  97.     XREF    @AllocFib
  98.     XREF    @CleanUp
  99.     XREF    @stpcpy
  100.     XREF    @strcat
  101.     XREF    @strlen
  102.     XREF    baddatestr
  103.     XREF    badtimestr
  104.     XREF    ColonStr
  105.     XREF    datepat
  106.     XREF    dayspermonth
  107.     XREF    DOSBase
  108.     XREF    gwbrstr
  109.     XREF    LSFlags
  110.     XREF    NoFindFmtStr
  111.     XREF    NoRAMMsg
  112.     XREF    RamNameStr
  113.     XREF    SlashStr
  114.     XREF    sortkey
  115.     XREF    timepat
  116.  
  117.     SECTION    CODE
  118. * --------------------------------------------------------------------- *
  119. * VOID *myalloc (LONG)
  120. *   d0            d0
  121. * --------------------------------------------------------------------- *
  122.     XDEF    @myalloc
  123. @myalloc:
  124.     movem.l    d2/a6,-(sp)
  125.     addq.l    #4,d0            ;Include sizeof(LONG)
  126.     move.l    d0,d2            ;Copy to survive AllocMem
  127.     moveq    #0,d1            ;MEMF_ANYTHING
  128.     SYS    AllocMem,4        ;AllocMem(size + 4, 0L)
  129.     tst.l    d0            ;Got it?
  130.      beq.s    1$
  131.     movea.l    d0,a6            ;Copy pointer
  132.     move.l    d2,(a6)+        ;Stash size in first 4 bytes
  133.     move.l    a6,d0            ;return final pointer in d0
  134. 1$
  135.     movem.l    (sp)+,d2/a6
  136.     rts
  137.  
  138. * --------------------------------------------------------------------- *
  139. * VOID myfree (VOID *)
  140. *               a0
  141. * --------------------------------------------------------------------- *
  142.     XDEF    @myfree
  143. @myfree:
  144.     move.l    a6,-(sp)
  145.  
  146.     lea    -4(a0),a1        ;Put in sys reg
  147.     move.l    (a1),d0            ;d0 = size to free
  148.     SYS    FreeMem,4
  149.  
  150.     movea.l    (sp)+,a6
  151.     rts
  152.  
  153. * --------------------------------------------------------------------- *
  154. * void asprintf(wstr, formatstring, args)
  155. *   char *wstr;
  156. *   char *formatstring;
  157. *   char **args;
  158. * 
  159. * Synopsis: Given formatstring and args to format, formats output to wstr.
  160. * Similar to sprintf(), except doesn't handle floats.
  161. * --------------------------------------------------------------------- *
  162.     XDEF    asprintf
  163. asprintf:
  164.     link    a5,#0
  165.     movem.l    d0-d2/a0-a3/a6,-(sp)    ;Save everything we might clobber
  166.  
  167. * Call format function to convert fmtstring and args to buffer on the stack
  168.     movea.l    12(a5),a0        ;Grab format string
  169.     lea    16(a5),a1        ;Grab EA of arguments
  170.     lea    kput1,a2        ;Grab EA of output subroutine
  171.     movea.l    8(a5),a3        ;Grab EA of dest workspace
  172.     SYS    RawDoFmt,4        ;Format it into workspace
  173.  
  174.     movem.l    (sp)+,d0-d2/a0-a3/a6    ;Restore registers
  175.     unlk    a5            ;And stack frame
  176.     rts
  177.  
  178. * --------------------------------------------------------------------- *
  179. * RawDoFmt() output routine for xprintf, called for each formatted char.
  180. * Takes byte in d0 and puts in buffer pointed to by a3, then increments a3.
  181. * --------------------------------------------------------------------- *
  182.     XDEF    kput1
  183. kput1:
  184.     move.b    d0,(a3)+
  185.     rts
  186.  
  187. * --------------------------------------------------------------------- *
  188. * void GetWinBounds(width, height)
  189. *   long *width, *height;
  190. *          a0       a1
  191. * Find current console window, determine width and height
  192. * in terms of current font, update width and height VPARMS passed.
  193. * --------------------------------------------------------------------- *
  194. height    EQU    -4
  195. width    EQU    -8
  196. conid    EQU    -12
  197. packet    EQU    -16
  198. rpport    EQU    -20
  199. rpstr    EQU    -40
  200.  
  201.     XDEF    @GetWinBounds
  202. @GetWinBounds:
  203.     link    a5,#-44
  204.     movem.l    d2-d4/a2/a6,-(sp)
  205.  
  206.     move.l    a0,width(a5)        ;Save width/height pointers on stack
  207.     move.l    a1,height(a5)
  208.  
  209.     SYS    Input,DOSBase(a4)    ;Grab Input filehandle
  210.     move.l    d0,d1
  211.     SYS    IsInteractive        ;IsInteractive(Input())?
  212.     tst.l    d0
  213.      beq.s    gwbnowbrep        ;Nope, can't get a bounds report
  214.     SYS    Output
  215.     move.l    d0,d1
  216.     SYS    IsInteractive        ;IsInteractive(Output())?
  217.     tst.l    d0
  218.      beq.s    gwbnowbrep        ;Nope, don't clutter output stream
  219.  
  220.     suba.l    a1,a1
  221.     SYS    FindTask,4        ;d0 = FindTask(0L), our process
  222.     movea.l    d0,a0            ;Transfer to address reg
  223.     move.l    pr_ConsoleTask(a0),conid(a5) ;Save proc->pr_ConsoleTask
  224.     tst.l    conid(a5)        ;Is there really a console there?
  225.      bne.s    gwbgotcon        ;Yep
  226.  
  227. gwbnowbrep:
  228. * Else we cannot get a window bounds report from this source
  229.     moveq    #23,d1            ;return H=23
  230.     moveq    #77,d2            ;       W=77
  231.     bra    gwbupdate
  232.  
  233. gwbgotcon:
  234.     moveq    #0,d4            ;Clear our success status register
  235.  
  236.     moveq    #0,d0
  237.     movea.l    d0,a0
  238.     jsr    CreatePort
  239.     move.l    d0,rpport(a5)        ;rpport = CreatePort(0L, 0L)
  240.      beq    gwbdone            ;Oops, no signals or ram available!
  241.     moveq    #sp_SIZEOF,d0
  242.     jsr    @myalloc
  243.     move.l    d0,packet(a5)        ;packet = AllocBlock(sizeof(*packet))
  244.      beq    gwbfreeport        ;Oops, no ram, free up port
  245.  
  246. * Okay, we got our process id, reply port, and packet
  247. * Now toggle the console into raw mode
  248.     movea.l    rpport(a5),a2
  249.     movea.l    d0,a1
  250.     movea.l    conid(a5),a0
  251.     moveq    #1,d0
  252.     jsr    SetConsoleType        ;SetConsoleType(1L, conid, packet, rpport)
  253.  
  254. * Request a window bounds report
  255.     SYS    Output,DOSBase(a4)
  256.     move.l    d0,d1
  257.     moveq    #4,d3
  258.     lea    gwbrstr(a4),a0
  259.     move.l    a0,d2
  260.     SYS    Write,DOSBase(a4)    ;Write(Output(), "\2330 q", 4L);
  261.     cmpi.l    #$0004,d0        ;Did the console choke on it?
  262.      bne    gwbsetcook        ;hmmm, see if we can back out gracefully
  263.  
  264. * Read the report string into stack buffer, if there is one
  265.     move.l    #10000,d2
  266.     SYS    Input
  267.     move.l    d0,d1
  268.     SYS    WaitForChar        ;WaitForChar(Input(), 10000L) (.01 secs)
  269.     tst.l    d0            ;Did we get the report?
  270.      beq    gwbsetcook        ;Nope, must not be a report coming
  271.     
  272.     SYS    Input
  273.     move.l    d0,d1
  274.     moveq    #16,d3            ;Don't let it get longer than 16 characters
  275.     lea    rpstr(a5),a0        ;Point to input string area
  276.     move.l    a0,d2
  277.     SYS    Read            ;Read(Input(), rpstr, 16L)
  278.     move.l    d0,d4            ;Save read length while we close shop
  279.  
  280. * Turn the console back to cooked mode pronto to avoid cursor blink
  281. gwbsetcook:
  282.     movea.l    rpport(a5),a2
  283.     movea.l    packet(a5),a1
  284.     movea.l    conid(a5),a0
  285.     moveq    #0,d0
  286.     jsr    SetConsoleType        ;SetConsoleType(0L, conid, packet, rpport)
  287.  
  288. * Release resources we borrowed
  289. gwbfreepack:
  290.     move.l    packet(a5),d0        ;Did we allocate a packet?
  291.      beq.s    gwbfreeport        ;nay, check for port to free
  292.     movea.l    d0,a0
  293.     jsr    @myfree            ;Else FreeBlock(packet)
  294.  
  295. gwbfreeport:
  296.     move.l    rpport(a5),d0        ;if (rpport)...
  297.      beq    gwbdone            ;nope
  298.     jsr    DeletePort        ;Else DeletePort(rpport)
  299.  
  300. * Finally, sanity check window bounds report string
  301. * d4 = length of report string according to Read()
  302.     cmpi.l    #9,d4            ;Less than 8 characters returned?
  303.      ble    gwbdone            ;hmmm, phonky bounds report from DOS?
  304.     lea    rpstr(a5),a2        ;a2 = rpstr
  305.     cmpi.b    #';',4(a2)        ;Matches a typical report template?
  306.      bne    gwbdone            ;nope, got some weird junk back?
  307.     cmpi.b    #'r',-1(a2,d4.w)    ;Last byte is 'r' for report?
  308.      bne    gwbdone            ;Nope, message fubar!
  309.  
  310. * Parse the height and width variables from the field now
  311. * Our report format looks like this in hex:
  312. *     9b 31 3b 31 3b y2 y1 3b x2 x1 20 72
  313. * Or in ascii:
  314. *    <0x9b>1;1;20;77 r
  315. * Which would indicate a width of 77 cols and a height of 20 rows for
  316. * the current console device
  317. *
  318. * REGS:    a2 points to beginning of 'r' terminated string
  319.  
  320.     addq.w    #5,a2            ;Point to first char of Y size
  321.     moveq    #0,d1            ;Clear out work reg
  322.  
  323. * Convert ascii rows value to LONG, update host data
  324.     move.b    (a2)+,d1        ;Grab a Y
  325.     subi.w    #'0',d1            ;Less ascii offset
  326.     cmpi.b    #';',(a2)        ;Any more Y digits?
  327.      beq.s    1$            ;Nope
  328.     mulu    #10,d1            ;Else shift by 10
  329.     add.b    (a2)+,d1        ;Add least significant Y digit
  330.     subi.b    #'0',d1            ;Less ascii offset
  331.     cmpi.b    #';',(a2)        ;Any more Y digits?
  332.      beq.s    1$            ;Nope
  333.     mulu    #$000a,d1        ;Else shift by 10
  334.     add.b    (a2)+,d1        ;Add least significant Y digit
  335.     subi.b    #'0',d1            ;Less ascii offset
  336.                     ;We'll assume screen height < 999 rows    
  337. 1$
  338. * Convert ascii columns value to LONG, update host data
  339.     addq.w    #1,a2            ;Move past the ';' separator
  340.     moveq    #0,d2            ;Zap work reg
  341.     move.b    (a2)+,d2        ;Grab msd of X
  342.     cmpi.b    #' ',d2            ;Premature end?
  343.      beq    gwbdone            ;Huh, must be garbage - don't update VPARMS
  344.     cmpi.b    #';',d2            ;Also a possible error
  345.      beq    gwbdone
  346.     cmpi.b    #'r',d2            ;And what about this?
  347.      beq    gwbdone
  348.  
  349.     subi.b    #'0',d2            ;Okay, adjust ascii offset
  350.     cmpi.b    #' ',(a2)        ;Hit end of report?
  351.      beq.s    2$            ;Yep
  352.     mulu    #$000a,d2        ;Else shift by 10
  353.     add.b    (a2)+,d2        ;Add next digit
  354.     subi.b    #'0',d2            ;Ascii adjust
  355.     cmpi.b    #' ',(a2)        ;Hit end of report?
  356.      beq.s    2$            ;Yep
  357.     mulu    #$000a,d2        ;Else shift by 10
  358.     add.b    (a2),d2            ;Add next digit
  359.     subi.b    #'0',d2            ;Ascii adjust
  360.  
  361. 2$
  362. gwbupdate:
  363. * Finally, update parameters by reference
  364.     movea.l    height(a5),a0        ;Grab height VPARM
  365.     move.l    d1,(a0)            ;*height = d1
  366.     movea.l    width(a5),a0        ;Grab width VPARM
  367.     move.l    d2,(a0)            ;*width = d2
  368.  
  369. gwbdone:
  370.     movem.l    (sp)+,d2-d4/a2/a6
  371.     unlk    a5
  372.     rts
  373.  
  374. * --------------------------------------------------------------------- *
  375. * void __asm SetConsoleType(flag, id, packet, port)
  376. *   register __d0 long flag;
  377. *   register __a0 struct Process *id;
  378. *   register __a1 struct StandardPacket *packet;
  379. *   register __a2 struct MsgPort *port;
  380. *
  381. * Flag = 1L -- Raw mode
  382. *      = 0L -- Cooked mode
  383. * --------------------------------------------------------------------- *
  384.     XDEF    SetConsoleType
  385. SetConsoleType:
  386.     movem.l    a2/a3/a5/a6,-(sp)
  387.  
  388.     movea.l    a0,a3            ;Copy process pointer
  389.     movea.l    a1,a5            ;Copy packet pointer
  390.     lea    sp_Pkt(a5),a0        ;a0 = &packet->sp_Pkt
  391.     move.l    a0,sp_Msg+LN_NAME(a5)    ;p->sp_Msg.mn_Node.ln_Name = &p->sp_Pkt
  392.     lea    sp_Msg(a5),a0        ;a0 = &packet->sp_Msg
  393.     move.l    a0,sp_Pkt+dp_Link(a5)    ;p->sp_Pkt.dp_Link = &p->sp_Msg
  394.     move.l    a2,sp_Pkt+dp_Port(a5)    ;p->sp_Pkt.dp_Port = replyport
  395.     move.l    #ACTION_SCREEN_MODE,sp_Pkt+dp_Type(a5)    ;Set function
  396.  
  397.     tst.w    d0            ;On or Off?
  398.      beq    1$
  399.     move.l    #-1,sp_Pkt+dp_Arg1(a5)    ;RAW ON
  400.     bra.s    2$
  401. 1$
  402.     clr.l    sp_Pkt+dp_Arg1(a5)    ;RAW OFF
  403. 2$
  404.     movea.l    a3,a0
  405.     movea.l    a5,a1
  406.     SYS    PutMsg,4        ;PutMsg(proc, packet)
  407.  
  408.     movea.l    a2,a0
  409.     SYS    WaitPort        ;WaitPort(port)
  410.     movea.l    a2,a0
  411.     SYS    GetMsg            ;(void)GetMsg(port)
  412.  
  413.     movem.l    (sp)+,a2/a3/a5/a6
  414.     rts
  415.  
  416. * ------------------------------------------------------------------------- *
  417. * struct MsgPort *CreatePort(name, pri) (a0/d0)
  418. * ------------------------------------------------------------------------- *
  419.     XDEF    CreatePort
  420. CreatePort:
  421.     movem.l    d5/d7/a2/a5/a6,-(sp)
  422.  
  423.     move.l    a0,a5            ;Save Name
  424.     move.l    d0,d5            ;Save Pri
  425.  
  426. * Allocate a free signal, crap out if we can't
  427.     moveq    #-1,d0
  428.     SYS    AllocSignal,4
  429.     cmp.l    #-1,d0            ;Did we get a signal?
  430.      bne.s    cpgotsig        ;Yep
  431.     moveq    #0,d0            ;Otherwise return NULL
  432.     bra    cpdone
  433.  
  434. cpgotsig:
  435.     move.l    d0,d7            ;Save our signal
  436.  
  437. * Allocate memory for MsgPort
  438.     moveq    #MP_SIZE,d0        ;Size of MsgPort
  439.     jsr    @myalloc        ;Allocate it
  440.     tst.l    d0            ;Did we get it?
  441.      bne.s    cpgotport        ;Yep
  442.  
  443.     move.l    d7,d0            ;Otherwise crap out, free signal
  444.     SYS    FreeSignal
  445.     moveq    #0,d0            ;Return NULL
  446.     bra    cpdone
  447.  
  448. cpgotport:
  449.     move.l    d0,a2            ;This is our new port!
  450.     move.l    a5,LN_NAME(a2)        ;port->mp_Node.ln_Name = name
  451.     move.b    d5,LN_PRI(a2)        ;port->mp_Node.ln_Pri = priority
  452.     move.b    #NT_MSGPORT,LN_TYPE(a2) ;port->mp_Node.ln_Type = NT_MSGPORT
  453.     move.b    #PA_SIGNAL,MP_FLAGS(a2) ;port->mp_Flags = PA_SIGNAL
  454.     move.b    d7,MP_SIGBIT(a2)    ;port->mp_SIGBIT = sigBit
  455.     suba.l    a1,a1
  456.     SYS    FindTask
  457.     move.l    d0,MP_SIGTASK(a2)    ;port->mp_SIGTASK = FindTask(0L)
  458.     
  459.     cmpa.l    #0,a5            ;Is this a new name?
  460.     beq.s    cpnoname        ;Nope, add it to the msg list
  461.  
  462.     movea.l    a2,a1
  463.     SYS    AddPort            ;Otherwise add this port
  464.     move.l    a2,d0            ;Return port pointer
  465.     bra.s    cpdone
  466.  
  467. cpnoname:
  468. * Initialized New List head
  469.     lea    MP_MSGLIST(a2),a0     ;a0 = &port->mp_MsgList
  470.     move.l    a0,(a0)            ;list->lh_Head = list
  471.     addq.l    #4,(a0)            ;list->lh_Head += 4L
  472.     clr.l    4(a0)            ;list->lh_Tail = 0L
  473.     move.l    a0,8(a0)        ;list->lh_TailPred = list
  474.     move.l    a2,d0            ;Return port pointer
  475.  
  476. cpdone:
  477.     movem.l    (sp)+,d5/d7/a2/a5/a6
  478.     rts
  479.  
  480. * ------------------------------------------------------------------------- *
  481. * DeletePort(port)(d0)
  482. * ------------------------------------------------------------------------- *
  483.     XDEF    DeletePort
  484. DeletePort:
  485.     movem.l    a5/a6,-(sp)
  486.  
  487.     move.l    d0,a5
  488.     movea.l    $4,a6
  489.     tst.l    LN_NAME(a5)        ;Is there a name?
  490.     beq.s    dpnoname
  491.     
  492.     move.l    d0,a1
  493.     SYS    RemPort            ;RemPort(port)
  494.     
  495. dpnoname:
  496.     move.b    #$ff,LN_TYPE(a5)     ;port->mp_Node.ln_Type = 0xff
  497.     move.l    #-1,MP_MSGLIST(a5)     ;port->mp_MsgList.lh_Head = -1L
  498.  
  499.     moveq    #0,d0
  500.     move.b    MP_SIGBIT(a5),d0    ;d0 = port->mp_SigBit
  501.     SYS    FreeSignal        ;FreeSignal(d0)
  502.  
  503.     movea.l    a5,a0
  504.     jsr    @myfree            ;FreeBlock(port)
  505.  
  506.     movem.l    (sp)+,a5/a6
  507.     rts
  508.  
  509. * ------------------------------------------------------------------------
  510. * FibFileDate(fib_date, datestr, timestr)
  511. *               a0      a1       8(a5)
  512. *   struct DateStamp *fib_date;
  513. *   char *datestr, *timestr;
  514. *   Calculate date based on DateStamp structure and return a pointer
  515. * to the formatted date string.
  516. * ------------------------------------------------------------------------
  517.     XDEF    @FibFileDate
  518. @FibFileDate:
  519.     link    a5,#0
  520.     movem.l    d3-d7/a2-a3/a6,-(sp)
  521.  
  522.     movea.l    a1,a3            ;a3 = datestr, 8(a5) = timestr
  523.     movea.l    a0,a1            ;Grab datestamp pointer
  524.     moveq    #78,d7            ;Initial year = 1978
  525.  
  526.     move.l    (a1),d5            ;days = fib_date->ds_Days
  527.      blt    ffdbaddate        ;Hey! you can't be negative! Invalid date...
  528.  
  529. * Determine what year it is
  530.     divu    #1461,d5
  531.     move.l    d5,d0            ;Stash it
  532.     ext.l    d5
  533.     lsl.l    #2,d5
  534.     add.l    d5,d7            ;year += (days / 1461) * 4
  535.  
  536. * Count how many months into that year
  537. ffdgetmo:
  538.     swap    d0            ;days %= 1461
  539.     move.w    d0,d5
  540.  
  541. 1$    tst.w    d5            ;Out of days yet?
  542.      beq.s    3$            ;Yep, done here
  543.  
  544.     move.w    #365,d6            ;Else month_days = 365
  545.     move.w    d7,d0            ;Grab year
  546.     andi.w    #3,d0            ;if (year & 3) == 0 Leap year?
  547.      bne.s    2$            ;Nope
  548.     addq.w    #1,d6            ;Otherwise bump month_days
  549.  
  550. 2$    cmp.w    d6,d5            ;is day < month_days?
  551.      blt.s    3$            ;yep, done here
  552.     sub.w    d6,d5            ;otherwise day -= month_days
  553.  
  554.     addq.l    #1,d7            ; year++
  555.     bra    1$
  556. 3$
  557.  
  558. * Count how many days into that month of that year
  559. ffdgetday:
  560. ;for (i = 0, day++; i < 12; i++)
  561.     moveq    #0,d4            ;current month = 0
  562.     moveq    #0,d6            ;Zap hinybs
  563.     addq.w    #1,d5
  564.     lea    dayspermonth(a4),a0
  565.  
  566. 1$
  567.     move.b    0(a0,d4.w),d6        ;month_days = dayspermonth[i]
  568.  
  569.     cmpi.w    #1,d4            ;if (i == 1 && (year & 3) == 0)
  570.      bne.s    2$
  571.     move.w    d7,d0
  572.     andi.w    #3,d0
  573.      bne.s    2$
  574.     addq.w    #1,d6            ;month_days++
  575.  
  576. 2$    cmp.w    d6,d5            ;if (day <= month_days)
  577.      ble.s    4$            ;Break out, found the right month
  578.  
  579.     sub.w    d6,d5            ;Else, day -= month_days
  580.  
  581.     addq.w    #1,d4            ;i++
  582. 3$    cmpi.w    #12,d4            ;Done all months yet?
  583.      blt    1$            ;Nope
  584.  
  585. 4$
  586. ffdprint:
  587. 1$    cmpi.l    #99,d7            ;while (year >= 100)
  588.      ble.s    2$
  589.     subi.l    #100,d7            ;year -= 100
  590.     bra    1$
  591. 2$
  592. ;asprintf(datestr, "%02d-%02d-%02d %02d:%02d:%02d", i + 1, day, year, hour, min, sec)
  593.     move.l    8(a1),d0        ;sec = fib_date->ds_Tick / 50;
  594.     divu    #50,d0
  595.     ext.l    d0
  596.     move.l    d0,-(sp)        ;Push secs
  597.     move.l    4(a1),d0        ;min = fib_date->ds_Minute
  598.     move.l    d0,d1            ;Clone it
  599.     divu    #60,d0
  600.     moveq    #0,d3
  601.     move.w    d0,d3            ;hour = min / 60
  602.     mulu    #60,d0
  603.     sub.w    d0,d1            ;min -= hour * 60
  604.     move.l    d1,-(sp)        ;Push mins
  605.     move.l    d3,-(sp)        ;Push hours
  606.     pea    timepat(a4)        ;Push the format pattern
  607.     move.l    8(a5),-(sp)        ;Push destination buffer, datestr
  608.     jsr    asprintf
  609.     lea    20(sp),sp
  610.  
  611.     move.l    d5,-(sp)        ;Push day
  612.     addq.w    #1,d4            ;Push month (offset by 1!)
  613.     move.l    d4,-(sp)
  614.     move.l    d7,-(sp)        ;Push year
  615.     pea    datepat(a4)        ;Push the format pattern
  616.     move.l    a3,-(sp)        ;Push destination buffer
  617.     jsr    asprintf    
  618.     lea    20(sp),sp
  619.  
  620. ffddone:
  621.     movem.l    (sp)+,d3-d7/a2-a3/a6
  622.     unlk    a5
  623.     rts
  624.  
  625. ffdbaddate:
  626.     lea    badtimestr(a4),a1    ;stpcpy (timestr, "00:00:00");
  627.     movea.l    8(a5),a0
  628.     jsr    @stpcpy
  629.     lea    baddatestr(a4),a1    ;stpcpy (datestr, "00-00-00");
  630.     movea.l    a3,a0
  631.     jsr    @stpcpy
  632.     bra    ffddone
  633.  
  634. *----------------------------------------------------------------------
  635. * LONG iswild(name)
  636. *   char *name;
  637. *          a0
  638. * Search a string for wild characters, return 1 if found
  639. *----------------------------------------------------------------------
  640.     XDEF    @iswild
  641. @iswild:
  642.     moveq    #0,d0            ;Clear out our character register
  643. ischk1:
  644.     move.b    (a0)+,d0        ;Grab a char
  645.      beq.s    iwdone            ;Might be end of string?
  646.     cmpi.b    #'*',d0            ;Is it *?
  647.      beq.s    iswdone            ;yep, is wild
  648.     cmpi.b    #'?',d0            ;Is it a qmark
  649.      bne.s    ischk1            ;Nope, check next character
  650.  
  651. iswdone:
  652.     moveq    #1,d0
  653. iwdone:
  654.     rts
  655.  
  656. * ------------------------------------------------------------------------
  657. ; Compare a wild card name with a normal name
  658. ; LONG wildmatch (name, wild)
  659. ;   char *name, *wild;
  660. ;          a0     a1
  661. * ------------------------------------------------------------------------
  662.     XDEF    @wildmatch
  663. @wildmatch:
  664.     link    a5,#-64
  665.     movem.l    d3/a2-a3,-(sp)
  666.  
  667.     movea.l    a0,a2            ;Grab name
  668.     movea.l    a1,a3            ;Grab pattern
  669.     lea    -64(a5),a0        ;back[0][0]
  670.     lea    -60(a5),a1        ;back[0][1]
  671.  
  672.     moveq    #0,d3            ;bi = 0
  673.  
  674. wmloop1:
  675.     tst.b    (a2)            ;End of name?
  676.      bne.s    wmnoteon
  677.     tst.b    (a3)            ;End of pattern?
  678.      beq    wmmatched        ;Yep, we matched
  679.  
  680. wmnoteon:
  681.     cmpi.b    #'*',(a3)        ;Is it a splat?
  682.      bne.s    wmnotstar        ;Nope, maybe '?'
  683.  
  684.     cmpi.w    #64,d3            ;Have we hit max expression depth?
  685.      beq    wmnomatch        ;Yep, ran out of room in recursion table
  686.  
  687. ;back[bi][0] = w
  688.     move.l    a3,0(a0,d3.w)        ;Stash pointer to this '*' in table
  689.  
  690. ;back[bi][1] = n
  691.     move.l    a2,0(a1,d3.w)
  692.  
  693.     addq.w    #8,d3            ;++bi
  694.     addq.w    #1,a3            ;++w
  695.     bra.s    wmloop1            ;Check next
  696.  
  697. wmgoback:
  698.     subq.w    #8,d3            ;--bi
  699.     move.l    a0,d0
  700. wmback1:
  701.     tst.w    d3            ;while (bi >= 0 && *back[bi][1] == '\x0')
  702.      blt.s    wmbacked
  703.     movea.l    0(a1,d3.l),a0
  704.     tst.b    (a0)
  705.      bne.s    wmbacked
  706.  
  707.     subq.w    #8,d3            ;--bi
  708.     bra.s    wmback1
  709.  
  710. wmbacked:
  711.     tst.w    d3            ;if (bi < 0)
  712.      blt.s    wmnomatch        ;return (0)
  713.  
  714.     movea.l    d0,a0
  715.     movea.l    0(a0,d3.w),a3        ;w = back[bi][0] + 1
  716.     addq.w    #1,a3    
  717.  
  718.     addq.l    #1,0(a1,d3.w)
  719.     movea.l    0(a1,d3.l),a2        ;n = ++back[bi][1]
  720.  
  721.     addq.w    #8,d3            ;++bi
  722.     bra.s    wmloop1
  723.  
  724. wmnotstar:
  725.     cmpi.b    #'?',(a3)        ;Is it '?'
  726.      bne.s    wmnotqmark
  727.  
  728.     tst.b    (a2)            ;Reached end of string?
  729.      bne.s    wmincpoint        ;Nope, move on to next char
  730.  
  731.     tst.w    d3            ;Are we at top level of expression?
  732.      beq.s    wmnomatch        ;Yep, expression didn't match
  733.     bra.s    wmgoback        ;Otherwise pop a level and try to match
  734.  
  735. wmnotqmark:
  736.     move.b    (a2),d0            ;Grab a char from bstr
  737.     cmpi.b    #$40,d0            ;less than @ character?
  738.      bls.s    1$            ;Yep
  739.     cmpi.b    #$5a,d0            ;Greater than Z?
  740.      bhi.s    1$            ;Yep
  741.     addi.b    #$20,d0
  742. 1$
  743.     move.b    (a3),d1            ;Grab a char from bstr
  744.     cmpi.b    #$40,d1            ;less than @ character?
  745.      bls.s    2$            ;Yep
  746.     cmpi.b    #$5a,d1            ;Greater than Z?
  747.      bhi.s    2$            ;Yep
  748.     addi.b    #$20,d1
  749. 2$
  750.     cmp.b    d0,d1            ;*n = *w?
  751.      beq.s    wmincpoint        ;Yep, move on past
  752.  
  753.     tst.w    d3            ;Are we at top expression level?
  754.      beq.s    wmnomatch        ;Yep, they didn't match
  755.     bra.s    wmgoback        ;Nope, process next part
  756.  
  757. wmincpoint:
  758.     tst.b    (a2)            ;Done with name?
  759.      beq.s    wmnamend        ;Yep
  760.     addq.w    #1,a2            ;Otherwise increment name pointer
  761.  
  762. wmnamend:
  763.     tst.b    (a3)            ;End of pattern?
  764.      beq.s    wmmatched        ;Yep, we matched
  765.     addq.w    #1,a3            ;Otherwise inc wild pointer, match next char
  766.     bra    wmloop1
  767.  
  768. wmmatched:
  769.     moveq    #1,d0
  770.     bra.s    wmdone
  771.  
  772. wmnomatch:
  773.     moveq    #0,d0
  774.  
  775. wmdone:
  776.     movem.l    (sp)+,d3/a2-a3
  777.     unlk    a5
  778.     rts
  779.  
  780. * --------------------------------------------------------------------- *
  781. * BOOL CompFibs (keytype, a,   b)
  782. *            d0   a0   a1
  783. *   LONG keytype;
  784. *   struct FileInfoBlock *a, *b;
  785. *
  786. * Used by SortFibs to determine precedence of Fibs.
  787. * keytype is one of 0, 1, or 2:
  788. *   0=alpha, 1=size, 2=date
  789. * --------------------------------------------------------------------- *
  790.     XDEF    @CompFibs
  791. @CompFibs:
  792.     movem.l    d2-d3/a2,-(sp)
  793.  
  794.     move.l    d0,d2            ;Stash keytype
  795.  
  796. * Prioritize Dirs/Files?
  797.     move.l    LSFlags(a4),d3        ;Grab flags
  798.  
  799.     btst.l    #17,d3            ;LSFlags & MIXFILEDIRS?
  800.      bne.s    cftstsort        ;Yep, don't bother comparing EntryTypes
  801.  
  802.     move.l    fib_DirEntryType(a0),d0
  803.     cmp.l    fib_DirEntryType(a1),d0
  804.      blt.s    1$            ;a0 is < a1, (dir < file)
  805.      beq.s    cftstsort        ;a0 is == a1, try next test
  806.  
  807.     moveq    #0,d0            ;a0 is > a1, (file > dir)
  808.     bra.s    2$
  809. 1$
  810.     moveq    #1,d0            ;greater than, (dir < file)
  811.  
  812. 2$    btst.l    #16,d3            ;LSFlags & FILESFIRST?
  813.      beq    cfexit0            ;Nope, default Dirs first
  814.     bchg.l    #0,d0            ;Else d0 ^= 1, reverse sense
  815.     bra    cfexit0
  816.     
  817. * Both entries are the same type, now see about sorting them
  818. cftstsort:
  819.     btst.l    #6,d3            ;LSFlags & NOSORTFLAG set?
  820.      bne    cffalse            ;Yep, always AddTail to list
  821.     
  822. * Switch keytype
  823.     tst.w    d2            ;Alphabetize?
  824.      bne.s    cfnalpha        ;Nope
  825.  
  826. * Compare lexigraphically, ignoring case differences
  827. cfalpha:
  828.     lea    fib_FileName(a0),a0    ;a = &Fipb->fib_FileName
  829.     lea    fib_FileName(a1),a1    ;b = &Fipb->fib_FileName
  830.  
  831. ;  for(; *a && tolower(*a) == tolower(*b); a++, b++);
  832. lccstart:
  833.     tst.b    (a0)            ;Is there a char here at source?
  834.      beq.s    lcceostr        ;Nope, fell off the end
  835.  
  836.     move.b    (a1)+,d1        ;Grab a char from bstr
  837.     cmpi.b    #$40,d1            ;less than @ character?
  838.      bls.s    1$            ;Yep
  839.     cmpi.b    #$5a,d1            ;Greater than Z?
  840.      bhi.s    1$            ;Yep
  841.     addi.b    #$20,d1
  842. 1$
  843.     move.b    (a0)+,d0        ;Grab a char from astr
  844.     cmpi.b    #$40,d0            ;less than @ character?
  845.      bls.s    2$            ;Yep
  846.     cmpi.b    #$5a,d0            ;Greater than Z?
  847.      bhi.s    2$            ;Yep
  848.     addi.b    #$20,d0
  849. 2$
  850.     cmp.b    d0,d1            ;are they the same?
  851.      beq    lccstart        ;Yep, compare next pair of chars
  852.  
  853. lcceostr:
  854.     sub.b    d1,d0            ;return(tolower(*astr) - tolower(*bstr))
  855.      bgt.s    cftrue            ; > 0?, return TRUE
  856.     bra.s    cffalse            ;Else return FALSE
  857.  
  858. cfnalpha:
  859.     subq.w    #1,d2            ;Size?
  860.      bne.s    cfnsize            ;Nope
  861.  
  862. * Compare fib_Sizes
  863.     move.l    fib_Size(a0),d0        ;d0 = afib->fib_Size
  864.     cmp.l    fib_Size(a1),d0        ;b->fib_Size > a->fib_Size?
  865.      bgt.s    cftrue            ;Yep, return TRUE
  866.      blt.s    cffalse            ;<, return FALSE
  867.      bra    cfalpha            ;Else it's a tie, alphabetize
  868.  
  869. cfnsize:
  870. * Compare fib_DateStamps
  871.     lea    fib_DateStamp(a0),a0    ;a = &afib->fib_DateStamp
  872.     lea    fib_DateStamp(a1),a1    ;b = &bfib->fib_DateStamp
  873.     jsr    @CompareDateStamps
  874.     tst.l    d0
  875.      beq    cfalpha            ;its the same date?, alphabetize
  876.      blt.s    cffalse
  877. cftrue:
  878.     moveq    #1,d0
  879.     bra.s    cfexit
  880. cffalse:
  881.     moveq    #0,d0
  882. cfexit:
  883.     btst.l    #9,d3            ;LSFlags & REVFLAG?
  884.      beq.s    1$            ;Nope
  885.     bchg.l    #0,d0            ;Else invert boolean result
  886. 1$
  887. cfexit0:
  888.     movem.l    (sp)+,d2-d3/a2
  889.     rts
  890.  
  891. * --------------------------------------------------------------------- *
  892. * LONG CompareDateStamps(adate, bdate)
  893. *  d0                     a0      a1
  894. *   struct DateStamp *adate, *bdate;
  895. * --------------------------------------------------------------------- *
  896.     XDEF    @CompareDateStamps
  897. @CompareDateStamps:
  898.     move.l    ds_Days(a0),d0        ;d0 = adate->ds_Days
  899.     sub.l    ds_Days(a1),d0        ;b->ds_Days > a->ds_Days?
  900.      bne.s    1$            ;Return b->day - a->day
  901.  
  902. ;They are the same day, check min/tick
  903.     move.l    ds_Minute(a0),d0
  904.     sub.l    ds_Minute(a1),d0    ;d0 = amin - bmin
  905.     muls    #3000,d0        ;     * 3000
  906.     add.l    ds_Tick(a0),d0
  907.     sub.l    ds_Tick(a1),d0        ;     + atick - btick
  908. 1$
  909.     rts
  910.  
  911. * --------------------------------------------------------------------- *
  912. * VOID InsertFibNode(hfib, newfib)
  913. *                     a0     a1
  914. *   struct List *hfib;
  915. *   struct FibEntry *newfib;
  916. *
  917. * Compare data in newfib->Fib with nodes in the list until we
  918. * find the insertion point.
  919. * --------------------------------------------------------------------- *
  920.     XDEF    @InsertFibNode
  921. @InsertFibNode:
  922.     movem.l    d2/a2-a3/a5/a6,-(sp)
  923.  
  924.     move.l    sortkey(a4),d2
  925.     movea.l    a0,a3            ;a3 = hfib
  926.     movea.l    a1,a2            ;a2 = newfib
  927.  
  928.     movea.l    LH_HEAD(a3),a5        ;afib = hfib->lh_Head
  929.  
  930. 1$    tst.l    fe_Node+LN_SUCC(a5)    ;afib->fe_Node.mln_Succ != 0?
  931.      beq.s    4$
  932.  
  933.     movea.l    fe_Fib(a2),a1
  934.     movea.l    fe_Fib(a5),a0
  935.     move.l    d2,d0
  936.     jsr    @CompFibs        ;CompFibs(sortkey, afib->Fib, newfib->Fib)
  937.     tst.w    d0
  938.      bne.s    4$
  939.     movea.l    fe_Node+LN_SUCC(a5),a5    ;afib = afib->fe_Node.mln_Succ
  940.     bra    1$
  941.  
  942. 4$    movea.l    a3,a0            ;a0 = List *
  943.     movea.l    a2,a1            ;a1 = Node *
  944.     movea.l    fe_Node+LN_PRED(a5),a2    ;a2 = Pred *
  945.     SYS    Insert,4        ;Insert(hfib, newfib, afib->fe_Node.mln_Succ)
  946.  
  947.     movem.l    (sp)+,d2/a2-a3/a5/a6
  948.     rts
  949.  
  950. * --------------------------------------------------------------------- *
  951. * LONG FillFibEntry (headfib, fibp)
  952. *               a0      a1          
  953. *   struct List *headfib;
  954. *   struct FileInfoBlock *fibp;
  955. * --------------------------------------------------------------------- *
  956.     XDEF    @FillFibEntry
  957. @FillFibEntry:
  958.     movem.l    a2-a3/a5/a6,-(sp)
  959.     movea.l    a0,a2            ;a2 = head of list
  960.     movea.l    a1,a3            ;a3 = fileinfoblock
  961.  
  962.     jsr    @AllocFib        ;Allocate a new fib
  963.     tst.l    d0            ;Got it?
  964.      beq.s    3$            ;Nope, return 0
  965.     movea.l    d0,a5            ;a5 = tfibp = AllocFib()
  966.  
  967.     move.l    #fib_SIZEOF,d0
  968.     movea.l    fe_Fib(a5),a1
  969.     movea.l    a3,a0
  970.     SYS    CopyMem,4        ;CopyMem(fibp, tfibp->Fib, sizeof(struct fib))
  971.  
  972.     movea.l    a5,a1
  973.     movea.l    a2,a0
  974.  
  975.     jsr    @InsertFibNode        ;InsertFibNode(headfib, tfibp)
  976.  
  977.     moveq    #1,d0            ;return(1)
  978. 3$
  979.     movem.l    (sp)+,a2-a3/a5/a6
  980.     rts
  981.  
  982. * --------------------------------------------------------------------- *
  983.     XDEF    @nullstub
  984. @nullstub:
  985.     moveq    #0,d0
  986.     rts
  987.  
  988. * --------------------------------------------------------------------- *
  989. * LONG GetPathString (dest, src)
  990. *  d0                  a0    a1
  991. *   BYTE *dest, *src;
  992. * --------------------------------------------------------------------- *
  993.     XDEF    @GetPathString
  994. @GetPathString:
  995.     move.l    a2,-(sp)
  996.  
  997.     moveq    #0,d0            ;Zero return dest length
  998.  
  999. * Find end of src string
  1000.     movea.l    a1,a2            ;Save src start address
  1001. 1$    tst.b    (a1)+            ;while (*src++ != 0)
  1002.      bne    1$
  1003.  
  1004. * Work backwards till we find a ':' or a '/'
  1005. 2$    move.b    -(a1),d1        ;c = *(--src)
  1006.     cmpi.b    #':',d1            ;Hit a colon?
  1007.      beq.s    4$            ;Yep, found our path end
  1008.     cmpi.b    #'/',d1            ;Hit a slash?
  1009.      bne.s    3$            ;Nope, try next char
  1010.     cmpa.l    a2,a1            ;At first char?
  1011.      beq.s    4$            ;Yep, leave the single slash
  1012.     cmpi.b    #'/',-1(a1)        ;Next char back is also a '/'?
  1013.      beq.s    4$            ;Yep, allow multiple slashes
  1014.     subq.w    #1,a1            ;Else backup to previous char, eliminate '/'
  1015.     bra.s    4$
  1016. 3$
  1017.     cmpa.l    a2,a1            ;Back at start of src?
  1018.      bhi    2$            ;Nope, try previous src char
  1019.     bra.s    gpsdone            ;Else no dest, return
  1020. 4$
  1021. * Copy path portion to dest
  1022. gpscpy:
  1023.     cmpa.l    a2,a1            ;Past end address?
  1024.      bcs.s    gpsdone            ;Yep, terminate
  1025.     move.b    (a2)+,(a0)+        ;Copy a char from src to dest
  1026.     addq.w    #1,d0            ;Bump dest length count
  1027.     bra    gpscpy            ;Check end address
  1028. gpsdone:
  1029.     clr.b    (a0)            ;Null terminate dest
  1030.  
  1031.     movea.l    (sp)+,a2
  1032.     rts
  1033.  
  1034. * --------------------------------------------------------------------- *
  1035. * LONG GetFileString (dest, src)
  1036. *  d0                  a0    a1
  1037. *   BYTE *dest, *src;
  1038. * --------------------------------------------------------------------- *
  1039.     XDEF    @GetFileString
  1040. @GetFileString:
  1041.     move.l    a2,-(sp)
  1042.  
  1043.     moveq    #0,d0            ;Zero return dest length
  1044.  
  1045. * Find end of src string
  1046.     movea.l    a1,a2            ;Save src start address
  1047. 1$    tst.b    (a1)+            ;while (*src++ != 0)
  1048.      bne    1$
  1049.  
  1050. * Work backwards till we find a ':' or a '/'
  1051. 2$    move.b    -(a1),d1        ;c = *(--src)
  1052.     cmpi.b    #':',d1            ;Hit a colon?
  1053.      beq.s    4$            ;Yep, found our path end
  1054.     cmpi.b    #'/',d1            ;Hit a slash?
  1055.      beq.s    4$            ;Nope, try next char
  1056. 3$
  1057.     cmpa.l    a2,a1            ;Back at start of src?
  1058.      bhi    2$            ;Nope, try previous src char
  1059.     bra.s    gfscpy            ;Else no path, entire src is filename
  1060. 4$
  1061.     addq.w    #1,a1            ;Move past ':' or '/'
  1062.  
  1063. * Copy name portion to dest
  1064. gfscpy:
  1065.     move.b    (a1)+,(a0)+        ;Copy a char from src to dest
  1066.      beq.s    2$
  1067.     addq.w    #1,d0            ;Bump dest length count
  1068.     bra    gfscpy            ;Check end address
  1069. 2$
  1070.     movea.l    (sp)+,a2
  1071.     rts
  1072.  
  1073. * ------------------------------------------------------------------------- *
  1074. * BYTE *astrncpy(dst, src, len)
  1075. * d0/a0          a0   a1    d0
  1076. * Takes text in a1, copies d0 bytes to text in a0.
  1077. * a0 returns pointing to null at end of final text.
  1078. * Dest text is always null terminated.
  1079. * ------------------------------------------------------------------------- *
  1080.     XDEF    @astrncpy
  1081. @astrncpy:
  1082. 1$    subq.l    #1,d0            ;Dec count
  1083.      blt.s    2$            ;Done!
  1084.  
  1085.     move.b    (a1)+,(a0)+        ;Copy a byte
  1086.      bne    1$            ;Do until end of src or cnt < 0
  1087. 2$
  1088.     clr.b    (a0)            ;Null terminate dest
  1089.     move.l    a0,d0            ;Return in d0 also
  1090.     rts
  1091.  
  1092. * ------------------------------------------------------------------------- *
  1093. * VOID amovmem(src, dst, len)
  1094. *              a0    a1   d0
  1095. * Takes text in a0, copies d0 bytes to text in a1. Correctly handles
  1096. * overlapping memory.
  1097. * ------------------------------------------------------------------------- *
  1098.     XDEF    amovmem
  1099. amovmem:
  1100.     cmpa.l    a0,a1            ;Low to high or high to low?
  1101.      bcs.s    2$            ;High to low, copy forward
  1102.     adda.w    d0,a0            ;Else start at end, copy backward
  1103.     adda.w    d0,a1
  1104.  
  1105. 1$    move.b    -(a0),-(a1)
  1106.     subq.w    #1,d0
  1107.      bgt    1$
  1108.     bra.s    amdone
  1109.  
  1110. 2$    move.b    (a0)+,(a1)+
  1111.     subq.w    #1,d0
  1112.      bgt    2$
  1113. amdone:
  1114.     rts
  1115.  
  1116. * --------------------------------------------------------------------- *
  1117. * BYTE *aindex(BYTE *, BYTE);
  1118. *  d0           a0      d0
  1119. * --------------------------------------------------------------------- *
  1120.     XDEF    @aindex
  1121. @aindex:
  1122. 1$    cmp.b    (a0),d0
  1123.      beq.s    aifound
  1124.     tst.b    (a0)+
  1125.      beq.s    ainomatch
  1126.     bra    1$
  1127.  
  1128. ainomatch:
  1129.     moveq    #0,d0
  1130.     rts
  1131.  
  1132. aifound:
  1133.     move.l    a0,d0
  1134.     rts
  1135.  
  1136. * --------------------------------------------------------------------- *
  1137. * LONG MakePathString(lock, dest)
  1138. *                      a0     a1
  1139. *   struct FileLock *lock;
  1140. *   BYTE *dest;
  1141. *
  1142. * DESCRIPTION:
  1143. *   Given text and a filelock, construct entire pathname and
  1144. * return in dest.
  1145. * --------------------------------------------------------------------- *
  1146.     XDEF    @MakePathString
  1147. @MakePathString:
  1148.     movem.l    d2-d5/d7/a2-a3/a6,-(sp)
  1149.  
  1150. * Grab pointer to lock and dest text to fill
  1151.     move.l    a0,d3            ;d3 = lock
  1152.     movea.l    a1,a2            ;a2 = dest
  1153.     clr.b    (a2)            ;NULL terminate dest
  1154.     moveq    #0,d5            ;LockFlag = 0
  1155.  
  1156. * Allocate a FileInfoBlock for local use
  1157.     move.l    #fib_SIZEOF,d0
  1158.     jsr    @myalloc
  1159.     move.l    d0,d7            ;d7 = *fib
  1160.      beq    mpsfailed        ;Whoops no mem? return!
  1161.  
  1162.     movea.l    DOSBase(a4),a6        ;DOSBase calls from here on
  1163.  
  1164. * while (lock != 0)
  1165. 1$
  1166.     tst.l    d3            ;Got a lock?
  1167.      beq.s    mpsokay            ;Nope, must be at root
  1168.  
  1169. * Examine the current lock
  1170.     move.l    d3,d1
  1171.     move.l    d7,d2
  1172.     SYS    Examine            ;Examine(lock, fib)
  1173.     tst.l    d0            ;Okay?
  1174.      beq.s    mpsfailed        ;Nope, some sort of dos failure?
  1175.  
  1176.     movea.l    d7,a1
  1177.     cmpi.b    #' ',fib_FileName(a1)    ;if (fib->fib_FileName[0] >= ' ')
  1178.      bcs.s    3$            ;Nope, don't bother inserting?
  1179.  
  1180.     tst.b    (a2)            ;if (dest[0] != 0)
  1181.      beq.s    2$
  1182.     lea    SlashStr(a4),a1
  1183.     movea.l    a2,a0
  1184.     jsr    @InsertPathString    ;InsertPathString(dest, "/");
  1185. 2$
  1186.     movea.l    d7,a1
  1187.     lea    fib_FileName(a1),a1
  1188.     movea.l    a2,a0
  1189.     jsr    @InsertPathString    ;InsertPathString(dest, fib->fib_FileName)
  1190. 3$
  1191. * Okay, move up one directory
  1192.     move.l    d3,d4            ;oldlock = lock
  1193.  
  1194.     move.l    d3,d1
  1195.     SYS    ParentDir
  1196.     move.l    d0,d3            ;lock = ParentDir(lock)
  1197.  
  1198.     tst.w    d5            ;LockFlag set?
  1199.      bne.s    4$            ;Yep, unlock
  1200.     moveq    #1,d5            ;Else LockFlag = 1, unlock next time
  1201.      bra    1$            ;Next directory up
  1202. 4$
  1203.     move.l    d4,d1
  1204.     SYS    UnLock            ;UnLock(oldlock)
  1205.     bra    1$            ;Examine
  1206.  
  1207. mpsokay:
  1208. * See if root was RAM:, special case
  1209.     movea.l    d7,a1            ;a1 = fib
  1210.     cmpi.b    #' ',fib_FileName(a1)    ;if (fib->fib_FileName[0] >= ' ')
  1211.      bcc.s    1$            ;Yep, not 1.1/1.2 RAM:
  1212.     lea    RamNameStr(a4),a1    ;Else...
  1213.     movea.l    a2,a0
  1214.     jsr    @InsertPathString    ;InsertPathString(dest, "RAM:")
  1215.     bra.s    mpsdone
  1216. 1$
  1217. * Find last slash we tacked on, change to a colon, or, add a colon
  1218.     moveq    #'/',d0
  1219.     movea.l    a2,a0
  1220.     jsr    @aindex            ;d0 = strchr(dest, '/')
  1221.     tst.l    d0            ;Do we have a slash?
  1222.      beq.s    2$            ;Nope, at root....
  1223.     movea.l    d0,a0
  1224.     move.b    #':',(a0)        ;Else change first '/' to a ':'
  1225.     bra.s    mpsdone
  1226.  
  1227. * No slash, must be locked at the root.  Append a colon to the dest.
  1228. 2$
  1229.     lea    ColonStr(a4),a1    
  1230.     movea.l    a2,a0
  1231.     jsr    @strcat            ;strcat (dest, ":")
  1232.     bra.s    mpsdone
  1233.  
  1234. * Come here if an error occured, return empty text to caller
  1235. mpsfailed:
  1236.     clr.b    (a2)            ;dest[0] = (BYTE)0
  1237.     moveq    #0,d3            ;return (0L)
  1238.     bra.s    mpsdeall
  1239.  
  1240. * Come here if everything is okay, deallocate FileInfoBlock
  1241. mpsdone:
  1242.     moveq    #1,d3            ;return (1L)
  1243.  
  1244. mpsdeall:
  1245.     tst.l    d7            ;Did we allocate a fib?
  1246.      beq.s    mpsfinis        ;nope
  1247.     movea.l    d7,a0            ;Else free the memory
  1248.     jsr    @myfree
  1249.  
  1250. mpsfinis:
  1251.     move.l    d3,d0            ;Put return value in d0
  1252.     movem.l    (sp)+,d2-d5/d7/a2-a3/a6
  1253.     rts
  1254.  
  1255. * --------------------------------------------------------------------- *
  1256. * VOID InsertPathString(dest, source)
  1257. *                        a0     a1
  1258. *   BYTE *dest, *source;
  1259. *
  1260. * DESCRIPTION:
  1261. *   Insert source text into dest text.
  1262. * Special case for source length == 0, source must be RAM.
  1263. * --------------------------------------------------------------------- *
  1264.     XDEF    @InsertPathString
  1265. @InsertPathString:
  1266.     movem.l    d7/a2-a3,-(sp)
  1267.  
  1268.     movea.l    a1,a3            ;a3 = source
  1269.     move.l    a0,a2            ;a2 = dest
  1270.  
  1271.     movea.l    a3,a0
  1272.     jsr    @strlen
  1273.     move.l    d0,d7            ;d7 = strlen(source)
  1274.  
  1275. 1$    movea.l    a2,a0
  1276.     jsr    @strlen            ;d0 = strlen(dest)
  1277.  
  1278.     addq.w    #1,d0            ;Bump the length to include zero byte at end
  1279.     movea.l    a2,a1
  1280.     adda.w    d7,a1            ;Push dest + slen
  1281.     movea.l    a2,a0            ;Push dest
  1282.     jsr    amovmem            ;amovmem(dest, dest + slen, strlen(dest) + 1)
  1283.  
  1284.     move.w    d7,d0
  1285.     movea.l    a2,a1
  1286.     movea.l    a3,a0
  1287.     jsr    amovmem            ;amovmem(source, dest, slen)
  1288.  
  1289.     movem.l    (sp)+,d7/a2-a3
  1290.     rts
  1291.  
  1292. * --------------------------------------------------------------------- *
  1293. * VOID NoMemExit(VOID)
  1294. * --------------------------------------------------------------------- *
  1295.     XDEF    @NoMemExit
  1296. @NoMemExit:
  1297.     moveq    #103,d1
  1298.     moveq    #20,d0
  1299.     lea    NoRAMMsg(a4),a0
  1300.     jsr    @CleanUp
  1301.     rts
  1302.  
  1303. * --------------------------------------------------------------------- *
  1304. * VOID NoFileExit(name)
  1305. *                  a0
  1306. * BYTE *name;
  1307. * --------------------------------------------------------------------- *
  1308.     XDEF    @NoFileExit
  1309. @NoFileExit:
  1310.     movem.l    d2-d4/a6,-(sp)
  1311.  
  1312.     move.l    a0,d2            ;Save name
  1313.     SYS    IoErr,DOSBase(a4)    ;Get IoError status
  1314.     move.l    d0,d3            ;Save it
  1315.  
  1316.     move.l    #300,d0
  1317.     jsr    @myalloc
  1318.     move.l    d0,d4            ;d3 = myalloc( 300 )
  1319.      bne.s    1$            ;Got it!
  1320.     jsr    @NoMemExit        ;else exit with No Ram message
  1321.     bra.s    2$
  1322. 1$
  1323.     move.l    d2,-(sp)
  1324.     pea    NoFindFmtStr(a4)
  1325.     move.l    d4,-(sp)
  1326.     jsr    asprintf        ;asprintf(tstr, NoFindFmtStr, name)
  1327.     lea    12(sp),sp
  1328.  
  1329.     move.l    d3,d1
  1330.     moveq    #20,d0
  1331.     movea.l    d4,a0
  1332.     jsr    @CleanUp        ;CleanUp(tstr, 20L, IoErr())
  1333.                     ;         a0   d0     d1
  1334.     move.l    d4,a0
  1335.     jsr    @myfree            ;free (tstr)
  1336. 2$
  1337.     movem.l    (sp)+,d2-d4/a6
  1338.     rts
  1339.  
  1340. * --------------------------------------------------------------------- *
  1341.     END
  1342. * --------------------------------------------------------------------- *
  1343.