home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib38a.dsk / MAY.1990 / HYPER.RES.DEMO.bas < prev   
BASIC Source File  |  2023-02-26  |  3KB  |  66 lines
  1. 10  REM  *************************
  2. 20  REM  * HYPER.RES.DEMO        *
  3. 30  REM  * BY Alvin Tutas        *
  4. 40  REM  * Copyright(c) 1990     *
  5. 50  REM  * MindCraft Publ. Corp. *
  6. 60  REM  * Concord, MA 01742     *
  7. 70  REM  *************************
  8. 80  NOTRACE : PRINT  CHR$(17): SPEED= 255: HOME : TEXT : IF  PEEK(1014) = 90  AND  PEEK(1015) = 148  THEN  RUN 130
  9. 90  READ T$: ONERR  GOTO 110
  10. 100  PRINT  CHR$(4)"BRUN"T$: POKE 216,0: RUN 130
  11. 110  PRINT  CHR$(7)"FILE" SPC( 1) CHR$(34)T$ CHR$(34) SPC( 1)"DID NOT LOAD." SPC( 2)
  12. 120  PRINT "BYE!": END 
  13. 130  VTAB 21: CALL  -958: READ T$: READ A$: PRINT : HTAB 6: INVERSE : PRINT T$: VTAB 22: HTAB 28: PRINT A$: NORMAL 
  14. 140  REM 
  15. 150  REM  SELECT WHITE
  16. 160  REM 
  17. 170  &  HCOLOR= 3: HCOLOR= 3:K = 158: GOSUB 560
  18. 180  REM 
  19. 190  REM  RANDOM POINTS
  20. 200  REM 
  21. 210  FOR J = 1 TO 50: &  HPLOT  RND(J) *278, RND(J) *K: NEXT 
  22. 220  FOR J = 1 TO 50: HPLOT  RND(J) *138 +142, RND(J) *K: NEXT 
  23. 230  READ A$: GOSUB 570: GOSUB 560
  24. 240  REM 
  25. 250  REM  SOME RAYS
  26. 260  REM 
  27. 270  FOR J = 0 TO 144  STEP 24: &  HPLOT 20,150 TO 260,150 -J: NEXT 
  28. 280  FOR J = 30 TO 240  STEP 35: &  HPLOT 20,150 TO 260 -J,0: NEXT 
  29. 290  FOR J = 0 TO 144  STEP 24: HPLOT 150,150 TO 270,150 -J: NEXT 
  30. 300  FOR J = 15 TO 120  STEP 17.5: HPLOT 150,150 TO 270 -J,0: NEXT 
  31. 310  READ A$: GOSUB 570: GOSUB 560
  32. 320  REM 
  33. 330  REM  TWO PARABOLAS
  34. 340  REM 
  35. 350  FOR J =  -75 TO 75: &  HPLOT 80 +J *J/50,J +75: NEXT 
  36. 360  FOR J =  -75 TO 75: HPLOT 180 +J *J/100,J +75: NEXT 
  37. 370  READ A$: GOSUB 570:K = 130: GOSUB 560
  38. 380  REM 
  39. 390  REM  PASS HI-RES AN ENDPOINT
  40. 400  REM 
  41. 410  GOSUB 420: GOTO 440
  42. 420  &  HPLOT 0,150 TO 70,0 TO 140,150 TO 210,0 TO 280,150
  43. 430  HPLOT  TO 175,0 TO 210,150 TO 245,0 TO 279,150: RETURN 
  44. 440  READ A$:A$ = T$ + CHR$(32) +A$: GOSUB 570
  45. 450  READ A$: GOSUB 570
  46. 460  REM 
  47. 470  REM  SELECT BLACK AND ERASE
  48. 480  REM 
  49. 490  &  HCOLOR= 0: HCOLOR= 0: GOSUB 420
  50. 500  READ A$:A$ = T$ + CHR$(32) +A$: GOSUB 570
  51. 510  REM 
  52. 520  REM  DEMO OVERHEAD
  53. 530  REM 
  54. 540  READ A$: GOSUB 570: IF A$ = "R"  OR A$ = "r"  THEN  RUN 130
  55. 550  HOME : TEXT : GOTO 120
  56. 560  HGR : &  HPLOT 280,0 TO 280,K: &  HPLOT 0,159 TO 559,159: RETURN 
  57. 570 A$ = ">" + CHR$(32) +A$ + CHR$(32) +"<": VTAB 24: PRINT  TAB( 21 - LEN(A$)/2)A$ SPC( 2): GET A$: HTAB 1: CALL  -958: RETURN 
  58. 580  DATA  "HYPER.RES"
  59. 590  DATA  "HI-RES"
  60. 600  DATA  "PLOT POINTS"
  61. 610  DATA  "DRAW LINES"
  62. 620  DATA  "TRACE CURVES"
  63. 630  DATA  "PASSES ITS ENDPOINT!"
  64. 640  DATA  "COMPARE THE RESOLUTION"
  65. 650  DATA  "ERASES, TOO!"
  66. 660  DATA  "QUIT OR REPEAT (Q/R)?"