home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib33b.dsk / METEOROIDS.EXP.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  60 lines
  1. 10  REM  **********************
  2. 20  REM  * METEROIDS.EXP      *
  3. 30  REM  * BY DANIEL JOYNT    *
  4. 40  REM  * COPYRIGHT (C) 1988 *
  5. 50  REM  * BY MICROSPARC, INC *
  6. 60  REM  * CONCORD, MA  01742 *
  7. 70  REM  **********************
  8. 80  FOR Y = 768 TO 826
  9. 90  READ K: POKE Y,K: NEXT Y
  10. 100  REM 
  11. 110  REM  SHAPE TABLE ADDRESS
  12. 120  REM 
  13. 130  POKE 232,34: POKE 233,3
  14. 140  REM 
  15. 150  REM  SET SHAPE PARAMETERS
  16. 160  REM 
  17. 170  ROT= 0: SCALE= 1
  18. 180  REM 
  19. 190  REM  CLEAR SCREEN
  20. 200  REM 
  21. 210  HGR : HCOLOR= 3
  22. 220  HOME : VTAB 22
  23. 230  PRINT "(A) UP"
  24. 240  PRINT "(Z) DOWN"
  25. 250  REM 
  26. 260  REM  INITIALIZE VARIABLES
  27. 270  REM 
  28. 280 Y = 120:S = Y:L = 159
  29. 290  REM 
  30. 300  REM  MAIN LOOP
  31. 310  REM 
  32. 320 K =  PEEK(49152):Y = Y +(K = 218) -(K = 193):Q =  PEEK(49200): DRAW 2 AT 278, RND(1) *S:S = S -.25 *(S >0):N = S + RND(1) *40: HPLOT 272,L TO 279,N:L = N: CALL 768: DRAW 1 AT 3,Y: ON   NOT  PEEK(234) GOTO 320
  33. 330  REM 
  34. 340  REM  PRINT SCORE
  35. 350  REM 
  36. 360  HOME : VTAB 21
  37. 370  PRINT "SCORE: ";
  38. 380  PRINT (120 -S) *100
  39. 390  PRINT 
  40. 400  PRINT "ANOTHER GAME (Y/N)";
  41. 410  POKE  -16368,0
  42. 420  INPUT A$
  43. 430 A$ =  LEFT$(A$,1)
  44. 440  IF A$ = "Y"  THEN 210
  45. 450  REM 
  46. 460  REM  SCROLL ROUTINE DATA
  47. 470  REM 
  48. 480  DATA  169,32,133,39,162,0
  49. 490  DATA  134,38,160,0,200,177
  50. 500  DATA  38,136,145,38,200
  51. 510  DATA  192,39,208,245,169,0
  52. 520  DATA  145,38,32,4,245,232
  53. 530  DATA  224,160,208,231,96
  54. 540  REM 
  55. 550  REM  SHAPES DATA
  56. 560  REM 
  57. 570  DATA  2,0,6,0,15,0
  58. 580  DATA  28,63,14,190,45,45
  59. 590  DATA  44,37,0,63,56,36
  60. 600  DATA  12,45,21,23,21,4,0