home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib33b.dsk
/
HUNGRY.DOT.DEMO.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
1KB
|
41 lines
10 POKE 768,1: POKE 769,0: POKE 770,4
20 POKE 771,0: POKE 772,4: POKE 773,0
30 POKE 232,0: POKE 233,3: REM $E8,E9=$300
40 REM SET UP SCREEN
50 HGR : ROT= 0: SCALE= 1
60 POKE -16302,0: REM FULL SCREEN DISPLAY
70 HCOLOR= 3: HPLOT 0,0: REM PLOT A POINT
80 CALL 62454: REM CLEAR TO COLOR
90 HCOLOR= 0
100 FOR Y = 56 TO 136: REM ERASE CENTER
110 HPLOT 80,Y TO 200,Y
120 NEXT Y
130 REM DRAW BORDER
140 HPLOT 0,0 TO 279,0 TO 279,191 TO 0,191 TO 0,0
150 HPLOT 3,3 TO 276,3 TO 276,188 TO 3,188 TO 3,3
160 HPLOT 4,4 TO 275,4 TO 275,187 TO 4,187 TO 4,4
170 HCOLOR= 3
180 REM SET UP SHAPES & VELOCITIES
190 FOR I = 1 TO 25: REM DRAW 'STARS'
200 X = 120 - RND(1) *120 +80
210 Y = 80 - RND(1) *80 +56
220 HPLOT X,Y
230 NEXT I
240 XV = 1:YV = 1:X = 140:Y = 96
250 ONERR GOTO 390
260 REM MOVE IT AROUND
270 XDRAW 1 AT X,Y
280 YV = YV +.005: REM 'GRAVITY'
290 IF PEEK( -16384) >127 THEN TEXT : END
300 IF PEEK(234) = 0 THEN 340: REM COLLISION
310 XDRAW 1 AT X,Y
320 X = X +XV:Y = Y +YV
330 GOTO 260
340 REM RE-CALC VELOCITY
350 XV = 1 - RND(1) *2: IF ABS(XV) <.5 THEN XV = XV *2
360 YV = 1 - RND(1) *2: IF ABS(YV) <.5 THEN YV = YV *2
370 S = PEEK( -16336) + PEEK( -16336) + PEEK( -16336)
380 GOTO 260
390 REM BOUNDARY COLLISION ('ILLEGAL QTY ERROR')
400 X = 140:Y = 96
410 GOTO 260