home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib31b.dsk / SIMPLE.SPELLER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  59 lines
  1. 1  REM  ************************
  2. 2  REM  * SIMPLE.SPELLER       *
  3. 3  REM  * BY ROB SMYTHE        *
  4. 4  REM  * COPYRIGHT (C) 1987   *
  5. 5  REM  * BY MICROSPARC, INC.  *
  6. 6  REM  * CONCORD, MA  01742   *
  7. 7  REM  ************************
  8. 100  HOME : PRINT  TAB( 6)"S I M P L E   S P E L L E R"
  9. 110  PRINT : PRINT  TAB( 6)"===========================": PRINT  TAB( 3)"COPYRIGHT 1987 BY MICROSPARC, INC."
  10. 120  DIM W$(100): REM  MAXIMUM # WORDS
  11. 130 G$ =  CHR$(7): REM  MAKE IT CHR$(0) IF YOU DON'T WANT SOUND
  12. 140 :
  13. 150  REM  READ IN WORDS FROM LIST
  14. 160  REM  MAKE LAST WORD "QUIT"
  15. 170 :
  16. 180 I = I +1: READ W$(I): IF W$(I) < >"QUIT"  THEN 180
  17. 190 N = I: REM  N=NUMBER OF WORDS
  18. 200 :
  19. 210  REM  ** START NEW WORD **
  20. 220 :
  21. 230  VTAB 10: HTAB 15: CALL  -958
  22. 240 COUNT = 1:N$ = "":W = 0
  23. 250  GET A$: REM  KEYPRESS
  24. 260  IF A$ = "?"  OR A$ = "/"  THEN A$ =  MID$ (W$(W),COUNT,1): REM  HINT
  25. 270 :
  26. 280  REM  CHECK EACH WORD FOR MATCH
  27. 290 :
  28. 300 NN$ = N$ +A$: REM  TRIAL PARTIAL WORD
  29. 310  FOR I = 1 TO N: REM  FOR EACH WORD...
  30. 320 LT$ =  LEFT$(W$(I),COUNT): REM  TARGET PARTIAL WORD
  31. 330  IF NN$ < >LT$  THEN  NEXT I: GOTO 250: REM  NO MATCH - TRY AGAIN
  32. 340 :
  33. 350  REM  A$ MAKES A POSSIBLE WORD
  34. 360 :
  35. 370 W = I: REM  REMEMBER WHICH POSSIBLE WORD
  36. 380  PRINT G$A$" ";:N$ = N$ +A$:J = I:I = N: NEXT I
  37. 390  IF COUNT =  LEN(W$(J))  THEN 440: REM  END OF A WORD?
  38. 400 COUNT = COUNT +1: GOTO 250: REM  GET NEXT LETTER
  39. 410 :
  40. 420  REM  WORD IS COMPLETE
  41. 430 :
  42. 440  PRINT G$G$G$G$: VTAB 10: HTAB 15: CALL  -958: FOR I = 1 TO 300: NEXT : VTAB 10: HTAB 15
  43. 450  FOR I = 1 TO COUNT: PRINT  MID$ (W$(J),I,1);G$;" ";
  44. 460  FOR K = 1 TO 200: NEXT 
  45. 470  NEXT I
  46. 480  FOR K = 1 TO 2000: NEXT 
  47. 490  IF J < >N  THEN 230: REM  LAST WORD?
  48. 500  VTAB 10: HTAB 12: PRINT "G O O D - B Y E"
  49. 510  VTAB 20: END 
  50. 520 :
  51. 530 :
  52. 540  REM  PUT WORDS HERE.
  53. 550  REM  MAKE LAST WORD "QUIT"
  54. 560 :
  55. 570  DATA  DADDY,MOMMY,DEBBIE,DUSTY,LESLEY,RYAN,GRAMMA,GRAMPA,NANA
  56. 580  DATA  SANDRA,JENNIFER,JILLIAN,DOG,BABY,CAT
  57. 590  DATA  CAR,GOOD,BOOK,HE,SHE,LOOK,HERE,MAT,HAT,SAT,AT,THE
  58. 600  DATA  IS,AM,YOU,WE,ME,MY,HUG
  59. 610  DATA  QUIT