home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib31a.dsk
/
JUNE.1987
/
MOUSEPOINTER.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
59 lines
1 REM ************************
2 REM * MOUSEPOINTER *
3 REM * BY KEVIN GARBELMAN *
4 REM * COPYRIGHT (C) 1987 *
5 REM * BY MICROSPARC, INC. *
6 REM * CONCORD, MA 01742 *
7 REM ************************
10 GOSUB 500: REM SET UP MOUSE
20 GOSUB 250: REM PRINT A SCREEN
30 GOSUB 70: REM GET A READING
40 GOSUB 400: REM ACT ON READING
50 GOTO 20
60 REM MOUSE ROUTINE
70 OL = 160:OD = 2039
80 PRINT CHR$(4);"IN#4"
90 VTAB 1: HTAB 40: INPUT "";MX,MY,MB
100 PRINT CHR$(4);"IN#0"
110 MY = INT(MY/6) +1
120 MX = INT(MX/4) +1
130 IF MY >24 THEN MY = 24
140 IF MX >40 THEN MX = 40
150 IF MB = 2 OR MB = -2 THEN FOR I = 1 TO 5:DU = PEEK(49200): NEXT : GOTO 220
160 POKE OD,OL
170 PK = 128 *MY +MX -(984 * INT((MY -1)/8)) +895
180 OL = PEEK(PK)
190 OD = PK
200 POKE PK,170
210 GOTO 80
220 RETURN
230 REM END OF GET MOUSE
240 REM PRINT A SCREEN
250 HOME
260 VTAB 1: PRINT "MOUSEPOINTER"
270 VTAB 2: PRINT "BY KEVIN GARBELMAN": PRINT "COPYRIGHT 1987 MY MICROSPARC, INC."
280 VTAB 6: HTAB 5: PRINT " OPTION # 1 "
290 VTAB 8: HTAB 5: PRINT " OPTION # 2 "
300 VTAB 10: HTAB 5: PRINT " OPTION # 3 OPTION # 4"
310 REM <10SPACES>
320 VTAB 18: HTAB 4: PRINT "INSTRUCTIONS:"
330 VTAB 19: HTAB 4: PRINT "MOVE THE MOUSE TO POSITION THE"
340 VTAB 20: HTAB 4: PRINT "CURSOR OVER AN OPTION AND PRESS"
350 VTAB 21: HTAB 4: PRINT "THE MOUSE BUTTON. THE 'FINISHED'"
360 VTAB 22: HTAB 4: PRINT "OPTION BELOW WILL END THE PROGRAM."
370 VTAB 24: HTAB 5: PRINT "FINISHED";
380 RETURN
390 REM DEAL WITH READING
400 HOME : VTAB 12: HTAB 1: PRINT " NO OPTION CHOSEN"
410 IF MY = 6 THEN VTAB 12: PRINT " YOU CHOSE OPTION # 1"
420 IF MY = 8 THEN VTAB 12: PRINT " YOU CHOSE OPTION # 2"
430 IF MY = 10 AND MX <20 THEN VTAB 12: PRINT " YOU CHOSE OPTION # 3"
440 IF MY = 10 AND MX >19 THEN VTAB 12: PRINT " YOU CHOSE OPTION # 4"
450 IF MY = 24 THEN HOME : VTAB 12: PRINT "GOODBYE": END
460 VTAB 18: HTAB 5: PRINT "PUSH THE BUTTON TO RETURN"
470 GOSUB 70
480 RETURN
490 REM ********* MOUSE SET UP *********
500 PRINT CHR$(4);"PR#4": PRINT CHR$(1)
510 PRINT CHR$(4);"PR#0"
520 RETURN