home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib30a.dsk
/
JANUARY.1987
/
MOVE.DEMO.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
49 lines
10 REM ************************
20 REM * MOVE.DEMO *
30 REM * BY STEVEN BIRGE *
40 REM * COPYRIGHT (C) 1987 *
50 REM * BY MICROSPARC, INC. *
60 REM * CONCORD, MA 01742 *
70 REM ************************
80 HIMEM: 37376: REM $9200 BELOW DATA BUFFER
90 ONERR GOTO 490
100 PRINT CHR$(4);"BLOAD MOVE": REM PLACE MACHINE LANGUAGE ROUTINE AT $300
110 POKE 216,0: TEXT : HOME : NORMAL : PRINT "MOVE DEMO": PRINT "BY STEVEN BIRGE": PRINT "COPYRIGHT 1987 BY MICROSPARC, INC.": POKE 34,5
120 VTAB 10: PRINT "CREATING DEMO FILE, PLEASE WAIT..."
130 REM CREATE DEMO FILE
140 PRINT CHR$(4);"OPEN TEST.FILE"
150 PRINT CHR$(4);"CLOSE TEST.FILE"
160 PRINT CHR$(4);"DELETE TEST.FILE"
170 PRINT CHR$(4);"OPEN TEST.FILE"
180 PRINT CHR$(4);"WRITE TEST.FILE"
190 FOR J = 0 TO 25
200 E$ = CHR$(J +65): REM E$=EACH LETTER OF ALPHABET
210 FOR K = 1 TO 10: PRINT E$;
220 NEXT K,J
230 PRINT : PRINT "IT WORKS!"
240 PRINT CHR$(4);"CLOSE"
250 REM TEST POSITION COMMAND
260 HOME : PRINT "NOW TESTING POSITION COMMAND"
270 PRINT CHR$(4);"OPEN TEST.FILE"
280 PRINT CHR$(4);"POSITION TEST.FILE,F1"
290 PRINT CHR$(4);"READ TEST.FILE"
300 INPUT A$
310 PRINT CHR$(4);"CLOSE"
320 PRINT : PRINT A$: PRINT : FOR X = 1 TO 2000: NEXT
330 REM TEST MOVE ROUTINES
340 PRINT : PRINT "NOW TESTING MOVE ROUTINES": PRINT
350 N$ = "/NIBBLE.1987/JANUARY.1987/TEST.FILE": REM N$ MUST CONTAIN THE FULL PATHNAME FOR THE FILE
360 POKE 774, LEN(N$): REM PUT LENGTH OF PATHNAME AT $306
370 FOR N = 1 TO LEN(N$)
380 POKE 774 +N, ASC( RIGHT$(N$, LEN(N$) -N +1)): REM PUT N$ IN $307 ON
390 NEXT
400 CALL 851: REM $353 OPEN FILE
410 CALL 877: CALL 877: REM READ AFTER FIRST CR
420 E = 0:A$ = ""
430 E$ = CHR$( PEEK(37376 +E)): REM READ CHARACTER
440 IF E$ = CHR$(13) THEN 460: REM CR
450 A$ = A$ +E$:E = E +1: GOTO 430
460 CALL 888: REM CLOSE FILE
470 PRINT A$
480 TEXT : VTAB 20: END
490 HOME : VTAB 7: PRINT "THIS PROGRAM REQUIRES THE BINARY FILE": PRINT "'MOVE' TO BE ON THE SAME DISK": END