home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib25a.dsk / JULY.1985 / DECISION.MAKER.bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  46 lines
  1. 10  REM  *************************
  2. 20  REM  *    DECISION.MAKER     *
  3. 30  REM  * BY BEIRNE L. KONARSKI *
  4. 40  REM  * COPYRIGHT (C) 1985    *
  5. 50  REM  * BY MICROSPARC, INC.   *
  6. 60  REM  * CONCORD, MA  01742    *
  7. 70  REM  *************************
  8. 80  REM 
  9. 90  REM  **********************
  10. 100  REM   CHOOSE PRIORITIES
  11. 110  REM **********************
  12. 120  HOME 
  13. 130  VTAB 5: HTAB 14: PRINT "DECISION MAKER"
  14. 140  HTAB 19: PRINT "BY"
  15. 150  HTAB 12: PRINT "BEIRNE L. KONARSKI": PRINT : PRINT "* COPYRIGHT (C) 1985 MICROSPARC, INC. *"
  16. 160  VTAB 13: HTAB 1: CALL  -958: INPUT "HOW MANY CHOICES DO YOU HAVE? ";C$:C =  VAL(C$): IF C <3  THEN 160
  17. 170  DIM LIS$(C),TALLY(C)
  18. 180  FOR X = 1 TO C
  19. 190  PRINT "CHOICE #"X;: INPUT LIS$(X)
  20. 200  NEXT 
  21. 210  FOR X = 1 TO C -1
  22. 220  FOR Y = X +1 TO C
  23. 230  HOME 
  24. 240  PRINT "1. "LIS$(X)
  25. 250  PRINT 
  26. 260  PRINT "2. "LIS$(Y)
  27. 270  PRINT 
  28. 280  PRINT "WHICH IS MORE IMPORTANT TO YOU? ": GET ANSWER$
  29. 290  IF ANSWER$ = "1"  THEN TALLY(X) = TALLY(X) +1: GOTO 320
  30. 300  IF ANSWER$ < >"2"  THEN  PRINT : PRINT "1 OR 2 PLEASE": PRINT : PRINT : PRINT "PRESS <RETURN> TO CONTINUE": GET A$: GOTO 230
  31. 310 TALLY(Y) = TALLY(Y) +1
  32. 320  NEXT 
  33. 330  NEXT 
  34. 340  REM  *********************
  35. 350  REM  DISPLAY PRIORITIES
  36. 360  REM  *********************
  37. 370  HOME 
  38. 380  FOR X = C -1 TO 1  STEP  -1
  39. 390  FOR Y = 1 TO X
  40. 400  IF TALLY(Y) <TALLY(Y +1)  THEN HOLD = TALLY(Y):TALLY(Y) = TALLY(Y +1):TALLY(Y +1) = HOLD:TEMP$ = LIS$(Y):LIS$(Y) = LIS$(Y +1):LIS$(Y +1) = TEMP$
  41. 410  NEXT : NEXT 
  42. 420  PRINT "HERE IS THE ORDER OF PRIORITY"
  43. 430  FOR X = 1 TO C: PRINT LIS$(X);: HTAB 20: PRINT TALLY(X): NEXT 
  44. 440  VTAB 22: PRINT "WOULD YOU LIKE TO RE-START? (Y/N)";: GET A$
  45. 450  IF A$ = "Y"  THEN  CLEAR : GOTO 120
  46. 460  PRINT : HOME : END