home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Nibble Magazine
/
nib22b.dsk
/
PRINTLOG.bas
< prev
next >
Wrap
BASIC Source File
|
2023-02-26
|
2KB
|
64 lines
10 REM **********************
20 REM * PRINTLOG *
30 REM * BY VICTOR FRICKE *
40 REM * COPYRIGHT (C) 1984 *
50 REM * BY MICROSPARC, INC *
60 REM * CONCORD, MA. 01742 *
70 REM **********************
80 REM PRINT HARD COPY OF CONSULTING LOG
90 D$ = CHR$(4)
100 HOME : PRINT "PRINTING WORK LOG - PLEASE MAKE SURE"
110 PRINT "PRINTER IS TURNED ON."
120 REM RETRIEVE NUMBER OF RECORDS
130 REM # OF RECS = POINTER-1
140 PRINT D$;"OPEN LOG,L58"
150 PRINT D$;"READ LOG,R0"
160 INPUT R$
170 R = VAL(R$) -1
180 PRINT D$;"CLOSE LOG"
190 REM PREPARE PRINTER
200 PRINT D$;"PR#1": REM CHANGE SLOT NUMBER IF NECESSARY
210 LN = 0: REM COUNTS LINES PRINTED ON PAGE
220 GOSUB 450: REM PRINT PAGE HEADING
230 PRINT D$;"PR#0": REM DESELECT PRINTER
240 FOR I = 1 TO R
250 PRINT D$;"OPEN LOG,L58"
260 PRINT D$;"READ LOG,R";I
270 INPUT REC$
280 PRINT D$;"CLOSE LOG"
290 PRINT D$;"PR#1"
300 GOSUB 530: REM PRINT RECORD
310 PRINT D$;"PR#0"
330 IF LN <60 THEN 390
340 REM NEW PAGE
350 PRINT D$;"PR#1"
360 PRINT CHR$(12): REM FORM FEED
365 LN = 0
370 GOSUB 450: REM PRINT NEW PAGE HEADING
380 PRINT D$;"PR#0"
390 NEXT I
400 PRINT D$;"PR#1"
410 PRINT CHR$(12)
420 PRINT D$;"PR#0"
430 HOME
440 END
450 REM PRINT PAGE HEADINGS
460 PRINT : PRINT
470 PRINT TAB( 65);"TIME SPENT"
480 PRINT SPC( 5);"DATE"; SPC( 4);"START TIME"; SPC( 5);"ACTIVITY DESCRIPTION"; SPC( 18);"HRS MIN"
490 PRINT SPC( 5);: FOR J = 1 TO 68: PRINT "=";: NEXT : PRINT
500 PRINT
510 LN = LN +6
520 RETURN
530 REM PRINT A RECORD
540 MM$ = LEFT$(REC$,4): REM MONTH
550 DD$ = MID$ (REC$,5,3): REM DAY
560 HH$ = MID$ (REC$,8,3): REM HOUR
570 MIN$ = MID$ (REC$,11,2): REM MINUTE
580 PM$ = MID$ (REC$,13,2): REM AM/PM
590 DSCR$ = MID$ (REC$,15,39): REM DESCRIPTION
600 EH$ = MID$ (REC$,54,2): REM ELAPSED HOURS
610 EM$ = MID$ (REC$,56,2): REM ELAPSED MINUTES
620 PRINT SPC( 5);MM$;DD$;" ";HH$;":";MIN$;" ";PM$;" ";DSCR$;" ";EH$;" ";EM$
630 LN = LN +1
640 RETURN