home *** CD-ROM | disk | FTP | other *** search
/ Transactor / Transactor_27_1988_Transactor_Publishing.d64 / copy-all.64 (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1988-01-01  |  2.4 KB  |  87 lines
  1. 100 print"[147] disk copy-all      jim butterfield"
  2. 110 a$="!jim butterfield!":a$=a$+a$+a$:a$=a$+a$+a$+a$+a$
  3. 120 p$=""
  4. 130 dim l2(232),l1%(232),n$(232),t%(232),t$(4)
  5. 140 data xxx,seq,prg,usr,rel
  6. 150 forj=0to4:readt$(j):nextj
  7. 160 input"from unit  8[157][157][157]";f
  8. 170 gosub830
  9. 180 f$=d$
  10. 190 input"to unit  9[157][157][157]";t
  11. 200 gosub830
  12. 210 t$=d$
  13. 220 iff=t andf$=t$thenrun
  14. 230 n=0:close1:close15:open 15,f,15:print#15,"i"+f$
  15. 240 gosub860:if e then stop:goto230
  16. 250 z=90:input"pattern  *[157][157][157]";p$
  17. 260 p$="xxx"+left$(p$+"[160][160][160][160][160][160][160][160][160][160][160][160][160][160][160]",16)
  18. 270 print"hold down 'y' or 'n' key to select"
  19. 280 print"programs to be copied..."
  20. 290 open 1,f,3,"$"+f$
  21. 300 gosub860:ifethenstop:goto230
  22. 310 sys4156
  23. 320 r=255:goto 340
  24. 330 sys4245
  25. 340 forj=16to2step-1:ifasc(mid$(a$,j+3))=160thennextj
  26. 350 n$=mid$(a$,4,j)
  27. 360 t9=asc(a$)-128:ift9<1ort9>4goto470
  28. 370 l1%=asc(mid$(a$,22))
  29. 380 l2=asc(mid$(a$,29))+asc(mid$(a$,30))*256
  30. 390 printmid$(a$,4,16);" ";t$(t9)
  31. 400 p=peek(203)andr
  32. 410 getz$:ifz$=""andp<064goto450
  33. 420 ifz$="y"orz$="n"thenz=asc(z$):r=255:goto450
  34. 430 ifz$=chr$(13)thenr=0:goto450
  35. 440 goto410
  36. 450 ifz<80thenprint"[145]                     [145]":goto470
  37. 460 n=n+1:l2(n)=l2:n$(n)=n$:t%(n)=t9:l1%(n)=l1%
  38. 470 ifst=0andn<232goto330
  39. 480 close1:close15:print" * * * * *"
  40. 485 ifn=0thenprint"* no programs *":goto 800
  41. 490 forj=1ton
  42. 500 l2=l2(j):t%=t%(j):ifl>l2goto670
  43. 510 ifq=0goto550
  44. 520 print"*** output disk full"
  45. 530 input"do you have a new one";z$
  46. 540 ifasc(z$)<>89thenend
  47. 550 close15:open15,t,15:input"want to new the output disk  n[157][157][157]";z$
  48. 560 ifasc(z$)<>89goto600
  49. 570 input"disk name,id";x$,y$
  50. 580 print#15,"n"+t$+":"+x$+","+y$
  51. 590 gosub860:ifethenstop:goto550
  52. 600 print#15,"i"+t$:open1,t,0,"$"+t$+":!#$%&"
  53. 610 gosub860:ifethenstop:goto550
  54. 620 gosub890:gosub890:q=q+1
  55. 630 get#1,x$:ifx$<>""goto630
  56. 640 gosub890
  57. 650 l=x+y*256:print"(";l;"blocks free )"
  58. 660 close1:close15:goto500
  59. 670 open14,f,15:open15,t,15
  60. 680 printleft$(n$(j)+"                    ",21);
  61. 690 open3,f,3,f$+":"+n$(j)+","+t$(t%)
  62. 700 input#14,e,e$,e1,e2:gosub870:ifethenprint"** ";e$;e:goto780
  63. 710 ift%=4thenopen4,t,4,t$+":"+n$(j)+",l,"+chr$(l1%(j)):goto730
  64. 720 open4,t,4,t$+":"+n$(j)+","+t$(t%)+",w"
  65. 730 l=l-l2:gosub860:ifethenprint"*** ";e$;e:goto780
  66. 740 ift%=4thensys4462:goto760
  67. 750 sys4443
  68. 760 n$(j)="":gosub860:ifethenprint"**** ";e$;e:goto780
  69. 770 print"[145]"
  70. 780 close4:close3:close15:close14
  71. 790 nextj
  72. 800 x=fre(0):input"another input disk ready";z$
  73. 810 ifasc(z$)=89goto230
  74. 820 end
  75. 830 input"drive  0[157][157][157]";d
  76. 840 ifd*d<>dgoto830
  77. 850 d$=chr$(d+48):return
  78. 860 input#15,e,e$,e1,e2
  79. 870 ife=0thene=(st and 191):e$="*st*"
  80. 880 return
  81. 890 get#1,x$
  82. 900 get#1,x$
  83. 910 get#1,x$
  84. 920 x=asc(x$+chr$(0))
  85. 930 get#1,x$:y=asc(x$+chr$(0))
  86. 940 return
  87.