Starlight/Starlight_10_19xx_Starlight_staff_de_Side_A.d64/ash

Commodore BASIC | 1990-01-01 | 4.7 KB | 173 lines

100 h$="1"
105 poke53280,0:poke53281,0:print"[147][153]":fl$="---":tl$="---"
110 print"            ashes of empire"
115 print"            auswertungshilfe"
120 print" nach der braunschen methode entwickelt"
125 print" bereits vielseitig erfolgreich getestet"
130 print"              auswahlmenue"
135 print" (f1) aenderungen"
140 print" (f3) daten laden"
145 print" (f5) daten sichern"
150 print" (f7) auswerten"
155 print" (i)nformation"
160 print" (v)ariablenreset"
165 print"      (c) by karamba soft in 1990"
170 geta$:ifa$=""goto170
175 ifa$="i"goto210
180 ifa$="v"thenclr:goto100
185 ifa$=chr$(133)goto430
190 ifa$=chr$(134)thengosub300:goto105
195 ifa$=chr$(135)goto335
200 ifa$=chr$(136)goto470
205 goto170
210 print"[147] dieses programm erleichtert die aus-"
215 print" wertung des spieles ashes of empire."
220 print" es berechnet den teil,der stets wieder"
225 print" auftaucht.der auswertungsvorgang zeigt"
230 print" die maximalen baumoeglichkeiten von"
235 print" fightern und transportern unter den"
240 print" gegebenen voraussetzungen.darueber-"
245 print" hinaus ermoeglicht er einen einblick"
250 print" in die naechste runde.spieltaktische"
255 print" zuege kann das programm nicht aus-"
260 print" arbeiten dies ist ja aber genau der"
265 print" reiz des spieles und sollte daher auch"
270 print" nicht dem computer ueberlassen werden."
275 print" aus diesem grunde rate ich ebenso ab,"
280 print" dieses programm zu oft einzusetzen,"
285 print" denn es ist perfekt."
290 geta$:ifa$=""goto290
295 goto105
300 input"[147] planetennummer";pl$
305 open2,8,2,"0:"+pl$+",s,r"
310 input#2,a,pr,f,o,r,fp,op,rp,fy,ty
315 close2
320 print" die daten sind nun im speicher."
325 geta$:ifa$=""goto325
330 return
335 print"[147]       bitte neue daten eingeben"
340 input" planetennummer";pl$:gosub305
345 print"altes a:";a
350 input"neues a";a
355 print"alte pr:";pr
360 input"neue pr";pr
365 print"fuel:";f,"ore:";o,"rare";r
370 input"fuel";f:input"ore";o:input"rare";r
375 print"fp:";fp,"op:";op,"rp:";rp
380 input"fp";fp:input"op";op:input"rp";rp
385 print"anzahl fy:";fy,"anzahl ty:";ty
390 input"anzahl fy";fy
395 input"anzahl ty";ty
400 c$=chr$(13):print" ende der eingabe"
405 open2,8,2,"@0:"+pl$+",s,w"
410 print#2,a;c$;pr;c$;f;c$;o;c$;r;c$;fp;c$;op;c$;rp;c$;fy;c$;ty
415 close2
420 print" die daten wurden gespeichert."
425 geta$:ifa$=""goto425
430 print"[147]     fighter/transporter"
435 print" (1)    ja       ja"
440 print" (2)    ja      nein"
445 print" (3)   nein      ja"
450 print" (4)   nein     nein"
455 print"      bitte auswaehlen!"
460 geth$:ifh$<>"1"andh$<>"2"andh$<>"3"andh$<>"4"goto460
465 goto105
470 a1=a:r2p=rp:o2p=op:f2p=fp:f1=f:r1=r:o1=o:t1y=ty:f3y=fy:goto535
475 ifa1<10thenfl$="a":return
480 ifr1<3thenfl$="rare":return
485 ifo1<1thenfl$="ore":return
490 iff1<1thenfl$="fuel":return
495 iff3y<1thenfl$="fighteryards":return
500 a1=a1-10:r1=r1-3:o1=o1-1:f1=f1-1:f3y=f3y-1:fi=fi+1:goto475
505 ifa1<20thentl$="a":return
510 ifr1<1thentl$="rare":return
515 ifo1<3thentl$="ore":return
520 iff1<2thentl$="fuel":return
525 ift1y<1thentl$="transporteryards":return
530 a1=a1-20:f1=f1-2:o1=o1-3:r1=r1-1:t1y=t1y-1:tr=tr+1:goto505
535 ifh$="1"thengosub475:gosub505:goto550
540 ifh$="2"thengosub475:goto550
545 ifh$="3"thengosub505
550 print"[147] anzahl der fighter";fi
555 print" baubegrenzung durch ";fl$
560 print" anzahl der transporter";tr
565 print" baubegrenzung durch ";tl$
570 print" uebrige arbeitskraft";a1
575 print" fighter zuerst festlegen (j/n)?"
580 getch$:ifch$<>"j"andch$<>"n"goto580
585 ifch$="n"goto625
590 print" wieviel fighter bauen (0-";fi;"[157])"
595 print" ";fi:input"[145]";f2i
600 iff2i<0thenprint"[145]";:goto595
605 iff2i>fithenprint"[145]";:goto595
610 di=fi-f2i:a1=a1+10*di:f1=f1+di:o1=o1+di:r1=r1+3*di:f3y=f3y+di
615 ifch$="n"goto685
620 gosub505
625 print" anzahl der transporter";tr
630 print" baubegrenzung durch ";tl$
635 print" wieviel transporter bauen (0-";tr;"[157])"
640 print" ";tr:input"[145]";t2
645 ift2<0thenprint"[145]";:goto640
650 ift2>trthenprint"[145]";:goto640
655 d2i=tr-t2:a1=a1+20*d2i:f1=f1+2*d2i:o1=o1+3*d2i:r1=r1+d2i:t1y=t1y+d2i
660 ifch$="j"goto685
665 gosub475
670 print" anzahl der fighter";fi
675 print" baubegrenzung durch ";fl$
680 goto590
685 print"[147] gebaute fighter:";f2i
690 print" gebaute transporter:";t2
695 print" uebrige arbeitskraft:";a1
700 print" fuelreserve:";f1
705 print" orereserve:";o1
710 print" rarereserve:";r1
715 print" fuelplants:";f2p
720 print" oreplants:";o2p
725 print" rareplants:";r2p
730 print" naechste runde:"
735 f3=f1+int(f2p*pr):print" fuel:";f3
740 o3=o1+int(o2p*pr):print" ore:";o3
745 r3=r1+int(r2p*pr):print" rare:";r3
750 print"             taste druecken!"
755 geta$:ifa$=""goto755
760 t5=ty+3:f5=fy+3
765 print"[147]"
770 forx=1tof5
775 f6=x-(f1+fp*pr)
780 o6=x-(o1+op*pr)
785 r6=x*3-(r1+rp*pr)
790 f8p=int(f6/pr+.5)
795 o8p=int(o6/pr+.5)
800 r8p=int(r6/pr+.5)
805 f7y=x-fy
810 print" zum bau von";x;"fightern fehlen:"
815 iff8p>0thenprint"fp:";f8p
820 ifo8p>0thenprint"op:";o8p
825 ifr8p>0thenprint"rp:";r8p
830 iff7y>0thenprint"fy:";f7y
835 geta$:ifa$=""goto835
840 nextx
845 input"[147] nochmal";a$:ifa$="j"goto765
850 print"[147]"
855 forx=1tot5
860 f6=x*2-(f1+int(fp*pr))
865 o6=x*3-(o1+int(op*pr))
870 r6=x-(r1+int(rp*pr))
875 f8p=int(f6/pr+.5)
880 o8p=int(o6/pr+.5)
885 r8p=int(r6/pr+.5)
890 t7y=x-ty
895 print" zum bau von";x;"transportern fehlen:"
900 iff8p>0thenprint"fp:";f8p
905 ifo8p>0thenprint"op:";o8p
910 ifr8p>0thenprint"rp:";r8p
915 ift7y>0thenprint"ty:";t7y
920 geta$:ifa$=""goto920
925 nextx
930 input"[147] nochmal";a$:ifa$="j"goto850
935 print"[147] ende des programms."
940 print" achtung:"
945 print" variablenreset nicht vergessen!"
950 geta$:ifa$=""goto950
955 clr:goto100