home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Power Pack
/
Power_Pack_5_1992_Alfons_Mittelmeyer_de.d64
/
dateigenerator
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
5KB
|
171 lines
10 rem dateigenerator===============c64
20 rem by alfons mittelmeyer
40 rem c64
50 rem basic v2.0
60 rem ================================
70 ifpeek(49154)=174then100
80 sys57812"sysmc",8,0:poke780,0
90 poke781,254:poke782,191:sys65493
100 gosub1411
140 printchr$(14)chr$(147);
150 sysat,10,5:print"[196][193][212][197][201][199][197][206][197][210][193][212][207][210]";
160 sysat,10,6:print"--------------";
170 sysat,10,8:print"1 = [205]aske";
180 sysat,10,9:print"2 = [196]atei";
190 sysat,10,10:print"3 = [214]erweis";
200 sysat,10,12:print"0 = [197]nde";
210 geta$:ifa$=""then210
211 a=asc(a$)and3:ifa$<"0"ora$>"3"then140
220 on a goto 750,490,240
230 printchr$(142);:end
240 printchr$(147);
250 sysat,10,5:print"[214]erweisdateien";
260 sysat,10,6:print"--------------";
270 sysat,10,8:print"1 = [197]inrichten";
280 sysat,10,9:print"2 = [201]nfo";
290 sysat,10,11:print"0 = [218]urueck";
300 geta$:ifa$=""then300
301 a=asc(a$)and3
310 on a goto 330,410,140
320 goto140
330 printchr$(147):sysat,0,7:print"[214]erweisdatei einrichten"
340 print"----------------------":print
350 print"[214]erweisdatei? ";:sysin:vw$
360 print"[205]askendatei? ";:sysin:mk$
370 print"[196]atenfile? ";:sysin:df$
380 open8,8,8,vw$+",p,w"
390 gosub1270:print#8,mk$:print#8,df$:close8
400 goto240
410 printchr$(147):sysat,0,7:print"[201]nfo [214]erweisdatei"
420 print"-----------------":print
430 print"[214]erweisdatei? ";:sysin:vw$
440 open8,8,8,vw$+",p,r":gosub1400
450 sysin:mk$:sysin:mk$:sysin:df$:gosub1410
460 print"[205]askendatei: "mk$
470 print"[196]atenfile: "df$
480 print:print"weiter mit [212]aste"
481 geta$:ifa$=""then481
482 goto240
490 printchr$(147)
500 sysat,10,5:print"[196]atenfiles";
510 sysat,10,6:print"--------------";
520 sysat,10,8:print"1 = [197]inrichten";
530 sysat,10,9:print"2 = [201]nfo";
540 sysat,10,11:print"0 = [218]urueck";
550 geta$:ifa$=""then550
555 a=asc(a$)and3
560 on a goto 580,660,140
570 goto140
580 printchr$(147):sysat,0,7:print"[196]atenfile einrichten"
590 print"--------------------":print
600 print"[198]ile-[206]ame? ";:sysin:nf$
610 input"[198]eldzahl";fz
620 input"[205]aximale [211]atzzahl";ms
630 open8,8,8,nf$+",p,w"
640 gosub1270:print#8,fz:print#8,ms:print#8,0:close8
650 goto490
660 printchr$(147):sysat,0,7:print"[201]nfo [196]atenfile"
670 print"--------------":print
680 print"[198]ile-[206]ame? ";:sysin:nf$
690 open8,8,8,nf$+",p,r"
700 input#8,mk$:input#8,fz:input#8,ms:input#8,sz:close8
710 print"[198]eldzahl: "fz
720 print"[205]aximale [211]atzzahl: "ms
730 print"[193]ktuelle [211]atzzahl: "sz
740 print:print"weiter mit [212]aste"
741 geta$:ifa$=""then741
742 goto490
750 printchr$(147);:clr:dimx(50),y(50),z$(50),xf(50),yf(50),fl(50)
751 gosub1411
760 sysat,10,5:print"[205]askenfiles";
770 sysat,10,6:print"-----------";
780 sysat,10,8:print"1 = [197]inrichten";
790 sysat,10,9:print"2 = [201]nfo";
800 sysat,10,10:print"3 = [193]endern";
810 sysat,10,12:print"0 = [218]urueck";
820 geta$:ifa$=""then820
821 a=asc(a$)and3
830 on a goto 850,1280,1380,140
840 goto140
850 tz=1:fz=1
860 printchr$(147)
870 sysat,1,23:printright$(str$(tz),2)+": x = [216], y = [217], z = [212]exteintrag";
880 sysat,5,24:print"f = [198]eld, b = [194]ild, e = [197]nde";
890 sysat,x(tz),y(tz):print""z$(tz)"[146]";
891 geta$:ifa$=""then890
892 sysat,0,22:printle$;
893 syswo,a$,"xyzfbe[145]",n:ifn=0then890
894 ifn>3thensysat,x(tz),y(tz):printz$(tz);
900 on n goto 910,920,930,1010,940,1150,970,990
910 sysat,1,22:print"[216]-[203]oordinate "str$(x(tz));:sysat,13,22:inputa:gosub961
911 x(tz)=a:goto890
920 sysat,1,22:print"[217]-[203]oordinate "str$(y(tz));:sysat,13,22:inputa:gosub961
921 y(tz)=a:goto890
930 sysat,1,22:print"[212]exteintrag? "z$(tz);:sysat,14,22:sysin:z$:gosub961
931 z$(tz)=z$:goto891
940 printchr$(147):fori=1totz:sysat,x(i),y(i):printz$(i);:next
950 fori=1tofz:sysat,xf(i),yf(i):print"<";:sysat,xf(i)+1+fl(i),yf(i)
960 print">";:next:goto870
961 sysat,x(tz),y(tz):printleft$(le$,len(z$(tz))):return
970 iftz<>1thentz=tz-1
980 sysat,1,23:printright$(str$(tz),2);:goto890
990 iftz<>50thentz=tz+1:sysat,1,23:printright$(str$(tz),2);
1000 goto890
1010 sysat,1,23:printright$(str$(fz),2)": x = [216], y = [217], z = [198]eldlaenge ";
1020 sysat,5,24:print"t = [212]ext, b = [194]ild, e = [197]nde";
1030 sysat,xf(fz),yf(fz):print"<"left$(le$,fl(fz))"[146]>";
1031 geta$:ifa$=""then1030
1032 sysat,0,22:printle$;
1033 syswo,a$,"xyztbe[145]",n:ifn=0then1030
1034 ifn>3thensysat,xf(fz),yf(fz):print""left$(le$,fl(fz));
1040 on n goto 1050,1060,1070,870,1080,1150,1110,1130
1050 sysat,1,22:print"[216]-[203]oordinate "str$(xf(fz));:sysat,13,22:inputa:gosub1072
1051 xf(fz)=a:goto1030
1060 sysat,1,22:print"[217]-[203]oordinate "str$(yf(fz)):sysat,13,22:inputa:gosub1072
1061 yf(fz)=a:goto1030
1070 sysat,1,22:print"[198]eldlaenge "str$(fl(fz));:sysat,11,22:inputa:gosub1072
1071 fl(fz)=a:goto1030
1072 sysat,xf(fz),yf(fz):printleft$(le$+" ",fl(fz)+2);:return
1080 printchr$(147):fori=1totz:sysat,x(i),y(i):printz$(i);:next
1090 fori=1tofz:sysat,xf(i),yf(i):print"<";:sysat,xf(i)+1+fl(i),yf(i)
1100 print">";:next:goto1010
1110 iffz<>1thenfz=fz-1
1120 sysat,1,23:printright$(str$(fz),2);:goto1030
1130 iffz<>50thenfz=fz+1:sysat,1,23:printright$(str$(fz),2);
1140 goto1030
1150 printchr$(147)
1160 sysat,10,5:print"[197]nde der [205]askengenerierung";
1170 sysat,10,6:print"--------------------------";
1180 sysat,10,8:print"[205]aske speichern j/n ?";
1181 geta$:ifa$=""then1181
1190 if a$="n"then750
1200 if a$<>"j"then1180
1210 print:print:print"[198]ilename? ";:sysin:f$
1220 fori=1totz:ifz$(i)=""thenz$(i)=" "
1230 next
1240 open8,8,8,f$+",p,w":gosub1270:print#8,fz:print#8,tz
1250 fori=1totz:print#8,x(i):print#8,y(i):print#8,z$(i):next
1260 fori=1tofz:print#8,xf(i):print#8,yf(i):print#8,fl(i):next:close8:goto750
1270 print#8,chr$(1)chr$(1)chr$(0)chr$(0):return
1280 printchr$(147):sysat,0,7:print"[201]nfo [205]askendatei"
1290 sysat,0,8:print"----------------";:gosub1310
1300 sysat,0,24:print"[215]eiter mit [212]aste";
1301 geta$:ifa$=""then1301
1302 goto750
1310 print:print:print"[205]asken-[206]ame? ";:sysin:f$
1320 open8,8,8,f$+",p,r":gosub1400:sysin:mk$:sysin:fz
1330 sysin:tz:fori=1totz:sysin:x(i):sysin:y(i):sysin:z$(i):next
1340 fori=1tofz:inputxf(i),yf(i),fl(i):next:gosub1410
1350 printchr$(147):fori=1totz:sysat,x(i),y(i):printz$(i);:next
1360 fori=1tofz:sysat,xf(i),yf(i):print"<";:sysat,xf(i)+1+fl(i),yf(i)
1370 print">";:next:return
1380 printchr$(147):sysat,0,7:print"[205]aske aendern";
1390 sysat,0,8:print"-------------";:gosub1310:goto870
1400 poke19,8:poke781,8:sys65478:return
1410 close8:sys65484:poke19,0:return
1411 in=49465:at=49152:wo=49172
1412 le$=" ":le$=left$(le$+le$+le$+le$,39):return
1420 rem ==============================
1430 rem p r o g r a m m e n d e
1440 rem ==============================