home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Go64!
/
Go64_2002-01_2002_CSW_Side_A.d64
/
refresh
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
875b
|
28 lines
1 clr:dimm$(683):rem blockanzahl 1541er
2 poke53280,0:poke53281,0:t=0:b=0
3 print"[147] refresh":input"[155] device ";g:ifg<8then3
4 print" input disk in drive-nr."g
5 print" ... and press a key":poke198,0:wait198,1
6 open1,g,15:print#1,"m-w"chr$(106)chr$(0)chr$(1)chr$(10):rem leseversuche(10)
7 print#1,"m-w"chr$(7)chr$(28)chr$(1)chr$(60):print#1,"i":rem zugriffzeit(60)
8 t=t+1:ift>35then19:rem track/sektor
9 gosub15:fors=0tox:open3,g,3,"#"
10 print#1,"u1:"3;0;t;s:rem lesen
11 input#1,f,f$,tf,sf:print"[147]"t"/"s tab(11)f;f$;tf;sf:iff=0then13
12 m$(b)=str$(tf)+" /"+str$(sf):b=b+1:goto14
13 print#3,"u2:"3;0;t;s:rem schreiben
14 close3:next:goto8
15 ift<18thenx=20:return
16 ift<25thenx=18:return
17 ift<31thenx=17:return
18 x=16:return
19 close3:close1:b$="[147] bad blocks[155] : ":gosub27:fori=0tob-1step4
20 printm$(i)tab(10)m$(i+1)tab(20)m$(i+2)tab(30)m$(i+3)
21 ifpeek(214)=20thengosub26
22 next:print"[153] another disk (j/n) ?"
23 getk$:ifk$="j"then1
24 ifk$<>"n"then23
25 poke53280,14:poke53281,6:print"[147][154]":end
26 poke214,22:poke211,16:sys58640:print"<taste>[146]":poke198,0:wait198,1
27 printb$;b"":return