home *** CD-ROM | disk | FTP | other *** search
/ Go64! / Go64_2001-06_2001_CSW_Side_A.d64 / funkt1 (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  2KB  |  94 lines
  1. 1000 a=200:goto20:rem z=f(x,y) ,bc3-c
  2. 1010 dimz(441):cn=0
  3. 1015 ifsv<35 thendimcc(1):rem compatibiliteit
  4. 1020 cc(0)=0:cc(1)=6:gosub100:gosub1500
  5. 1030 gosub100:gosub1670
  6. 1040 gosub600:t=0
  7. 1050 rem -- plaats tekst --
  8. 1060 sr$=z$:ho=.4:ve=.95:gosub650
  9. 1070 rem -- teken in x-richting --
  10. 1080 forpy=0 to20:y=py/3.18-ff
  11. 1090 forpx=0 to20:x=px/3.18-ff
  12. 1100 gosub1390:gosub1480
  13. 1110 ifpx=0 then gosub620:goto1130
  14. 1120 gosub630
  15. 1130 nextpx:nextpy
  16. 1140 rem -- teken in y-richting --
  17. 1150 forpx=0 to20:x=px/3.18-ff
  18. 1160 forpy=0 to20:y=py/3.18-ff
  19. 1170 z=z(px+21*py)
  20. 1180 gosub1450:ifpy=0 then gosub620:goto1200
  21. 1190 gosub630
  22. 1200 nextpy:nextpx
  23. 1210 ifff=0 then1240
  24. 1220 px=10:py=10:z=z(220):gosub1450
  25. 1230 gosub620:ve=.1:gosub630:goto1260
  26. 1240 px=0:py=0:z=z(0):gosub1450
  27. 1250 gosub620:ve=.1:gosub630
  28. 1260 gosub210:gosub100
  29. 1270 ho=4:ve=10:gosub110
  30. 1280 print"[206]og een funktie ([202]/[206]) ? ";
  31. 1290 gosub210:ifin=74 then1030
  32. 1300 ifin=78 then950
  33. 1310 goto1290
  34. 1320 rem -- formules --
  35. 1330 onfu goto1340,1350,1360,1370
  36. 1340 z$="z=sin(x) * sin(y)":return
  37. 1350 z$="z=cos(x) * sin(2y)":return
  38. 1360 z$="z=sin(x) + sin(y)":return
  39. 1370 z$="z=sin(2x) + cos(y)":return
  40. 1380 rem -- bereken z --
  41. 1390 onfu goto1400,1410,1420,1430
  42. 1400 z=sin(x)*sin(y):goto1450
  43. 1410 z=cos(x)*sin(2*y):goto1450
  44. 1420 z=sin(x)+sin(y):goto1450
  45. 1430 z=sin(2*x)+cos(y)
  46. 1440 rem -- bereken coordinaten --
  47. 1450 ho=.23+px/27-py/100
  48. 1460 ve=.85-px/80-py/40-z/20:return
  49. 1470 rem -- bewaar z in z() --
  50. 1480 z(t)=z:t=t+1:return
  51. 1490 rem -- inleiding --
  52. 1500 ho=9:ve=1:gosub110
  53. 1510 sr$="[218] = f([216],[217])":gosub150
  54. 1520 print:print
  55. 1530 print"[196]it programma maakt de ruimtelijke"
  56. 1540 print"afbeelding van het vlak [218]. [196]e [216]-as"
  57. 1550 print"wijst naar rechts , de  [217]-as wijst"
  58. 1560 print"naar achter  en de [218]-as wijst naar"
  59. 1570 print"boven.":print
  60. 1580 print"[197]r zijn twee opties:":print
  61. 1590 print"[200]et eerste kwadrant wordt getekend"
  62. 1600 print"voor het domein van 0 tot 2 pi [210][193][196]"
  63. 1610 print"= 0 tot 360 graden in [216] en [217].":print
  64. 1620 print"[197]r worden vier kwadranten getekend"
  65. 1630 print"met de oorsprong in het midden, en"
  66. 1640 print"180 graden in alle richtingen.":print
  67. 1650 print"[201]eder hokje is 18 bij 18 graden.":print
  68. 1660 print"    [212]ik op een toets ";:gosub210:return
  69. 1670 print
  70. 1680 print"[194]eschikbaar zijn de funkties:":print
  71. 1690 print"1.  z = sin(x) * sin(y)":print
  72. 1700 print"2.  z = cos(x) * sin(2y)":print
  73. 1710 print"3.  z = sin(x) + sin(y)":print
  74. 1720 print"4.  z = sin(2x) + cos(y)":print
  75. 1730 print"    kies een funktie : ";
  76. 1740 gosub210:if(in$<"1")or(in$>"4") then1740
  77. 1750 printin$:print:fu=val(in$):gosub1330
  78. 1760 print"[193].  vier kwadranten":print
  79. 1770 print"[194].  alleen eerste kwadrant":print
  80. 1780 print"    kies [193] of [194]: ";
  81. 1790 gosub210:if(in<65)or(in>66) then1790
  82. 1800 ff=3.14:ifin=66 thenff=0
  83. 1810 printz$:print
  84. 1820 print"    [212]ik op een toets ";
  85. 1830 gosub210:return
  86. 1840 rem---------------------------------
  87. 32000 rem  ch.w.brederode
  88. 32010 rem  von bonninghausenlaan 33
  89. 32020 rem  2161 es  lisse
  90. 32030 rem
  91. 32040 rem tros-radio dd 911127
  92. 32050 rem ds-kultur
  93. 32060 rem -spezial 911211
  94.