Computer Buyer 1996 June/BUYER_696.iso/internet/wincim/scripts.lib/TELENET.SCR

Text File | 1995-12-05 | 1KB | 50 lines

!
!  Copyright (c) 1995
!  by CompuServe Incorporated, Columbus, Ohio
!
!  The information in this software is subject to change without
!  notice and should not be construed as a commitment by CompuServe.
!
!  TELENET:
!    Connect to SprintNet
!    Success:  returns %Success
!    Failure:  saves error msg in %FailureMsg and returns %Failure
!
!+V
! "3.8.1"
!-V

Attempts = 3;
on cancel goto SprintNet_Cancelled;
show "Connecting to SprintNet";
send "@." & %CR;
wait until 1;    ! pause required for 2400 baud
send %CR & %CR;

Wait_SprintNet:
    if Attempts = 0 goto SprintNet_Failed;
    Attempts = Attempts - 1;

    wait
        "Terminal"    goto send_telenet_id,
        "@"        goto send_telenet_host
    until 85;

    send %CR & %CR;
    goto Wait_SprintNet;

send_telenet_id:
    send "D1" & %CR;
    goto Wait_SprintNet;

send_telenet_host:
    send "C 202202" & %CR;
    exit %Success;

SprintNet_Failed:
    define %FailureMsg = "SprintNet: No answer";
    exit %Failure;

SprintNet_Cancelled:
    exit %Cancel;