Computer Buyer 1995 November/SHOWCASE.ISO/files/goer.dir/00002_Script_2

Text File | 1995-06-13 | 3KB | 100 lines

-- òò -- Lingo coding by David K. Anderson and Terry R. Schussler -- òò --

global gPTimerSet, gPresentationLight, gLightColor

on startMovie
  clearGlobals
  set gLightColor = "Green timer light"
  if the colordepth <> 8 then set the colordepth = 8
  set the soundLevel = 5
  InitIntro
  set gPresentationLight = 48
  set the timeoutLength =  36000
  set the timeoutScript = "timeoutProcedure"
  set gPTimerSet = 0
  if the controlDown then
    if the optionDown then
      put "Hi Heidi!" into field "Who to"
    else
      put "Hi Alex!" into field "Who to"
    end if
    go "Set Presentation Time"
    exit
  end if
  if the optionDown then
    put "Company Name" into field "Who to"
    go "Set Presentation Time"
    exit
  end if
  if the commandDown then
    put "Hi Karyn!" into field "Who to"
    go "Set Presentation Time"
    exit
  end if
  if the shiftDown then
    put "Hi Cathy!" into field "Who to"
    go "Set Presentation Time"
    exit
  end if
end

-- This handler searches for an empty text file on the CD to determine the correct path to the Director files.
on InitIntro
  global gMyPath, gFile
  set the searchCurrentFolder = 0
  if the machinetype = 256 then
    -- Creat a list of potential drive names to be used when searching for the CD-ROM drive.
    set PathList = ["C:\FILES\", "D:\FILES\", "E:\FILES\",  "F:\FILES\", ¼
"G:\FILES\", "H:\FILES\", "I:\FILES\", "J:\FILES\", "K:\FILES\", "L:\FILES\", "M:\FILES\", "N:\FILES\", "O:\FILES\", "P:\FILES\", "Q:\FILES\", "R:\FILES\", "S:\FILES\", "T:\FILES\", "U:\FILES\", "V:\FILES\", "W:\FILES\", "X:\FILES\", "Y:\FILES\", "Z:\FILES\", "EOL"]
    set gMyPath = "D:\FILES\"
    repeat with x = 1 to count(PathList)
      set gMyPath = getAT(PathList, x)
      set foo = ReadCDTestFile()
      put foo && "Reading from disk:" && getAT(PathList, x)
      if foo then exit repeat
      if gMyPath = "EOL" then CantFindCD
    end repeat
  else
    set gMyPath = "SHOWCASE:FILES:"
    set foo = ReadCDTestFile()
    put foo
    if NOT foo then CantFindCD
  end if
end

-- This handler uses the FileIO XObject to determine whether the text file exists on the selected disk.
on ReadCDTestFile
  global gFile, gMyPath, gTheProblem
  put "READ CD ROUTINE"
  if objectP(gFile) then gFile(mDispose)
  if the machineType = 256 then
    set TestPath = gMyPath & "CDLOCALE.TXT"
  else
    set TestPath = gMyPath & "CDLOCALE.TXT"
  end if
  set gFile = fileIO(mNew, "read", TestPath)
  if NOT objectp( gFile ) then
    put "NOT found"
    return FALSE
  else
    gFile(mDispose)
    put "Found!"
    setAt the searchpath 1, gMyPath
    return TRUE
  end if
end

-- If the file can't be found, give up and go home.
on CantFindCD
  if the machinetype = 256 then
    alert "You don't seem to have the Showcase CD-ROM loaded!  Please make sure ¼
the CD is in the drive." & RETURN & RETURN & "Then restart the application."
  else
    alert "You don't seem to have the Showcase CD-ROM loaded!  Please make sure ¼
the CD is in the drive and that the" && QUOTE & "Showcase"  & QUOTE && "icon appears on the desktop." & RETURN & RETURN & "Then restart the application."
  end if
  quit
end