home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tiger Disk 105
/
Tiger_Disk_105_20xx_Tiger-Crew-Disk_de_Side_B.d64
/
bestell-datei_tc
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
4KB
|
161 lines
10 fe$=" programm unvollstaendig ! [146]":dimx$(200,2):lw=peek(186):iflw<8thengosub1550
20 open2,lw,2,"konfig,s,r":gosub1290:ifa<>0thenprintfe$:close2:end
30 input#2,az:dimbz$(az)
40 fort=1toaz:input#2,bz$(t):next
50 close2:close15
60 poke53281,0:poke53280,0:dimg(200,az)
70 print"[147] bestell-datei"
80 print" [153]by tigercrew"
90 print" (c) 1992"
100 fort=1to500:next
110 p=0:goto360
120 print"[147]","datei wird eingelesen[146]"
130 open2,lw,2,"vk-liste,s,r":gosub1290:ifa<>0then360
140 i=1
150 input#2,x$(i,1),x$(i,2):fort=1toaz:input#2,g(i,t):next
160 ifst<>64theni=i+1:goto150
170 close2:close15
180 print" "i;"datensaetze sind geladen"
190 gosub1280:gosub260:return
200 print" eingabe richtig (space=j/n) ? [146]"
210 getp$:ifp$<>"j"andp$<>" "andp$<>"n"then210
220 ifp$="n"thenreturn
230 print" weitere eingaben (space=j/n)[160]? [146]"
240 getr$:ifr$<>"j"andr$<>" "andr$<>"n"then240
250 return
260 poke198,0:wait198,1:poke198,0:return
270 open2,lw,2,"vk-liste,s,w"
280 gosub1290:ifa<>0then360
290 fort=1toi
300 print#2,x$(t,1):print#2,x$(t,2)
310 fortt=1toaz:print#2,g(t,tt):nexttt
320 nextt
330 close2:close15:ifj<>0theni=j:j=0
340 print"[147]","datei ist gespeichert[146]"
350 gosub1280:gosub260
360 print"[147]","[155]datei einrichten","1"
370 print"","datei erweitern","2"
380 print"","mengen eingeben","3"
390 print"","daten ausgeben","4"
400 print"","konfiguration","5"
410 print"","prg. beenden","6"
420 getwe$:ifwe$<"1"orwe$>"6"then420
430 ifwe$="6"thenend
440 ifwe$="2"then570
450 ifwe$="3"andp>0then670
460 ifwe$="3"then660
470 ifwe$="4"andp>0then920
480 ifwe$="4"then900
490 ifwe$="5"then1350
500 i=1
510 x$(i,1)="":input"[147] artikel ";x$(i,1):ifx$(i,1)=""then360
520 input" lieferant";x$(i,2)
530 gosub200:ifp$="n"then510
540 ifr$="n"then560
550 i=i+1:goto510
560 print"[147]","datei wird gespeichert[146]":goto270
570 l=1:print"[147]"
580 x$(l,1)="":input" artikel ";x$(l,1):ifx$(l,1)=""then360
590 input" lieferant";x$(l,2)
600 gosub200:ifp$="n"thenprint"[145][145][145][145][145][145][145][145]":goto580
610 ifr$="n"then630
620 l=l+1:print"[147]":goto580
630 print"[147]","datei wird gespeichert[146]":j=i+l:i=l
640 open2,lw,2,"vk-liste,s,a"
650 goto280
660 gosub120
670 fi=0:input"[147] artikel";s$
680 forzz=1toi
690 ifx$(zz,1)=s$thenfi=1:z=zz:zz=i
700 nextzz
710 iffi<>0then790
720 print"artikel ist nicht gespeichert"
730 print"","weiter[146]",,"1[146]"
740 print""," ende [146]",,"2[146]"
750 getq$:ifq$<>"1"andq$<>"2"then750
760 ifq$="1"then670
770 ifq$="2"ando>0then880
780 ifq$="2"then360
790 fi=0:print"neuer art. = e"
800 input"groesse";gr$
810 ee=0:ifgr$="e"then670
820 fort=1toaz:ifgr$=bz$(t)thenee=t:t=az
830 next:ifee=0thenprint"[145][145][145]":goto800
840 input"menge ";m$:m=val(m$)
850 gosub200:ifp$="n"thenprint"[145][145][145][145][145]":goto800
860 g(z,ee)=g(z,ee)+m:ifr$="n"then880
870 goto800
880 print"[147]","datei wird gespeichert[146]"
890 open15,lw,15,"s:vk-liste":close15:goto270
900 gosub120
910 p=p+1
920 print"[147]ausgabe drucken ? (j/n)"
930 getdu$:ifdu$<>"j"anddu$<>"n"then930
940 print"[147] lieferant = l / alle = a":z=0
950 s$="":input" gesuchter artikel ";s$:ifs$=""then360
960 ifs$="a"then1100
970 ifs$="l"then1180
980 forzz=1toi
990 ifx$(zz,1)=s$thenz=zz:zz=i
1000 nextzz:ifz<>0thenprint"[147]":gosub1110:goto1060
1010 print"artikel ist nicht gespeichert"
1020 print"","weiter[146]",,"1[146]"
1030 print""," ende [146]",,"2[146]"
1040 getq$:ifq$<>"1"andq$<>"2"then1040
1050 onval(q$)goto950,360
1060 print"[147] weiteren artikel ausgeben (j/n) ?"
1070 getu$:ifu$<>"j"andu$<>"n"then1070
1080 ifu$="j"thenz=0:goto950
1090 goto360
1100 forz=1toi:gosub1110:next:goto1160
1110 ifdu$="j"thenopen4,4:cmd4
1120 print"artikel :",x$(z,1):print"lieferant:",x$(z,2):print""
1130 fort=1toaz:printbz$(t),g(z,t):next
1140 ifdu$="j"thenprint#4:close4:return
1150 gosub1280:gosub260:return
1160 print"[147] datei - ende [146]"
1170 gosub1280:gosub260:goto360
1180 input"[147] gesuchter lieferant ";li$:li=len(li$)
1190 forz=1toi
1200 ifleft$(x$(z,2),li)=li$thenfo=1:gosub1110
1210 nextz
1220 iffo=0thenprint"[147] nicht gefunden!"
1230 fo=0:print"","neu suchen[146]","1[146]"
1240 print""," ende [146]","2[146]"
1250 getq$:ifq$<>"1"andq$<>"2"then1250
1260 ifq$="1"then1180
1270 goto360
1280 print" taste druecken [146]":return
1290 open15,lw,15
1300 input#15,a,bb$,c,d
1310 ifa=0then1340
1320 print" fehler[160]!":print""a,bb$,c;d
1330 gosub260:close2:close15:return
1340 return
1350 print"[147] konfiguration [146]"
1360 print"bei versehentlicher anwahl f2[146] druecken."
1370 print"f1[146] = vorhandene daten ansehen.":print"space[146] = dateneingabe"
1380 getbx$:ifbx$=""then1380
1390 ifbx$=chr$(137)then360
1400 ifbx$=chr$(133)then1540
1410 clr:dimbz$(25):print"[147]":t=1
1420 printt" ";:bz$(t)="":input"bezeichung ";bz$(t):ifbz$(t)=""thent=t-1:goto1480
1430 print" eingabe korrekt ? "
1440 geteg$:ifeg$<>" "andeg$<>"j"andeg$<>"n"then1440
1450 ifeg$="n"thenprint"[145][145][145][145]":goto1420
1460 print"[145] [145]":t=t+1:ift<26then1420
1470 print"ende der eingabe !":forbs=1to500:next
1480 ift<1then360
1490 open15,lw,15,"s:konfig":close15
1500 open2,lw,2,"konfig,s,w"
1510 print#2,t
1520 forsr=1tot:print#2,bz$(sr):next
1530 close2:clr:run
1540 print"[147]":fort=1toaz:printt" "bz$(t):next:gosub260:goto1350
1550 print"[147]durch programm-abbruch ist vor neustart eine laufwerkbestimmung er";
1560 print"forderlich.":print"bitte, geben sie ein, mit welchem lw dasprogramm";
1570 print" arbeiten soll:"
1580 lw$="":input"";lw$:iflw$=""thenend
1590 lw=val(lw$):iflw<8orlw>15then1550
1600 return