home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tiger Disk 35
/
Tiger_Disk_035_1997-02_Tiger-Crew-Disk_de_Side_A.d64
/
feiertage
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
820b
|
24 lines
10 poke53280,6:poke53281,6:print"[147] ausgabe von beweglichen feiertagen "
20 input" welches jahr ";j$:j=val(j$)
30 ifj<1901 or j>2099 then print"anderes jahr eingeben":goto 20
40 print"[159] bewegliche feiertage im jahr";j;":"
50 fori=2 to 6:readm$(i):next
60 a=j-int(j/19)*19:b=j-int(j/4)*4:c=j-int(j/7)*7:d=19*a+24:d=d-int(d/30)*30
70 e=2*b+4*c+6*d+5:e=e-int(e/7)*7:f=d+e-9:n=f+90-(int(j/4)=j/4)
80 printchr$(150)" rosenmontag ";:m=n-48:gosub170
90 print" ostersonntag ";:m=n:gosub170
100 print" christi himmelfahrt ";:m=n+39:gosub170
110 print" pfingstsonntag ";:m=n+49:gosub170
120 print" fronleichnam ";:m=n+60:gosub170
130 restore:clr
140 input"nochmal (j/n) ";a$
150 ifa$="j" then 10
160 end
170 for i=6 to 2 step -1
180 t=int((158*i-157)/5)+(i>2)*(i-(int(j/4)<j/4))
190 if m>t then a=m-t:gosub220
200 next i:return
210 data februar,maerz,april,mai,juni
220 ifa<10thenprint" ";
230 printa"."m$(i)"":i=2:return