home *** CD-ROM | disk | FTP | other *** search
/ Tiger Disk 11 / Tiger_Disk_011_19xx_Tiger-Crew-Disk_de_Side_A.d64 / hex_dez_bin-conv (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  3KB  |  78 lines
  1. 1 print"[147]"
  2. 5 poke53280,1:poke53281,1
  3. 6 rem:                               :
  4. 7 rem: hex - dec - bin converter     :
  5. 8 rem:    by: bob swift              :
  6. 9 rem:                               :
  7. 10 dimh$(15):fori=0to15:readh$(i):nexti
  8. 20 data0,1,2,3,4,5,6,7,8,9,a,b,c,d,e,f
  9. 30 printchr$(14);"[147][200][197][216] [144]- [196][197][218] [144]- [194][201][206] [144][195][207][206][214][197][210][212][197][210]"
  10. 40 print"[215]ritten by: [210].[196]. [211]wift, [208].[197]ng.":printtab(12);"1983 - 03 - 27"
  11. 50 print"    1[146] - [200]exadezimal [144]zu [196]ezimal[144]"
  12. 60 print"    2[146] - [196]ezimal [144]zu [200]exadezimal[144]"
  13. 70 print"    3[146] - [200]exadezimal [144]zu [194]inaer[144]"
  14. 80 print"    4[146] - [194]inaer [144]zu [200]exadezimal[144]"
  15. 90 print"    5[146] - [196]ezimal [144]zu [194]inaer[144]"
  16. 100 print"    6[146] - [194]inaer [144]zu [196]ezimal[144]"
  17. 110 print"    _[146] - [197][160][206][160][196][160][197]"
  18. 120 print"[194]ei der [213]mrechnung kommst [196]u mit"
  19. 130 print" [210][197][212][213][210][206] [146] wieder zum [205][197][206][213][197]."
  20. 140 geta$:ifa$=""then140
  21. 150 ifa$="1"thenprintchr$(142);"[147]hexadezimal [144]zu dezimal":goto1000
  22. 160 ifa$="2"thenprintchr$(142);"[147]dezimal [144]zu hexadezimal":goto2000
  23. 170 ifa$="3"thenprintchr$(142);"[147]hexadezimal [144]zu binaer":goto3000
  24. 180 ifa$="4"thenprintchr$(142);"[147]binaer [144]zu hexadezimal":goto4000
  25. 190 ifa$="5"thenprintchr$(142);"[147]dezimal [144]zu binaer":goto5000
  26. 200 ifa$="6"thenprintchr$(142);"[147]binaer [144]zu dezimal":goto6000
  27. 210 ifa$="_"thenprintchr$(142);"[147]":end
  28. 220 goto140
  29. 997 rem:                             :
  30. 998 rem:   hexadecimal to decimal    :
  31. 999 rem:                             :
  32. 1000 a$="":input"input hex[144]";a$:ifa$=""then30
  33. 1010 iflen(a$)>4then30
  34. 1020 gosub1030:goto1070
  35. 1030 d=0:fori=1tolen(a$):t$=mid$(a$,len(a$)-i+1,1)
  36. 1040 forj=0to15:ift$=h$(j)then1060
  37. 1050 nextj:goto30
  38. 1060 d=d+(16^(i-1))*j:nexti:d=int(d):return
  39. 1070 printtab(19);"[145]";int(d);"":goto1000
  40. 1997 rem:                            :
  41. 1998 rem:   decimal to hexadecimal   :
  42. 1999 rem:                            :
  43. 2000 d=-1:input"input dec[144]";d:d=int(d):ifd<0ord>65535then30
  44. 2010 gosub2020:goto2060
  45. 2020 t=int(d/4096):a$=h$(t):d=int(d-t*4096)
  46. 2030 t=int(d/256):a$=a$+h$(t):d=int(d-t*256)
  47. 2040 t=int(d/16):a$=a$+h$(t):d=int(d-t*16)
  48. 2050 a$=a$+h$(d):return
  49. 2060 printtab(21);"[145]";a$;"":goto2000
  50. 2997 rem:                            :
  51. 2998 rem:   hexadecimal to binary    :
  52. 2999 rem:                            :
  53. 3000 a$="":input"input hex[144]";a$:ifa$=""then30
  54. 3010 iflen(a$)>2then30
  55. 3020 gosub1030:gosub3040
  56. 3030 printtab(18);"[145]";a$;"":goto3000
  57. 3040 a$="":fori=0to7:if(dand2^i)then3060
  58. 3050 a$="0"+a$:next:return
  59. 3060 a$="1"+a$:next:return
  60. 3997 rem:                            :
  61. 3998 rem:   binary to hexadecimal    :
  62. 3999 rem:                            :
  63. 4000 a$="":input"input bin[144]";a$:ifa$=""orlen(a$)>8then30
  64. 4010 gosub4020:a$="":gosub2040:printtab(20);"[145]";a$;"":goto4000
  65. 4020 d=0:fori=1tolen(a$):ifmid$(a$,len(a$)-i+1,1)="0"thennext:d=int(d):return
  66. 4030 ifmid$(a$,len(a$)-i+1,1)="1"thend=d+2^(i-1):next:d=int(d):return
  67. 4040 goto30
  68. 4997 rem:                            :
  69. 4998 rem:     decimal to binary      :
  70. 4999 rem:                            :
  71. 5000 d=-1:input"input dec[144]";d:d=int(d):ifd<0ord>255then30
  72. 5010 gosub3040:printtab(17);"[145]";a$;"":goto5000
  73. 5997 rem:                            :
  74. 5998 rem:     binary to decimal      :
  75. 5999 rem:                            :
  76. 6000 a$="":input"input bin[144]";a$:ifa$=""orlen(a$)>8then30
  77. 6010 gosub4020:printtab(20);"[145]";d;"":goto6000
  78.