home *** CD-ROM | disk | FTP | other *** search
/ Floppy Magazine 1986 #2 / Floppy_Magazine_86-2_1986_Megasystems_Oy_fi.d64 / fmfkey (.txt) < prev    next >
Commodore BASIC  |  2023-02-26  |  4KB  |  106 lines
  1. 0 rem --- multifunction fkey editor ---
  2. 1 rem ---        version 2.0        ---
  3. 2 rem ---      (c) megasystems      ---
  4. 3 rem ---  by jokoware, 19-feb-1986 ---
  5. 4 rem
  6. 5 ifa<>1thena=1:load"standard keyfile",8,1
  7. 10 poke53280,11:poke53281,11:poke646,0
  8. 40 ifpeek(655)<>72thenpoke655,72
  9. 50 ifpeek(656)<>235thenpoke656,235
  10. 80 fa(1)=49926:fl(1)=49999:fa(2)=50006:fl(2)=50079:fa(3)=50086:fl(3)=50159
  11. 82 fa(4)=50166:fl(4)=50239:fa(5)=50246:fl(5)=50319:fa(6)=50326:fl(6)=50399
  12. 84 fa(7)=50406:fl(7)=50479:fa(8)=50486:fl(8)=50559
  13. 86 f(1)=1:f(2)=3:f(3)=5:f(4)=7:f(5)=2:f(6)=4:f(7)=6:f(8)=8
  14. 99 rem --- menu -----------------------
  15. 100 print"[147]    *** [205][213][204][212][201][198][213][206][195][212][201][207][206] [198][203][197][217] [197][196][201][212][207][210] ***"
  16. 110 print"[214]ersion 2.0           ([195]) [202]o[203]o[215]are, 1986"
  17. 120 forx=1to40:print"[163]";:next:print
  18. 130 ifpeek(49152)=32andpeek(49153)=204then150
  19. 140 print"[204]ataa tiedosto ennen kuin kaytat":print"tata ohjelmaa!":end
  20. 150 print" -1-  [197]ditoi funktionappainta."
  21. 160 print" -2-  [205]uuta vareja."
  22. 170 print" -3-  [205]uuta kirjoitus-aanta."
  23. 180 print" -4-  [212]alleta tiedosto."
  24. 185 print" -5-  [204]opetus - aktivoi nappaimet."
  25. 190 forx=1to40:print"[164]";:next:print
  26. 200 print" [214]alitse 1-5"
  27. 210 geta$:ifa$=""then210
  28. 220 onval(a$)goto240,450,530,670,800
  29. 230 goto210
  30. 239 rem --- fkey editor ---------------
  31. 240 print"[145] [208]aina sita funktiota, jota aiot         editoida!"
  32. 250 geta$:ifa$=""then250
  33. 260 ifasc(a$)<133orasc(a$)>140then250
  34. 270 k=asc(a$)-132:k=f(k)
  35. 280 print"[147] ";:fori=fa(k)-5tofa(k)-2:printchr$(peek(i));:next:print" [146]"
  36. 290 print"[205]ax. 74 merk.":print"_ = [210]eturn, [195][200][210]$(13)"
  37. 292 print"[203]orvaa pilkku pisteella.":print"[203]orvaa kaksoispiste ([195]omm/[203]):lla."
  38. 298 forx=1to40:print"[164]";:next:print
  39. 300 f$="":q$="":fori=fa(k)tofl(k):ifpeek(i)=0then310
  40. 305 f$=f$+chr$(peek(i)):next
  41. 310 printf$;:forx=1tolen(f$):print"[157]";:next
  42. 320 poke19,1:inputq$:poke19,0:print:print
  43. 322 forx=1tolen(q$):a$=mid$(q$,x,1):ifa$="."thena$=","
  44. 324 ifa$="[161]"thena$=":"
  45. 326 printa$;:next:print:forx=1to40:print"[164]";:next:print
  46. 330 print"[207]nko oikein? ([203]/[197]) >";
  47. 340 geta$:ifa$<>"k"anda$<>"e"then340
  48. 350 ifa$="e"then280
  49. 360 print" - [203]ylla."
  50. 362 iflen(q$)<74thenq$=q$+chr$(0):goto362
  51. 370 fori=fa(k)tofl(k):a$=mid$(q$,i-fa(k)+1,1)
  52. 380 rem ifa$="_"thena$+chr$(13)
  53. 390 ifa$="[161]"thena$=":"
  54. 400 ifa$="."thena$=","
  55. 410 pokei,asc(a$):next
  56. 420 print"[198]unktio on talletettu muistiin.":print"-- [208]aina jotain nappainta! --"
  57. 430 geta$:ifa$=""then430
  58. 440 goto100
  59. 449 rem --- colours -------------------
  60. 450 print"[147] [214]arien muutos [146]"
  61. 460 print"[212]amanhetkiset varit ovat:"
  62. 470 print"[210]ajaus.";peek(49334):print"[210]uutu .";peek(49339)
  63. 480 print"[212]eksti .";peek(49344);""
  64. 490 poke19,1:input"[213]usi taustavari? >";x:poke49334,x:poke53280,x:print
  65. 500 input"[213]usi ruutuvari?  >";x:poke49339,x:poke53281,x:print
  66. 510 input"[213]usi tekstivari? >";x:poke49344,x:poke646,x:poke19,0:print
  67. 520 goto100
  68. 529 rem --- key klick effect ----------
  69. 530 print"[147] [193]seta kirjoitusaani. [146]":poke650,255
  70. 532 fori=54272to54296:pokei,0:next
  71. 535 poke54296,15:poke54277,20:poke54273,150
  72. 540 print"[212]amanhetkiset arvot:"
  73. 550 print"[203]ork.    [157][157][157][157]";peek(49177):print"[208]ituus    [157][157][157][157]";peek(49172)
  74. 560 print"      + -   [205]uuta korkeutta":print"[211][200][201][198][212] + -   [205]uuta pituutta"
  75. 570 print"[211][208][193][195][197]       [212]esti.":print"[210][197][212][213][210][206]      [212]alleta uudet arvot."
  76. 575 print"       _    [208]alauta alkuperaiset arvot."
  77. 580 geta$:ifa$=""then580
  78. 582 ifa$=chr$(13)thenpoke650,0:goto100
  79. 585 ifa$=" "then650
  80. 587 ifa$="_"then640
  81. 590 ifa$="+"thenifpeek(49177)<255thenpoke49177,peek(49177)+1
  82. 600 ifa$="-"thenifpeek(49177)>0thenpoke49177,peek(49177)-1
  83. 610 ifa$="[219]"thenifpeek(49172)<255thenpoke49172,peek(49172)+1
  84. 620 ifa$="[221]"thenifpeek(49172)>0thenpoke49172,peek(49172)-1
  85. 630 print"":goto540
  86. 640 poke49177,150:poke49172,32:goto630
  87. 650 poke54277,peek(49172):poke54273,peek(49177):poke54276,32:poke54276,33
  88. 660 goto580
  89. 669 rem --- save key file -------------
  90. 670 print"[147] [212]iedoston talletus. [146]":n$=""
  91. 680 poke19,1:input"[212]iedoston nimi? >*[157]";n$:poke19,0:print
  92. 690 n$=left$(n$,16):ifn$="*"then100
  93. 700 print"([204])evy vai ([203])asetti >";
  94. 710 geta$:ifa$<>"l"anda$<>"k"then710
  95. 720 ifa$="k"thenprint"[203]asetti":de=1
  96. 730 ifa$="l"thenprint"[204]evy":de=8
  97. 740 poke251,peek(43):poke252,peek(44):poke253,peek(45):poke254,peek(46)
  98. 750 printchr$(142);"[147]poke43,0:poke44,192:poke45,0:poke46,198"
  99. 760 print"talletus";chr$(34);n$;chr$(34);",";de;""
  100. 780 print"p[207]43,p[197](251):p[207]44,p[197](252):p[207]45,p[197](253):p[207]46,p[197](254):run"
  101. 790 poke631,19:fori=632to636:pokei,13:next:poke198,6:end
  102. 800 print"[145] [207]letko varma? ([203]/[197]) >"
  103. 810 geta$:ifa$<>"k"anda$<>"e"then810
  104. 820 ifa$="e"then100
  105. 830 printchr$(142):sys49152
  106.