home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Dimension 64 2
/
Dimension_64_Nr.02_19xx_-_de_Side_A.d64
/
def.sekt.mark
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2023-02-26
|
1KB
|
43 lines
0 sys42926
30 print"[147]"
35 print" markieren defekter sektoren "
36 print" in der bam ok"
37 input"def. diskette einlegen und return";a$:print"moment bitte...."
38 open1,8,15,"v:":close1
39 print"[147] bitte geben sie nacheinander"
40 print"die defekten [146]spur-und sektornummern an:":j=0
45 dimq (255)
47 goto 90
50 sp=0:se=0
55 input"spur, sektor (0,0 = ende!)";sp,se:if sp=0 and se=0 then return
60 if (sp > 35 or sp<1) or (se<0 or se > 20) then print"ungueltig !":goto50
69 sp = sp * 4:by=int(se/8):bi=se-8*by:bi=2^bi
70 sp=sp+by+1
71 if(q(sp)andbi)=0then print" dieser sektor war schon belegt! ":return
72 q(sp)=q(sp) and (255-bi):sp=sp-by-1
73 ifq(sp)thenq(sp)=q(sp)-1:print"uebrige bloecke dieser spur:"q(sp):j=j+1:return
74 print"spur 18 kaputt! disk nicht verwenden.":stop
80 print"bitte kontrollieren:";j" bloecke":input"sollen gekillt werden j/n";a$
82 if a$<>"j"then run
83 return
90 open15,8,15:open5,8,5,"#":print#15,"u1:5,"0,18,0
140 fori=0to255
150 get#5,a$:q(i)=asc(a$+chr$(0))
170 next
175 close5
187 gosub 50:if sp=0 and se=0 then 200
199 goto 187
200 gosub80:open2,8,2,"#"
210 fori=2to255
212 print#15,"b-p:"2,i
214 print#2,chr$(q(i));
216 next
220 print#15,"u2:2,"0,18,0
239 close2
240 print"[158]erledigt!"
250 print#15,"i":close15
300 print"tip: auf dieser diskette "
310 print"kein validate durchfuehren!!"
320 print"die defekten sektoren werden"
330 print" sonst wieder frei."