home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / dateentry.itk < prev    next >
Encoding:
Text File  |  2003-09-01  |  15.4 KB  |  425 lines
  1. #
  2. # Dateentry
  3. # ----------------------------------------------------------------------
  4. # Implements a quicken style date entry field with a popup calendar
  5. # by combining the datefield and calendar widgets together.  This
  6. # allows a user to enter the date via the keyboard or by using the
  7. # mouse by selecting the calendar icon which brings up a popup calendar.
  8. # ----------------------------------------------------------------------
  9. #   AUTHOR:  Mark L. Ulferts          E-mail: mulferts@austin.dsccc.com
  10. #
  11. #   @(#) $Id: dateentry.itk,v 1.6 2002/09/05 19:33:58 smithc Exp $
  12. # ----------------------------------------------------------------------
  13. #            Copyright (c) 1997 DSC Technologies Corporation
  14. # ======================================================================
  15. # Permission to use, copy, modify, distribute and license this software 
  16. # and its documentation for any purpose, and without fee or written 
  17. # agreement with DSC, is hereby granted, provided that the above copyright 
  18. # notice appears in all copies and that both the copyright notice and 
  19. # warranty disclaimer below appear in supporting documentation, and that 
  20. # the names of DSC Technologies Corporation or DSC Communications 
  21. # Corporation not be used in advertising or publicity pertaining to the 
  22. # software without specific, written prior permission.
  23. # 
  24. # DSC DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE, INCLUDING 
  25. # ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, AND NON-
  26. # INFRINGEMENT. THIS SOFTWARE IS PROVIDED ON AN "AS IS" BASIS, AND THE
  27. # AUTHORS AND DISTRIBUTORS HAVE NO OBLIGATION TO PROVIDE MAINTENANCE, 
  28. # SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS. IN NO EVENT SHALL 
  29. # DSC BE LIABLE FOR ANY SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR 
  30. # ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
  31. # WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTUOUS ACTION,
  32. # ARISING OUT OF OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS 
  33. # SOFTWARE.
  34. # ======================================================================
  35. #
  36. # ----------------------------------------------------------------------
  37. #
  38. # Modified 2001-10-23 by Mark Alston to pass options to the datefield 
  39. # constructor.  Needed to allow use of new option -int which lets the 
  40. # user use dates in YYYY-MM-DD format as well as MM/DD/YYYY format.
  41. #
  42. # option -int yes sets dates to YYYY-MM-DD format
  43. #        -int no sets dates to MM/DD/YYYY format.
  44. #
  45. # ----------------------------------------------------------------------
  46. #
  47. # Usual options.
  48. #
  49. itk::usual Dateentry {
  50.     keep -background -borderwidth -currentdatefont -cursor \
  51.     -datefont -dayfont -foreground -highlightcolor \
  52.     -highlightthickness -labelfont -textbackground -textfont \
  53.     -titlefont -int
  54. }
  55.  
  56. # ------------------------------------------------------------------
  57. #                              DATEENTRY
  58. # ------------------------------------------------------------------
  59. itcl::class iwidgets::Dateentry {
  60.     inherit iwidgets::Datefield
  61.  
  62.     constructor {args} {
  63.     eval Datefield::constructor $args
  64.     } {}
  65.  
  66.     itk_option define -grab grab Grab "global"
  67.     itk_option define -icon icon Icon {}
  68.     
  69.     #
  70.     # The calendar widget isn't created until needed, yet we need
  71.     # its options to be available upon creation of a dateentry widget.
  72.     # So, we'll define them in these class now so they can just be
  73.     # propagated onto the calendar later.
  74.     #
  75.     itk_option define -days days Days {Su Mo Tu We Th Fr Sa}
  76.     itk_option define -forwardimage forwardImage Image {}
  77.     itk_option define -backwardimage backwardImage Image {}
  78.     itk_option define -weekdaybackground weekdayBackground Background \#d9d9d9
  79.     itk_option define -weekendbackground weekendBackground Background \#d9d9d9
  80.     itk_option define -outline outline Outline \#d9d9d9
  81.     itk_option define -buttonforeground buttonForeground Foreground blue
  82.     itk_option define -foreground foreground Foreground black
  83.     itk_option define -selectcolor selectColor Foreground red
  84.     itk_option define -selectthickness selectThickness SelectThickness 3
  85.     itk_option define -titlefont titleFont Font \
  86.     -*-helvetica-bold-r-normal--*-140-*
  87.     itk_option define -dayfont dayFont Font \
  88.     -*-helvetica-medium-r-normal--*-120-*
  89.     itk_option define -datefont dateFont Font \
  90.     -*-helvetica-medium-r-normal--*-120-*
  91.     itk_option define -currentdatefont currentDateFont Font \
  92.     -*-helvetica-bold-r-normal--*-120-*
  93.     itk_option define -startday startDay Day sunday
  94.     itk_option define -height height Height 165
  95.     itk_option define -width width Width 200
  96.     itk_option define -state state State normal
  97.  
  98.     protected {
  99.     method _getPopupDate {date}
  100.     method _releaseGrab {}
  101.     method _releaseGrabCheck {rootx rooty}
  102.     method _popup {}
  103.     method _getDefaultIcon {}
  104.  
  105.         common _defaultIcon ""
  106.     }
  107. }
  108.  
  109. #
  110. # Provide a lowercased access method for the dateentry class.
  111. # 
  112. proc ::iwidgets::dateentry {pathName args} {
  113.     uplevel ::iwidgets::Dateentry $pathName $args
  114. }
  115.  
  116. # ------------------------------------------------------------------
  117. #                        CONSTRUCTOR
  118. # ------------------------------------------------------------------
  119. itcl::body iwidgets::Dateentry::constructor {args} {
  120.     #
  121.     # Create an icon label to act as a button to bring up the 
  122.     # calendar popup.
  123.     #
  124.     itk_component add iconbutton {
  125.     label $itk_interior.iconbutton -relief raised
  126.     } {
  127.     keep -borderwidth -cursor -foreground 
  128.     }
  129.     grid $itk_component(iconbutton) -row 0 -column 0 -sticky ns
  130.     
  131.     #
  132.     # Initialize the widget based on the command line options.
  133.     #
  134.     eval itk_initialize $args
  135. }
  136.  
  137. # ------------------------------------------------------------------
  138. #                             OPTIONS
  139. # ------------------------------------------------------------------
  140.  
  141. # ------------------------------------------------------------------
  142. # OPTION: -icon
  143. #
  144. # Specifies the calendar icon image to be used in the date.
  145. # Should one not be provided, then a default pixmap will be used
  146. # if possible, bitmap otherwise.
  147. # ------------------------------------------------------------------
  148. itcl::configbody iwidgets::Dateentry::icon {
  149.     if {$itk_option(-icon) == {}} {
  150.     $itk_component(iconbutton) configure -image [_getDefaultIcon]
  151.     } else {
  152.     if {[lsearch [image names] $itk_option(-icon)] == -1} {
  153.         error "bad icon option \"$itk_option(-icon)\":\
  154.                    should be an existing image"
  155.     } else {
  156.         $itk_component(iconbutton) configure -image $itk_option(-icon)
  157.     }
  158.     }
  159. }
  160.  
  161. # ------------------------------------------------------------------
  162. # OPTION: -grab
  163. #
  164. # Specifies the grab level, local or global, to be obtained when 
  165. # bringing up the popup calendar.  The default is global.
  166. # ------------------------------------------------------------------
  167. itcl::configbody iwidgets::Dateentry::grab {
  168.     switch -- $itk_option(-grab) {
  169.     "local" - "global" {}
  170.     default {
  171.         error "bad grab option \"$itk_option(-grab)\":\
  172.                    should be local or global"
  173.     }
  174.     }
  175. }
  176.  
  177. # ------------------------------------------------------------------
  178. # OPTION: -state
  179. #
  180. # Specifies the state of the widget which may be disabled or
  181. # normal.  A disabled state prevents selection of the date field
  182. # or date icon button.
  183. # ------------------------------------------------------------------
  184. itcl::configbody iwidgets::Dateentry::state {
  185.     switch -- $itk_option(-state) {
  186.     normal {
  187.         bind $itk_component(iconbutton) <Button-1> [itcl::code $this _popup]
  188.     }
  189.     disabled {
  190.         bind $itk_component(iconbutton) <Button-1> {}
  191.     }
  192.     }
  193. }
  194.  
  195. # ------------------------------------------------------------------
  196. #                            METHODS
  197. # ------------------------------------------------------------------
  198.  
  199. # ------------------------------------------------------------------
  200. # PROTECTED METHOD: _getDefaultIcon
  201. #
  202. # This method is invoked uto retrieve the name of the default icon
  203. # image displayed in the icon button.
  204. # ------------------------------------------------------------------
  205. itcl::body iwidgets::Dateentry::_getDefaultIcon {} {
  206.     if {[lsearch [image types] pixmap] != -1} {
  207.       set _defaultIcon [image create pixmap -data {
  208.       /* XPM */
  209.       static char *calendar[] = {
  210.       /* width height num_colors chars_per_pixel */
  211.       "    25    20        6            1",
  212.       /* colors */
  213.       ". c #808080",
  214.       "# c #040404",
  215.       "a c #848484",
  216.       "b c #fc0404",
  217.       "c c #fcfcfc",
  218.       "d c #c0c0c0",
  219.       /* pixels */
  220.       "d##########d###########dd",
  221.       "d#ccccccccc##ccccccccca#d",
  222.       "##ccccccccc.#ccccccccc..#",
  223.       "##cccbbcccca#cccbbbccca.#",
  224.       "##cccbbcccc.#ccbbbbbcc..#",
  225.       "##cccbbccc####ccccbbcc..#",
  226.       "##cccbbcccca#ccccbbbcca.#",
  227.       "##cccbbcccc.#cccbbbccc..#",
  228.       "##cccbbcccca#ccbbbcccca.#",
  229.       "##cccbbbccc.#ccbbbbbcc..#",
  230.       "##ccccccccc.#ccccccccc..#",
  231.       "##ccccccccca#ccccccccca.#",
  232.       "##cc#####c#cd#c#####cc..#",
  233.       "##cccccccc####cccccccca.#",
  234.       "##cc#####cc.#cc#####cc..#",
  235.       "##ccccccccc.#ccccccccc..#",
  236.       "##ccccccccc.#ccccccccc..#",
  237.       "##..........#...........#",
  238.       "###..........#..........#",
  239.       "#########################"
  240.      };
  241.     }]
  242.     } else {
  243.     set _defaultIcon [image create bitmap -data {
  244.         #define calendr2_width 25
  245.         #define calendr2_height 20
  246.         static char calendr2_bits[] = {
  247.         0xfe,0xf7,0x7f,0xfe,0x02,0x18,0xc0,0xfe,0x03,
  248.         0x18,0x80,0xff,0x63,0x10,0x47,0xff,0x43,0x98,
  249.         0x8a,0xff,0x63,0x3c,0x4c,0xff,0x43,0x10,0x8a,
  250.         0xff,0x63,0x18,0x47,0xff,0x23,0x90,0x81,0xff,
  251.         0xe3,0x98,0x4e,0xff,0x03,0x10,0x80,0xff,0x03,
  252.         0x10,0x40,0xff,0xf3,0xa5,0x8f,0xff,0x03,0x3c,
  253.         0x40,0xff,0xf3,0x99,0x8f,0xff,0x03,0x10,0x40,
  254.         0xff,0x03,0x18,0x80,0xff,0x57,0x55,0x55,0xff,
  255.         0x57,0xb5,0xaa,0xff,0xff,0xff,0xff,0xff};
  256.         }]
  257.     }
  258.  
  259.     #
  260.     # Since this image will only need to be created once, we redefine
  261.     # this method to just return the image name for subsequent calls.
  262.     #
  263.     itcl::body ::iwidgets::Dateentry::_getDefaultIcon {} {
  264.     return $_defaultIcon
  265.     }
  266.  
  267.     return $_defaultIcon
  268. }
  269.  
  270. # ------------------------------------------------------------------
  271. # PROTECTED METHOD: _popup
  272. #
  273. # This method is invoked upon selection of the icon button.  It 
  274. # creates a calendar widget within a toplevel popup, calculates 
  275. # the position at which to display the calendar, performs a grab
  276. # and displays the calendar.
  277. # ------------------------------------------------------------------
  278. itcl::body iwidgets::Dateentry::_popup {} {
  279.     #
  280.     # First, let's nullify the icon binding so that any another 
  281.     # selections are ignored until were done with this one.  Next,
  282.     # change the relief of the icon.
  283.     #
  284.     bind $itk_component(iconbutton) <Button-1> {}
  285.     $itk_component(iconbutton) configure -relief sunken
  286.  
  287.     #
  288.     # Create a withdrawn toplevel widget and remove the window 
  289.     # decoration via override redirect.
  290.     #
  291.     itk_component add -private popup {
  292.     toplevel $itk_interior.popup 
  293.     } 
  294.     $itk_component(popup) configure -borderwidth 2 -background black
  295.     wm withdraw $itk_component(popup)
  296.     wm overrideredirect $itk_component(popup) 1
  297.  
  298.     #
  299.     # Add a binding to button 1 events in order to detect mouse
  300.     # clicks off the calendar in which case we'll release the grab.
  301.     # Also add a binding for Escape to always release.
  302.     #
  303.     bind $itk_component(popup) <1> [itcl::code $this _releaseGrabCheck %X %Y]
  304.     bind $itk_component(popup) <KeyPress-Escape> [itcl::code $this _releaseGrab]
  305.  
  306.     #
  307.     # Create the calendar widget and set its cursor properly.
  308.     #
  309.     itk_component add calendar {
  310.     iwidgets::Calendar $itk_component(popup).calendar \
  311.         -command [itcl::code $this _getPopupDate %d] \
  312.         -int $itk_option(-int)
  313.     } {
  314.     usual
  315.     keep -days -forwardimage -backwardimage -weekdaybackground \
  316.         -weekendbackground -outline -buttonforeground -selectcolor \
  317.         -selectthickness -titlefont -dayfont -datefont \
  318.         -currentdatefont -startday -width -height
  319.     }
  320.     grid $itk_component(calendar) -row 0 -column 0
  321.     $itk_component(calendar) configure -cursor top_left_arrow
  322.  
  323.     #
  324.     # The icon button will be used as the basis for the position of the
  325.     # popup on the screen.  We'll always attempt to locate the popup
  326.     # off the lower right corner of the button.  If that would put
  327.     # the popup off the screen, then we'll put above the upper left.
  328.     #
  329.     set rootx [winfo rootx $itk_component(iconbutton)]
  330.     set rooty [winfo rooty $itk_component(iconbutton)]
  331.     set popupwidth [winfo reqwidth $itk_component(popup)]
  332.     set popupheight [winfo reqheight $itk_component(popup)]
  333.  
  334.     set popupx [expr {$rootx + 3 + \
  335.             [winfo width $itk_component(iconbutton)]}]
  336.     set popupy [expr {$rooty + 3 + \
  337.             [winfo height $itk_component(iconbutton)]}]
  338.  
  339.     if {(($popupx + $popupwidth) > [winfo screenwidth .]) || \
  340.         (($popupy + $popupheight) > [winfo screenheight .])} {
  341.     set popupx [expr {$rootx - 3 - $popupwidth}]
  342.     set popupy [expr {$rooty - 3 - $popupheight}]
  343.     }
  344.     
  345.     #
  346.     # Get the current date from the datefield widget and both
  347.     # show and select it on the calendar.
  348.     #
  349.     # Added catch for bad dates. Calendar then shows current date.
  350.     if [catch "$itk_component(calendar) show [get]" err] {
  351.     $itk_component(calendar) show now
  352.     $itk_component(calendar) select now
  353.     } else {
  354.     $itk_component(calendar) select [get]
  355.     }
  356.     #
  357.     # Display the popup at the calculated position.
  358.     #
  359.     wm geometry $itk_component(popup) +$popupx+$popupy
  360.     wm deiconify $itk_component(popup)
  361.     tkwait visibility $itk_component(popup)
  362.  
  363.     #
  364.     # Perform either a local or global grab based on the -grab option.
  365.     #
  366.     if {$itk_option(-grab) == "local"} {
  367.     grab $itk_component(popup)
  368.     } else {
  369.     grab -global $itk_component(popup)
  370.     }
  371.  
  372.     #
  373.     # Make sure the widget is above all others and give it focus.
  374.     #
  375.     raise $itk_component(popup)
  376.     focus $itk_component(calendar)
  377. }
  378.  
  379. # ------------------------------------------------------------------
  380. # PROTECTED METHOD: _popupGetDate
  381. #
  382. # This method is the callback for selection of a date on the 
  383. # calendar.  It releases the grab and sets the date in the
  384. # datefield widget.
  385. # ------------------------------------------------------------------
  386. itcl::body iwidgets::Dateentry::_getPopupDate {date} {
  387.     _releaseGrab 
  388.     show $date
  389. }
  390.  
  391. # ------------------------------------------------------------------
  392. # PROTECTED METHOD: _releaseGrabCheck rootx rooty
  393. #
  394. # This method handles mouse button 1 events.  If the selection
  395. # occured within the bounds of the calendar, then return normally
  396. # and let the calendar handle the event.  Otherwise, we'll drop
  397. # the calendar and release the grab.
  398. # ------------------------------------------------------------------
  399. itcl::body iwidgets::Dateentry::_releaseGrabCheck {rootx rooty} {
  400.     set calx [winfo rootx $itk_component(calendar)]
  401.     set caly [winfo rooty $itk_component(calendar)]
  402.     set calwidth [winfo reqwidth $itk_component(calendar)]
  403.     set calheight [winfo reqheight $itk_component(calendar)]
  404.  
  405.     if {($rootx < $calx) || ($rootx > ($calx + $calwidth)) || \
  406.         ($rooty < $caly) || ($rooty > ($caly + $calheight))} {
  407.     _releaseGrab
  408.     return -code break
  409.     }
  410. }
  411.  
  412. # ------------------------------------------------------------------
  413. # PROTECTED METHOD: _releaseGrab
  414. #
  415. # This method releases the grab, destroys the popup, changes the 
  416. # relief of the button back to raised and reapplies the binding
  417. # to the icon button that engages the popup action.
  418. # ------------------------------------------------------------------
  419. itcl::body iwidgets::Dateentry::_releaseGrab {} {
  420.     grab release $itk_component(popup)
  421.     $itk_component(iconbutton) configure -relief raised
  422.     destroy $itk_component(popup) 
  423.     bind $itk_component(iconbutton) <Button-1> [itcl::code $this _popup]
  424. }
  425.