home *** CD-ROM | disk | FTP | other *** search
/ PC World 2005 June / PCWorld_2005-06_cd.bin / software / vyzkuste / firewally / firewally.exe / framework-2.3.exe / canvasprintbox.itk < prev    next >
Encoding:
Text File  |  2003-09-01  |  31.5 KB  |  1,112 lines
  1. #
  2. # CanvasPrintBox v1.5
  3. # ----------------------------------------------------------------------
  4. # Implements a print box for printing the contents of a canvas widget
  5. # to a printer or a file. It is possible to specify page orientation, the
  6. # number of pages to print the image on and if the output should be
  7. # stretched to fit the page.
  8. # 
  9. # CanvasPrintBox is a "super-widget" that can be used as an
  10. # element in ones own GUIs. It is used to print the contents
  11. # of a canvas (called the source hereafter) to a printer or a
  12. # file. Possible settings include: portrait and landscape orientation
  13. # of the output, stretching the output to fit the page while maintaining
  14. # a proper aspect-ratio and posterizing to enlarge the output to fit on
  15. # multiple pages. A stamp-sized copy of the source will be shown (called
  16. # the stamp hereafter) at all times to reflect the effect of changing
  17. # the settings will have on the output.
  18. #
  19. # ----------------------------------------------------------------------
  20. # AUTHOR: Tako Schotanus               EMAIL: Tako.Schotanus@bouw.tno.nl
  21. # ----------------------------------------------------------------------
  22. #                Copyright (c) 1995  Tako Schotanus
  23. # ======================================================================
  24. # Permission is hereby granted, without written agreement and without
  25. # license or royalty fees, to use, copy, modify, and distribute this
  26. # software and its documentation for any purpose, provided that the
  27. # above copyright notice and the following two paragraphs appear in
  28. # all copies of this software.
  29. # 
  30. # IN NO EVENT SHALL THE COPYRIGHT HOLDER BE LIABLE TO ANY PARTY FOR
  31. # DIRECT, INDIRECT, SPECIAL, INCIDENTAL, OR CONSEQUENTIAL DAMAGES 
  32. # ARISING OUT OF THE USE OF THIS SOFTWARE AND ITS DOCUMENTATION, EVEN 
  33. # IF THE COPYRIGHT HOLDER HAS BEEN ADVISED OF THE POSSIBILITY OF SUCH 
  34. # DAMAGE.
  35. #
  36. # THE COPYRIGHT HOLDER SPECIFICALLY DISCLAIMS ANY WARRANTIES, INCLUDING, 
  37. # BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND 
  38. # FITNESS FOR A PARTICULAR PURPOSE.  THE SOFTWARE PROVIDED HEREUNDER IS
  39. # ON AN "AS IS" BASIS, AND THE COPYRIGHT HOLDER HAS NO OBLIGATION TO
  40. # PROVIDE MAINTENANCE, SUPPORT, UPDATES, ENHANCEMENTS, OR MODIFICATIONS.
  41. # ======================================================================
  42.  
  43. #
  44. # Default resources.
  45. #
  46. option add *Canvasprintbox.filename    "canvas.ps"    widgetDefault
  47. option add *Canvasprintbox.hPageCnt    1        widgetDefault
  48. option add *Canvasprintbox.orient    landscape    widgetDefault
  49. option add *Canvasprintbox.output    printer        widgetDefault
  50. option add *Canvasprintbox.pageSize    A4        widgetDefault
  51. option add *Canvasprintbox.posterize    0        widgetDefault
  52. option add *Canvasprintbox.printCmd    lpr        widgetDefault
  53. option add *Canvasprintbox.printRegion    ""        widgetDefault
  54. option add *Canvasprintbox.vPageCnt    1        widgetDefault
  55.  
  56. #
  57. # Usual options.
  58. #
  59. itk::usual Canvasprintbox {
  60.     keep -background -cursor -textbackground -foreground
  61. }
  62.  
  63. #<
  64. #
  65. # CanvasPrintBox is a "super-widget" that can be used as an
  66. # element in ones own GUIs. It is used to print the contents
  67. # of a canvas (called the source hereafter) to a printer or a
  68. # file. Possible settings include: portrait and landscape orientation
  69. # of the output, stretching the output to fit the page while maintaining
  70. # a proper aspect-ratio and posterizing to enlarge the output to fit on
  71. # multiple pages. A stamp-sized copy of the source will be shown (called
  72. # the stamp hereafter) at all times to reflect the effect of changing
  73. # the settings will have on the output.
  74. #
  75. #>
  76. itcl::class iwidgets::Canvasprintbox {
  77.     inherit itk::Widget
  78.  
  79.     #
  80.     # Holds the current state for all check- and radiobuttons.
  81.     #
  82.     itk_option define -filename filename FileName "canvas.ps"
  83.     itk_option define -hpagecnt hPageCnt PageCnt 1
  84.     itk_option define -orient orient Orient "landscape"
  85.     itk_option define -output output Output "printer"
  86.     itk_option define -pagesize pageSize PageSize "A4"
  87.     itk_option define -posterize posterize Posterize 0
  88.     itk_option define -printcmd printCmd PrintCmd ""
  89.     itk_option define -printregion printRegion PrintRegion ""
  90.     itk_option define -stretch stretch Stretch 0
  91.     itk_option define -vpagecnt vPageCnt PageCnt 1
  92.     
  93.     constructor {args} {}
  94.     destructor {}
  95.  
  96.     # ---------------------------------------------------------------
  97.     # PUBLIC
  98.     #----------------------------------------------------------------
  99.     public {
  100.       method getoutput {}
  101.       method print {}
  102.       method refresh {}
  103.       method setcanvas {canv}
  104.       method stop {}
  105.     }
  106.  
  107.     # ---------------------------------------------------------------
  108.     # PROTECTED
  109.     #----------------------------------------------------------------
  110.     protected {
  111.       #
  112.       # Just holds the names of some widgets/objects. "win" is used to
  113.       # determine if the object is fully constructed and initialized.
  114.       #
  115.       variable win ""
  116.       variable canvw ""
  117.     
  118.       #
  119.       # The canvas we want to print. 
  120.       #
  121.       variable canvas ""
  122.     
  123.       #
  124.       # Boolean indicating if the attribute "orient" is set
  125.       # to landscape or not.
  126.       #
  127.       variable rotate 1
  128.     
  129.       #
  130.       # Holds the configure options that were used to create this object.
  131.       #
  132.       variable init_opts ""
  133.     
  134.       #
  135.       # The following attributes hold a list of lines that are
  136.       # currently drawn on the "stamp" to show how the page(s) is/are
  137.       # oriented. The first holds the vertical dividing lines and the
  138.       # second the horizontal ones.
  139.       #
  140.       variable hlines ""
  141.       variable vlines ""
  142.  
  143.       #
  144.       # Updating is set when the thumbnail is being drawn. Settings
  145.       # this to 0 while drawing is still busy will terminate the
  146.       # proces.
  147.       # Restart_update can be set to 1 when the thumbnail is being
  148.       # drawn to force a redraw.
  149.       #
  150.       variable _reposition ""
  151.       variable _update_attr_id ""
  152.  
  153.       method _calc_poster_size {}
  154.       method _calc_print_region {}
  155.       method _calc_print_scale {}
  156.       method _mapEventHandler {}
  157.       method _update_attr {{when later}}
  158.       method _update_canvas {{when later}}
  159.  
  160.       common _globVar
  161.  
  162.       proc ezPaperInfo {size {attr ""} \
  163.         {orient "portrait"} {window ""}} {}
  164.     }
  165. }
  166.  
  167. #
  168. # Provide a lowercased access method for the Canvasprintbox class.
  169. # 
  170. proc ::iwidgets::canvasprintbox {args} {
  171.     uplevel ::iwidgets::Canvasprintbox $args
  172. }
  173.  
  174. # ------------------------------------------------------------------
  175. #                             OPTIONS
  176. # ------------------------------------------------------------------
  177.  
  178. #<
  179. # A list of four coordinates specifying which part of the canvas to print.
  180. # An empty list means that the canvas' entire scrollregion should be
  181. # printed. Any change to this attribute will automatically update the "stamp".
  182. # Defaults to an empty list.
  183. #>
  184. itcl::configbody iwidgets::Canvasprintbox::printregion {
  185.     if {$itk_option(-printregion) != ""
  186.     && [llength $itk_option(-printregion)] != 4} {
  187.         error {bad option "printregion": should contain 4 coordinates}
  188.     }
  189.     _update_canvas
  190. }
  191.  
  192. #<
  193. # Specifies where the postscript output should go: to the printer
  194. # or to a file. Can take on the values "printer" or "file".
  195. # The corresponding entry-widget will reflect the contents of
  196. # either the printcmd attribute or the filename attribute.
  197. #>
  198. itcl::configbody iwidgets::Canvasprintbox::output {
  199.     switch $itk_option(-output) {
  200.         file - printer {
  201.         set _globVar($this,output) $itk_option(-output)
  202.         }
  203.         default {
  204.         error {bad output option \"$itk_option(-output)\":\
  205.             should be file or printer}
  206.         }
  207.     }
  208.     _update_attr
  209. }
  210.  
  211. #<
  212. # The command to execute when printing the postscript output.
  213. # The command will get the postscript directed to its standard
  214. # input. (Only when output is set to "printer")
  215. #>
  216. itcl::configbody iwidgets::Canvasprintbox::printcmd {
  217.     set _globVar($this,printeref) $itk_option(-printcmd)
  218.     _update_attr
  219. }
  220.  
  221. #<
  222. # The file to write the postscript output to (Only when output
  223. # is set to "file"). If posterizing is turned on and hpagecnt
  224. # and/or vpagecnt is more than 1, x.y is appended to the filename
  225. # where x is the horizontal page number and y the vertical page number.
  226. #>
  227. itcl::configbody iwidgets::Canvasprintbox::filename {
  228.     set _globVar($this,fileef) $itk_option(-filename)
  229.     _update_attr
  230. }
  231.  
  232. #<
  233. # The pagesize the printer supports. Changes to this attribute
  234. # will be reflected immediately in the "stamp".
  235. #>
  236. itcl::configbody iwidgets::Canvasprintbox::pagesize {
  237.     set opt [string tolower $itk_option(-pagesize)]
  238.     set lst [string tolower [ezPaperInfo types]]
  239.     if {[lsearch $lst $opt] == -1} {
  240.         error "bad option \"pagesize\": should be one of: [ezPaperInfo types]"
  241.     }
  242.     $itk_component(paperom) select "*[string range $opt 1 end]"
  243.     _update_canvas
  244. }
  245.  
  246. #<
  247. # Determines the orientation of the output to the printer (or file).
  248. # It can take the value "portrait" or "landscape" (default). Changes
  249. # to this attribute will be reflected immediately in the "stamp".
  250. #>
  251. itcl::configbody iwidgets::Canvasprintbox::orient {
  252.     switch $itk_option(-orient) {
  253.         "portrait" - "landscape" {
  254.         $itk_component(orientom) select $itk_option(-orient)
  255.         _update_canvas
  256.  
  257.         }
  258.         default {
  259.         error "bad orient option \"$itk_option(-orient)\":\
  260.             should be portrait or landscape"
  261.         }
  262.     }
  263. }
  264.  
  265. #<
  266. # Determines if the output should be stretched to fill the
  267. # page (as defined by the attribute pagesize) as large as
  268. # possible. The aspect-ratio of the output will be retained
  269. # and the output will never fall outside of the boundaries
  270. # of the page.
  271. #>
  272. itcl::configbody iwidgets::Canvasprintbox::stretch {
  273.     if {$itk_option(-stretch) != 0 && $itk_option(-stretch) != 1} {
  274.         error {bad option "stretch": should be a boolean}
  275.     }
  276.     set _globVar($this,stretchcb) $itk_option(-stretch)
  277.     _update_attr
  278. }
  279.  
  280. #<
  281. # Indicates if posterizing is turned on or not. Posterizing
  282. # the output means that it is possible to distribute the
  283. # output over more than one page. This way it is possible to
  284. # print a canvas/region which is larger than the specified
  285. # pagesize without stretching. If used in combination with
  286. # stretching it can be used to "blow up" the contents of a
  287. # canvas to as large as size as you want (See attributes:
  288. # hpagecnt end vpagecnt). Any change to this attribute will
  289. # automatically update the "stamp".
  290. #>
  291. itcl::configbody iwidgets::Canvasprintbox::posterize {
  292.     if {$itk_option(-posterize) != "0" && $itk_option(-posterize) != "1"} {
  293.         error "expected boolean but got \"$itk_option(-posterize)\""
  294.     }
  295.     set _globVar($this,postercb) $itk_option(-posterize)
  296.     _update_canvas
  297. }
  298.  
  299. #<
  300. # Is used in combination with "posterize" to determine over
  301. # how many pages the output should be distributed. This
  302. # attribute specifies how many pages should be used horizontaly.
  303. # Any change to this attribute will automatically update the "stamp".
  304. #>
  305. itcl::configbody iwidgets::Canvasprintbox::hpagecnt {
  306.     set _globVar($this,hpc) $itk_option(-hpagecnt)
  307.     _update_canvas
  308. }
  309.  
  310. #<
  311. # Is used in combination with "posterize" to determine over
  312. # how many pages the output should be distributed. This
  313. # attribute specifies how many pages should be used verticaly.
  314. # Any change to this attribute will automatically update the "stamp".
  315. #>
  316. itcl::configbody iwidgets::Canvasprintbox::vpagecnt {
  317.     set _globVar($this,vpc) $itk_option(-vpagecnt)
  318.     _update_canvas
  319. }
  320.  
  321. # ------------------------------------------------------------------
  322. # CONSTRUCTOR
  323. # ------------------------------------------------------------------
  324. itcl::body iwidgets::Canvasprintbox::constructor {args} {
  325.     set _globVar($this,output) printer
  326.     set _globVar($this,printeref) ""
  327.     set _globVar($this,fileef) "canvas.ps"
  328.     set _globVar($this,hpc) 1
  329.     set _globVar($this,vpc) 1
  330.     set _globVar($this,postercb) 0
  331.     set _globVar($this,stretchcb) 0
  332.  
  333.     itk_component add canvasframe {
  334.         frame $itk_interior.f18 -bd 2
  335.     }
  336.  
  337.     itk_component add canvas {
  338.         canvas $itk_component(canvasframe).c1 \
  339.             -bd 2 -relief sunken \
  340.             -scrollregion {0c 0c 10c 10c} \
  341.             -width 250
  342.     }
  343.     pack $itk_component(canvas) -expand 1 -fill both
  344.  
  345.     itk_component add outputom {
  346.         iwidgets::Labeledframe $itk_interior.outputom \
  347.             -labelpos nw \
  348.             -labeltext "Output to"
  349.     }
  350.     set cs [$itk_component(outputom) childsite]
  351.  
  352.     itk_component add printerrb {
  353.         radiobutton $cs.printerrb \
  354.             -text Printer \
  355.             -variable [itcl::scope _globVar($this,output)] \
  356.             -anchor w \
  357.             -justify left \
  358.             -value printer \
  359.             -command [itcl::code $this _update_attr]
  360.     } { 
  361.         usual
  362.         rename -font -labelfont labelFont Font
  363.     }
  364.     itk_component add printeref {
  365.         iwidgets::entryfield $cs.printeref \
  366.             -labeltext "command:" \
  367.             -state normal \
  368.             -labelpos w \
  369.             -textvariable [itcl::scope _globVar($this,printeref)]
  370.     }
  371.  
  372.     itk_component add filerb {
  373.         radiobutton $cs.filerb \
  374.             -text File \
  375.             -justify left \
  376.             -anchor w \
  377.             -variable [itcl::scope _globVar($this,output)] \
  378.             -value file \
  379.             -command [itcl::code $this _update_attr]
  380.     } { 
  381.         usual
  382.         rename -font -labelfont labelFont Font
  383.     }
  384.     itk_component add fileef {
  385.         iwidgets::entryfield $cs.fileef \
  386.             -labeltext "filename:" \
  387.             -state disabled \
  388.             -labelpos w \
  389.             -textvariable [itcl::scope _globVar($this,fileef)]
  390.     }
  391.  
  392.     itk_component add propsframe {
  393.         iwidgets::Labeledframe $itk_interior.propsframe \
  394.             -labelpos nw \
  395.             -labeltext "Properties"
  396.     }
  397.     set cs [$itk_component(propsframe) childsite]
  398.  
  399.     itk_component add paperom {
  400.         iwidgets::optionmenu $cs.paperom \
  401.             -labelpos w -cyclicon 1 \
  402.             -labeltext "Paper size:" \
  403.             -command [itcl::code $this refresh]
  404.     } { 
  405.         usual
  406.         rename -font -labelfont labelFont Font
  407.     }
  408.     eval $itk_component(paperom) insert end [ezPaperInfo types]
  409.     $itk_component(paperom) select A4
  410.  
  411.     itk_component add orientom {
  412.         iwidgets::radiobox $itk_interior.orientom \
  413.             -labeltext "Orientation" -command [itcl::code $this refresh]
  414.     }
  415.     $itk_component(orientom) add landscape -text Landscape
  416.     $itk_component(orientom) add portrait -text Portrait
  417.     $itk_component(orientom) select 0
  418.  
  419.     itk_component add stretchcb {
  420.         checkbutton $cs.stretchcb \
  421.             -relief flat \
  422.             -text {Stretch to fit} \
  423.             -justify left \
  424.             -anchor w \
  425.             -variable [itcl::scope _globVar($this,stretchcb)] \
  426.             -command [itcl::code $this refresh]
  427.     } { 
  428.         usual
  429.         rename -font -labelfont labelFont Font
  430.     }
  431.  
  432.     itk_component add postercb {
  433.         checkbutton $cs.postercb \
  434.             -relief flat \
  435.             -text Posterize \
  436.             -justify left \
  437.             -anchor w \
  438.             -variable [itcl::scope _globVar($this,postercb)] \
  439.             -command [itcl::code $this refresh]
  440.     } { 
  441.         usual
  442.         rename -font -labelfont labelFont Font
  443.     }
  444.  
  445.     itk_component add hpcnt {
  446.         iwidgets::entryfield $cs.hpcnt \
  447.             -labeltext on \
  448.             -textvariable [itcl::scope _globVar($this,hpc)] \
  449.             -validate integer -width 3 \
  450.             -command [itcl::code $this refresh]
  451.     }
  452.  
  453.     itk_component add vpcnt {
  454.         iwidgets::entryfield $cs.vpcnt \
  455.             -labeltext by \
  456.             -textvariable [itcl::scope _globVar($this,vpc)] \
  457.             -validate integer -width 3 \
  458.             -command [itcl::code $this refresh]
  459.     }
  460.  
  461.     itk_component add pages {
  462.         label $cs.pages -text pages.
  463.     } { 
  464.         usual
  465.         rename -font -labelfont labelFont Font
  466.     }
  467.     
  468.     set init_opts $args
  469.     
  470.     grid $itk_component(canvasframe) -row 0 -column 0 -rowspan 4 -sticky nsew
  471.     grid $itk_component(propsframe)  -row 0 -column 1 -sticky nsew
  472.     grid $itk_component(outputom)    -row 1 -column 1 -sticky nsew
  473.     grid $itk_component(orientom)    -row 2 -column 1 -sticky nsew
  474.     grid columnconfigure $itk_interior 0 -weight 1
  475.     grid rowconfigure    $itk_interior 3 -weight 1
  476.  
  477.     grid $itk_component(printerrb) -row 0 -column 0 -sticky nsw
  478.     grid $itk_component(printeref) -row 0 -column 1 -sticky nsw
  479.     grid $itk_component(filerb)    -row 1 -column 0 -sticky nsw
  480.     grid $itk_component(fileef)    -row 1 -column 1 -sticky nsw
  481.     iwidgets::Labeledwidget::alignlabels $itk_component(printeref) $itk_component(fileef)
  482.     grid columnconfigure $itk_component(outputom) 1 -weight 1
  483.  
  484.     grid $itk_component(paperom)   -row 0 -column 0 -columnspan 2 -sticky nsw
  485.     grid $itk_component(stretchcb) -row 1 -column 0 -sticky nsw
  486.     grid $itk_component(postercb)  -row 2 -column 0 -sticky nsw
  487.     grid $itk_component(hpcnt)     -row 2 -column 1 -sticky nsw
  488.     grid $itk_component(vpcnt)     -row 2 -column 2 -sticky nsw
  489.     grid $itk_component(pages)     -row 2 -column 3 -sticky nsw
  490.     grid columnconfigure $itk_component(propsframe) 3 -weight 1
  491.  
  492.     eval itk_initialize $args
  493.  
  494.     bind $itk_component(pages) <Map> +[itcl::code $this _mapEventHandler]
  495.     bind $itk_component(canvas) <Configure> +[itcl::code $this refresh]
  496. }
  497.  
  498.  
  499. # ---------------------------------------------------------------
  500. # PUBLIC METHODS
  501. #----------------------------------------------------------------
  502.  
  503. #<
  504. # This is used to set the canvas that has to be printed.
  505. # A stamp-sized copy will automatically be drawn to show how the
  506. # output would look with the current settings.
  507. #
  508. # In:    canv - The canvas to be printed
  509. # Out:    canvas (attrib) - Holds the canvas to be printed
  510. #>    
  511. itcl::body iwidgets::Canvasprintbox::setcanvas {canv} {
  512.     set canvas $canv
  513.     _update_canvas
  514. }
  515.  
  516. #<
  517. # Returns the value of the -printercmd or -filename option
  518. # depending on the current setting of -output.
  519. #
  520. # In:    itk_option (attrib)
  521. # Out:    The value of -printercmd or -filename
  522. #>
  523. itcl::body iwidgets::Canvasprintbox::getoutput {} {
  524.     switch $_globVar($this,output) {
  525.       "file" {
  526.         return $_globVar($this,fileef)
  527.       }
  528.       "printer" {
  529.           return $_globVar($this,printeref)
  530.       }
  531.     }
  532.     return ""
  533. }
  534.  
  535. #<
  536. # Perfrom the actual printing of the canvas using the current settings of
  537. # all the attributes.
  538. #
  539. # In:    itk_option, rotate (attrib)
  540. # Out:    A boolean indicating wether printing was successful
  541. #>
  542. itcl::body iwidgets::Canvasprintbox::print {} {
  543.  
  544.     global env tcl_platform
  545.  
  546.     stop
  547.  
  548.     if {$itk_option(-output) == "file"} {
  549.         set nm $_globVar($this,fileef)
  550.         if {[string range $nm 0 1] == "~/"} {
  551.             set nm "$env(HOME)/[string range $nm 2 end]"
  552.         }
  553.     } else {
  554.         set nm "/tmp/xge[winfo id $canvas]"
  555.     }
  556.  
  557.     set pr [_calc_print_region]
  558.     set x1 [lindex $pr 0]
  559.     set y1 [lindex $pr 1]
  560.     set x2 [lindex $pr 2]
  561.     set y2 [lindex $pr 3]
  562.     set cx [expr {int(($x2 + $x1) / 2)}]
  563.     set cy [expr {int(($y2 + $y1) / 2)}]
  564.     if {!$itk_option(-stretch)} {
  565.         set ps [_calc_poster_size]
  566.         set pshw [expr {int([lindex $ps 0] / 2)}]
  567.         set pshh [expr {int([lindex $ps 1] / 2)}]
  568.         set x [expr {$cx - $pshw}]
  569.         set y [expr {$cy - $pshh}]
  570.         set w [ezPaperInfo $itk_option(-pagesize) pwidth $itk_option(-orient) $win]
  571.         set h [ezPaperInfo $itk_option(-pagesize) pheight $itk_option(-orient) $win]
  572.     } else {
  573.         set x $x1
  574.         set y $y1
  575.         set w [expr {($x2-$x1) / $_globVar($this,hpc)}]
  576.         set h [expr {($y2-$y1) / $_globVar($this,vpc)}]
  577.     }
  578.  
  579.     set i 0
  580.     set px $x
  581.     while {$i < $_globVar($this,hpc)} {
  582.         set j 0
  583.         set py $y
  584.         while {$j < $_globVar($this,vpc)} {
  585.             set nm2 [expr {$_globVar($this,hpc) > 1 || $_globVar($this,vpc) > 1 ? "$nm$i.$j" : $nm}]
  586.  
  587.             if {$itk_option(-stretch)} {
  588.                 $canvas postscript \
  589.                   -file $nm2 \
  590.                   -rotate $rotate \
  591.                   -x $px -y $py \
  592.                   -width $w \
  593.                   -height $h \
  594.                   -pagex [ezPaperInfo $itk_option(-pagesize) centerx] \
  595.                   -pagey [ezPaperInfo $itk_option(-pagesize) centery] \
  596.                   -pagewidth [ezPaperInfo $itk_option(-pagesize) pwidth $itk_option(-orient)] \
  597.                   -pageheight [ezPaperInfo $itk_option(-pagesize) pheight $itk_option(-orient)]
  598.             } else {
  599.                 $canvas postscript \
  600.                   -file $nm2 \
  601.                   -rotate $rotate \
  602.                   -x $px -y $py \
  603.                   -width $w \
  604.                   -height $h \
  605.                   -pagex [ezPaperInfo $itk_option(-pagesize) centerx] \
  606.                   -pagey [ezPaperInfo $itk_option(-pagesize) centery]
  607.             }
  608.  
  609.             if {$itk_option(-output) == "printer"} {
  610.                 set cmd "$itk_option(-printcmd) < $nm2"
  611.                 if {[catch {eval exec $cmd &}]} {
  612.                     return 0
  613.                 }
  614.             }
  615.  
  616.             set py [expr {$py + $h}]
  617.             incr j
  618.         }
  619.         set px [expr {$px + $w}]
  620.         incr i
  621.     }
  622.  
  623.     return 1
  624. }
  625.  
  626. #<
  627. # Retrieves the current value for all edit fields and updates
  628. # the stamp accordingly. Is useful for Apply-buttons.
  629. #>
  630. itcl::body iwidgets::Canvasprintbox::refresh {} {
  631.     stop
  632.     _update_canvas
  633.         return
  634. }
  635.  
  636. #<
  637. # Stops the drawing of the "stamp". I'm currently unable to detect
  638. # when a Canvasprintbox gets withdrawn. It's therefore advised
  639. # that you perform a stop before you do something like that.
  640. #>
  641. itcl::body iwidgets::Canvasprintbox::stop {} {
  642.  
  643.     if {$_reposition != ""} {
  644.         after cancel $_reposition
  645.         set _reposition ""
  646.     }
  647.  
  648.     if {$_update_attr_id != ""} {
  649.         after cancel $_update_attr_id
  650.         set _update_attr_id ""
  651.     }
  652.  
  653.         return
  654. }
  655.  
  656. # ---------------------------------------------------------------
  657. # PROTECTED METHODS
  658. #----------------------------------------------------------------
  659.  
  660. #
  661. # Calculate the total size the output would be with the current
  662. # settings for "pagesize" and "posterize" (and "hpagecnt" and
  663. # "vpagecnt"). This size will be the size of the printable area,
  664. # some space has been substracted to take into account that a
  665. # page should have borders because most printers can't print on
  666. # the very edge of the paper.
  667. #
  668. # In:    posterize, hpagecnt, vpagecnt, pagesize, orient (attrib)
  669. # Out:    A list of two numbers indicating the width and the height
  670. #    of the total paper area which will be used for printing
  671. #    in pixels.
  672. #
  673. itcl::body iwidgets::Canvasprintbox::_calc_poster_size {} {
  674.     set tpw [expr {[ezPaperInfo $itk_option(-pagesize) \
  675.         pwidth $itk_option(-orient) $win]*$_globVar($this,hpc)}]
  676.     set tph [expr {[ezPaperInfo $itk_option(-pagesize) \
  677.         pheight $itk_option(-orient) $win]*$_globVar($this,vpc)}]
  678.  
  679.     return "$tpw $tph"
  680. }
  681.  
  682. #
  683. # Determine which area of the "source" canvas will be printed.
  684. # If "printregion" was set by the "user" this will be used and
  685. # converted to pixel-coordinates. If the user didn't set it
  686. # the bounding box that contains all canvas-items will be used
  687. # instead.
  688. #
  689. # In:    printregion, canvas (attrib)
  690. # Out:    Four floats specifying the region to be printed in
  691. #    pixel-coordinates (topleft & bottomright).
  692. #
  693. itcl::body iwidgets::Canvasprintbox::_calc_print_region {} {
  694.     set printreg [expr {$itk_option(-printregion) != "" 
  695.         ? $itk_option(-printregion) : [$canvas bbox all]}]
  696.  
  697.     if {$printreg != ""} {
  698.         set prx1 [winfo fpixels $canvas [lindex $printreg 0]]
  699.         set pry1 [winfo fpixels $canvas [lindex $printreg 1]]
  700.         set prx2 [winfo fpixels $canvas [lindex $printreg 2]]
  701.         set pry2 [winfo fpixels $canvas [lindex $printreg 3]]
  702.  
  703.         set res "$prx1 $pry1 $prx2 $pry2"
  704.     } else {
  705.         set res "0 0 0 0"
  706.     }
  707.     
  708.     return $res
  709. }
  710.  
  711. #
  712. # Calculate the scaling factor needed if the output was
  713. # to be stretched to fit exactly on the page (or pages).
  714. # If stretching is turned off this will always return 1.0.
  715. #
  716. # In:    stretch (attrib)
  717. # Out:    A float specifying the scaling factor.
  718. #
  719. itcl::body iwidgets::Canvasprintbox::_calc_print_scale {} {
  720.     if {$itk_option(-stretch)} {
  721.         set pr [_calc_print_region]
  722.         set prw [expr {[lindex $pr 2] - [lindex $pr 0]}]
  723.         set prh [expr {[lindex $pr 3] - [lindex $pr 1]}]
  724.         set ps [_calc_poster_size]
  725.         set psw [lindex $ps 0]
  726.         set psh [lindex $ps 1]
  727.         set sfx [expr {$psw / $prw}]
  728.         set sfy [expr {$psh / $prh}]
  729.         set sf [expr {$sfx < $sfy ? $sfx : $sfy}]
  730.         return $sf
  731.     } else {
  732.         return 1.0
  733.     }
  734. }
  735.  
  736. #
  737. # Schedule the thread that makes a copy of the "source"
  738. # canvas to the "stamp".
  739. #
  740. # In:    win, canvas (attrib)
  741. # Out:    -
  742. #
  743. itcl::body iwidgets::Canvasprintbox::_update_canvas {{when later}} {
  744.     if {$win == "" || $canvas == "" || [$canvas find all] == ""} {
  745.         return
  746.     }
  747.     if {$when == "later"} {
  748.         if {$_reposition == ""} {
  749.             set _reposition [after idle [itcl::code $this _update_canvas now]]
  750.         }
  751.         return
  752.     }
  753.  
  754.     _update_attr now
  755.  
  756.     #
  757.     # Make a copy of the "source" canvas to the "stamp".
  758.     #
  759.     if {$_globVar($this,hpc) == [llength $vlines] &&
  760.         $_globVar($this,vpc) == [llength $hlines]} {
  761.         stop
  762.         return
  763.     }    
  764.  
  765.     $canvw delete all
  766.  
  767.     set width  [winfo width $canvw]
  768.     set height [winfo height $canvw]
  769.     set ps [_calc_poster_size]
  770.  
  771.     #
  772.     # Calculate the scaling factor that would be needed to fit the
  773.     # whole "source" into the "stamp". This takes into account the
  774.     # total amount of "paper" that would be needed to print the
  775.     # contents of the "source".
  776.     #
  777.     set xsf [expr {$width/[lindex $ps 0]}]
  778.     set ysf [expr {$height/[lindex $ps 1]}]
  779.     set sf [expr {$xsf < $ysf ? $xsf : $ysf}]
  780.     set w [expr {[lindex $ps 0]*$sf}]
  781.     set h [expr {[lindex $ps 1]*$sf}]
  782.     set x1 [expr {($width-$w)/2}]
  783.     set y1 [expr {($height-$h)/2}]
  784.     set x2 [expr {$x1+$w}]
  785.     set y2 [expr {$y1+$h}]
  786.     set cx [expr {($x2+$x1)/ 2}]
  787.     set cy [expr {($y2+$y1)/ 2}]
  788.  
  789.     set printreg [_calc_print_region]
  790.     set prx1 [lindex $printreg 0]
  791.     set pry1 [lindex $printreg 1]
  792.     set prx2 [lindex $printreg 2]
  793.     set pry2 [lindex $printreg 3]
  794.     set prcx [expr {($prx2+$prx1)/2}]
  795.     set prcy [expr {($pry2+$pry1)/2}]
  796.  
  797.     set psf [_calc_print_scale]
  798.  
  799.     #
  800.     # Copy all items from the "real" canvas to the canvas
  801.     # showing what we'll send to the printer. Bitmaps and
  802.     # texts are not copied because they can't be scaled,
  803.     # a rectangle will be created instead.
  804.     #
  805.     set tsf [expr {$sf * $psf}]
  806.     set dx [expr {$cx-($prcx*$tsf)}]
  807.     set dy [expr {$cy-($prcy*$tsf)}]
  808.     $canvw create rectangle \
  809.         [expr {$x1+0}] \
  810.         [expr {$y1+0}] \
  811.         [expr {$x2-0}] \
  812.         [expr {$y2-0}] -fill white
  813.     set items [eval "$canvas find overlapping $printreg"]
  814.  
  815.     set itemCount [llength $items]
  816.     for {set cnt 0} {$cnt < $itemCount} {incr cnt} {
  817.         #
  818.         # Determine the item's type and coordinates
  819.         #
  820.         set i [lindex $items $cnt]
  821.         set t [$canvas type $i]
  822.         set crds [$canvas coords $i]
  823.  
  824.         #
  825.         # Ask for the item's configuration settings and strip
  826.         # it to leave only a list of option names and values.
  827.         #
  828.         set cfg [$canvas itemconfigure $i]
  829.         set cfg2 ""
  830.         foreach c $cfg {
  831.             if {[llength $c] == 5} {
  832.                 lappend cfg2 [lindex $c 0] [lindex $c 4]
  833.             }
  834.         }
  835.  
  836.         #
  837.         # Handle texts and bitmaps differently: they will
  838.         # be represented as rectangles.
  839.         #
  840.         if {$t == "text" || $t == "bitmap" || $t == "window"} {
  841.             set t "rectangle"
  842.             set crds [$canvas bbox $i]
  843.             set cfg2 "-outline {} -fill gray"
  844.         }
  845.  
  846.         #
  847.         # Remove the arrows from a line item when the scale
  848.         # factor drops below 1/3rd of the original size.
  849.         # This to prevent the arrowheads from dominating the
  850.         # display.
  851.         #
  852.         if {$t == "line" && $tsf < 0.33} {
  853.             lappend cfg2 -arrow none
  854.         }
  855.         
  856.         #
  857.         # Create a copy of the item on the "printing" canvas.
  858.         #
  859.         set i2 [eval "$canvw create $t $crds $cfg2"]
  860.         $canvw scale $i2 0 0 $tsf $tsf
  861.         $canvw move $i2 $dx $dy
  862.  
  863.         if {($cnt%25) == 0} {
  864.             update
  865.         }
  866.         if {$_reposition == ""} {
  867.             return
  868.         }
  869.     }
  870.  
  871.     set p $x1
  872.     set i 1
  873.     set vlines {}
  874.     while {$i < $_globVar($this,hpc)} {
  875.         set p [expr {$p + ($w/$_globVar($this,hpc))}]
  876.         set l [$canvw create line $p $y1 $p $y2]
  877.         lappend vlines $l
  878.         incr i
  879.     }
  880.  
  881.     set p $y1
  882.     set i 1
  883.     set vlines {}
  884.     while {$i < $_globVar($this,vpc)} {
  885.         set p [expr {$p + ($h/$_globVar($this,vpc))}]
  886.         set l [$canvw create line $x1 $p $x2 $p]
  887.         lappend vlines $l
  888.         incr i
  889.     }
  890.  
  891.     set _reposition ""
  892. }
  893.  
  894. #
  895. # Update the attributes to reflect changes made in the user-
  896. # interface.
  897. #
  898. # In:    itk_option (attrib) - the attributes to update
  899. #    itk_component (attrib) - the widgets
  900. #    _globVar (common) - the global var holding the state
  901. #        of all radiobuttons and checkboxes.
  902. # Out:    -
  903. #
  904. itcl::body iwidgets::Canvasprintbox::_update_attr {{when "later"}} {
  905.     if {$when != "now"} {
  906.         if {$_update_attr_id == ""} {
  907.             set _update_attr_id [after idle [itcl::code $this _update_attr now]]
  908.         }
  909.         return
  910.     }
  911.  
  912.         set itk_option(-printcmd)  $_globVar($this,printeref)
  913.         set itk_option(-filename)  $_globVar($this,fileef)
  914.         set itk_option(-output)    $_globVar($this,output)
  915.     set itk_option(-pagesize)  [string tolower [$itk_component(paperom) get]]
  916.     set itk_option(-stretch)   $_globVar($this,stretchcb)
  917.     set itk_option(-posterize) $_globVar($this,postercb)
  918.     set itk_option(-vpagecnt)  $_globVar($this,vpc)
  919.     set itk_option(-hpagecnt)  $_globVar($this,hpc)
  920.     set itk_option(-orient)    [$itk_component(orientom) get]
  921.     set rotate                 [expr {$itk_option(-orient) == "landscape"}]
  922.  
  923.     if {$_globVar($this,output) == "file"} {
  924.         $itk_component(fileef) configure \
  925.             -state normal -foreground $itk_option(-foreground)
  926.         $itk_component(printeref) configure \
  927.             -state disabled -foreground $itk_option(-disabledforeground)
  928.     } else {
  929.         $itk_component(fileef) configure \
  930.             -state disabled -foreground $itk_option(-disabledforeground)
  931.         $itk_component(printeref) configure \
  932.             -state normal -foreground $itk_option(-foreground)
  933.     }
  934.  
  935.     set fg [expr {$_globVar($this,postercb) \
  936.         ? $itk_option(-foreground) : $itk_option(-disabledforeground)}]
  937.  
  938.     $itk_component(vpcnt) configure -foreground $fg
  939.     $itk_component(hpcnt) configure -foreground $fg
  940.     $itk_component(pages) configure -foreground $fg
  941.  
  942.     #
  943.     # Update dependencies among widgets. (For example: disabling
  944.     # an entry-widget when its associated checkbox-button is used
  945.     # to turn of the option (the entry's value is not needed
  946.     # anymore and this should be reflected in the fact that it
  947.     # isn't possible to change it anymore).
  948.     #
  949.     # former method:_update_widgets/_update_UI
  950.     #
  951.     set state [expr {$itk_option(-posterize) ? "normal" : "disabled"}]
  952.     $itk_component(vpcnt) configure -state $state
  953.     $itk_component(hpcnt) configure -state $state
  954.     $itk_component(paperom) select "*[string range $itk_option(-pagesize) 1 end]"
  955.  
  956.     set _update_attr_id ""
  957. }
  958.  
  959. #
  960. # Gets called when the CanvasPrintBox-widget gets mapped.
  961. #
  962. itcl::body iwidgets::Canvasprintbox::_mapEventHandler {} {
  963.     set win $itk_interior
  964.     set canvw $itk_component(canvas)
  965.     if {$canvas != ""} {
  966.         setcanvas $canvas
  967.     }
  968.     _update_attr
  969. }
  970.  
  971. #
  972. # Destroy this object and its associated widgets.
  973. #
  974. itcl::body iwidgets::Canvasprintbox::destructor {} {
  975.     stop
  976. }
  977.  
  978. #
  979. # Hold the information about common paper sizes. A bit of a hack, but it
  980. # should be possible to add your own if you take a look at it.
  981. #
  982. itcl::body iwidgets::Canvasprintbox::ezPaperInfo {size {attr ""} \
  983.     {orient "portrait"} {window ""}} {
  984.     
  985.     set size [string tolower $size]
  986.     set attr [string tolower $attr]
  987.     set orient [string tolower $orient]
  988.     
  989.     case $size in {
  990.         types {
  991.             return "A5 A4 A3 A2 A1 Legal Letter"
  992.         }
  993.         a5 {
  994.             set paper(x1) "1.0c"
  995.             set paper(y1) "1.0c"
  996.             set paper(x2) "13.85c"
  997.             set paper(y2) "20.0c"
  998.             set paper(pheight) "19.0c"
  999.             set paper(pwidth) "12.85c"
  1000.             set paper(height) "21.0c"
  1001.             set paper(width) "14.85c"
  1002.             set paper(centerx) "7.425c"
  1003.             set paper(centery) "10.5c"
  1004.         }
  1005.         a4 {
  1006.             set paper(x1) "1.0c"
  1007.             set paper(y1) "1.0c"
  1008.             set paper(x2) "20.0c"
  1009.             set paper(y2) "28.7c"
  1010.             set paper(pheight) "27.7c"
  1011.             set paper(pwidth) "19.0c"
  1012.             set paper(height) "29.7c"
  1013.             set paper(width) "21.0c"
  1014.             set paper(centerx) "10.5c"
  1015.             set paper(centery) "14.85c"
  1016.         }
  1017.         a3 {
  1018.             set paper(x1) "1.0c"
  1019.             set paper(y1) "1.0c"
  1020.             set paper(x2) "28.7c"
  1021.             set paper(y2) "41.0c"
  1022.             set paper(pheight) "40.0c"
  1023.             set paper(pwidth) "27.7c"
  1024.             set paper(height) "42.0c"
  1025.             set paper(width) "29.7c"
  1026.             set paper(centerx) "14.85c"
  1027.             set paper(centery)  "21.0c"
  1028.         }
  1029.         a2 {
  1030.             set paper(x1) "1.0c"
  1031.             set paper(y1) "1.0c"
  1032.             set paper(x2) "41.0c"
  1033.             set paper(y2) "58.4c"
  1034.             set paper(pheight) "57.4c"
  1035.             set paper(pwidth) "40.0c"
  1036.             set paper(height) "59.4c"
  1037.             set paper(width) "42.0c"
  1038.             set paper(centerx) "21.0c"
  1039.             set paper(centery)  "29.7c"
  1040.         }
  1041.         a1 {
  1042.             set paper(x1) "1.0c"
  1043.             set paper(y1) "1.0c"
  1044.             set paper(x2) "58.4c"
  1045.             set paper(y2) "83.0c"
  1046.             set paper(pheight) "82.0c"
  1047.             set paper(pwidth) "57.4c"
  1048.             set paper(height) "84.0c"
  1049.             set paper(width) "59.4c"
  1050.             set paper(centerx) "29.7c"
  1051.             set paper(centery)  "42.0c"
  1052.         }
  1053.         legal {
  1054.             set paper(x1) "0.2i"
  1055.             set paper(y1) "0.2i"
  1056.             set paper(x2) "8.3i"
  1057.             set paper(y2) "13.8i"
  1058.             set paper(pheight) "13.6i"
  1059.             set paper(pwidth) "8.1i"
  1060.             set paper(height) "14.0i"
  1061.             set paper(width) "8.5i"
  1062.             set paper(centerx) "4.25i"
  1063.             set paper(centery) "7.0i"
  1064.         }
  1065.         letter {
  1066.             set paper(x1) "0.2i"
  1067.             set paper(y1) "0.2i"
  1068.             set paper(x2) "8.3i"
  1069.             set paper(y2) "10.8i"
  1070.             set paper(pheight) "10.6i"
  1071.             set paper(pwidth) "8.1i"
  1072.             set paper(height) "11.0i"
  1073.             set paper(width) "8.5i"
  1074.             set paper(centerx) "4.25i"
  1075.             set paper(centery) "5.5i"
  1076.         }
  1077.         default {
  1078.             error "ezPaperInfo: Unknown paper type ($type)"
  1079.         }
  1080.     }
  1081.     
  1082.     set inv(x1) "y1"
  1083.     set inv(x2) "y2"
  1084.     set inv(y1) "x1"
  1085.     set inv(y2) "x2"
  1086.     set inv(pwidth) "pheight"
  1087.     set inv(pheight) "pwidth"
  1088.     set inv(width) "height"
  1089.     set inv(height) "width"
  1090.     set inv(centerx) "centery"
  1091.     set inv(centery) "centerx"
  1092.     
  1093.     case $orient in {
  1094.         landscape {
  1095.             set res $paper($inv($attr))
  1096.         }
  1097.         portrait {
  1098.             set res $paper($attr)
  1099.         }
  1100.         default {
  1101.             error "ezPaperInfo: orientation should be\
  1102.                 portrait or landscape (not $orient)"
  1103.         }
  1104.     }
  1105.     
  1106.     if {$window != ""} {
  1107.         set res [winfo fpixels $window $res]
  1108.     }
  1109.     
  1110.     return $res
  1111. } 
  1112.