PC World Komputer 1996 May/PCW596.iso/polskie/eduk/genfast/demo_12.pak/OKNO_NEO.DA_

Text File | 1996-03-16 | 18.4 KB | 990 lines

; PRZYK£ADOWY EDYTOR GRAFICZNY - GenPaint

; Uwaga! To nie jest aplikacja skoñczona, a jedynie jej szkielet
; majåcy na celu wyÆåcznie pokazanie moºliwo₧ci pakietu GENFAST 2.0.
; Pewne funkcje så wyÆåczone lub okrojone z powodu mniejszych
; moºliwo₧ci wersji demonstracyjnej jæzyka EasyGEN (dotyczy to
; m.in. opcji zapisu i odczytu pliku graficznego)...

[procedure CZEKAJ]
[180]
@getmouseposition;
@if (%Z <> 0) then goto:180
@return;

[procedure OKNO_STAMP]
; w zmiennych a i b zdefiniowano staÆe ekranowe dla okna
@a:=200
@b:=150
@uparea(%a,%b,%a+300,%b+200,3)
@downarea(%a+10,%b+10,%a+290,%b+190,7)
;ikonki: np1->kasuj, np2->x, np3->lewo, np4->prawo, np5->dóÆ
;pierwsza
@uparea(%a+11,%b+11,%a+31,%b+31,7)
@setposition(%a+14,%b+15)
@picture('np1.rbm')
@setinvisiblebutton(%a+11,%b+11,%a+31,%b+31,999)
;druga
@uparea(%a+32,%b+11,%a+52,%b+31,7)
@setposition(%a+34,%b+13)
@picture('np2.rbm')
@setinvisiblebutton(%a+32,%b+11,%a+52,%b+31,999)
;trzecia
@uparea(%a+53,%b+11,%a+289,%b+31,3)
@setcolors(15,7)
@setposition(%a+61,%b+19)
@fastwrite('Okienko dialogowe')
@setcolors(0,7)
@setposition(%a+60,%b+18)
@fastwrite('Okienko dialogowe')
;obszar pierwszy
@downarea(%a+25,%b+50,%a+170,%b+160,7)
@clear(%a+30,%b+48,%a+90,%b+53)
@setposition(%a+35,%b+45)
@fastwrite('Rysunek')
@setcolors(15,7)
@bar(%a+30,%b+55,%a+165,%b+155)
@setcolors(0,7)
;przyciski
@drawbutton(%a+180,%b+50,%a+280,%b+80,7,998,'AKCEPTUJ','')
@drawbutton(%a+180,%b+90,%a+280,%b+120,7,999,'REZYGNUJ','')
;obszar drugi
@downarea(%a+180,%b+130,%a+280,%b+185,7)
@clear(%a+185,%b+128,%a+243,%b+133)
@setposition(%a+190,%b+125)
@fastwrite('Rodzaj')
;pull-down -> PCX<>RBM
@downarea(%a+190,%b+150,%a+249,%b+170,9)
@setposition(%a+210,%b+156)
@fastwrite('PCX')
@uparea(%a+250,%b+150,%a+270,%b+170,7)
@setposition(%a+254,%b+152)
@picture('np5.rbm')
; tæ proceduræ trzeba bædzie zdefiniowaì - na razie nie aktywna!
@setinvisiblebutton(%a+250,%b+150,%a+270,%b+170,995)
;suwak
@downarea(%a+25,%b+165,%a+170,%b+185,8)
;
@uparea(%a+26,%b+166,%a+46,%b+184,7)
@setposition(%a+28,%b+169)
@picture('np3.rbm')
@setinvisiblebutton(%a+26,%b+166,%a+46,%b+184,153)
@uparea(%a+149,%b+166,%a+169,%b+184,7)
@setposition(%a+152,%b+169)
@picture('np4.rbm')
@setinvisiblebutton(%a+149,%b+166,%a+169,%b+184,154)
@Gosub:156
@Gosub:154
@Return;

[procedure KOLORY]
@DownArea(4,170,66,370,8)
@PushVariables;
@A:=0
@B:=0
@Repeat:8
@SetColors(%A,15)
@Bar(6,172+%B,35,192+%B)
@SetInvisibleButton(6,172+%B,35,192+%B,400+%A)
@A:=%A+1
@B:=%B+20
@Next;
@A:=8
@B:=0
@Repeat:8
@SetColors(%A,15)
@Bar(36,172+%B,64,192+%B)
@SetInvisibleButton(36,172+%B,64,192+%B,400+%A)
@A:=%A+1
@B:=%B+20
@Next;
@PopVariables;
@Gosub:420
@GoSub:430
@Return

[procedure LINIE]
@DownArea(4,70,66,167,8)
@setposition(16,76)
@setcolors(0,7)
@fastwrite('LINIA')
@setcolors(15,7)
@setposition(15,75)
@fastwrite('LINIA')
@setcolors(15,7)
@bar(10,90,60,100)
@setcolors(0,7)
@line(15,95,55,95)
@setinvisiblebutton(10,90,60,100,550)
@setcolors(15,7)
@bar(10,110,60,120)
@setcolors(0,7)
@bar(15,114,55,116)
@setinvisiblebutton(10,110,60,120,551)
@setcolors(15,7)
@bar(10,130,60,140)
@setcolors(0,7)
@bar(15,133,55,137)
@setinvisiblebutton(10,130,60,140,552)
@setcolors(15,7)
@bar(10,150,60,160)
@setcolors(0,7)
@bar(15,152,55,158)
@setinvisiblebutton(10,150,60,160,553)
@return

[procedure  PRZYCISKI]
;DEKLARACJE KLAWISZY RYSOWANIA
@setcolors(7,15)
@DrawButton(4,4,65,25,7,900,'OPCJE','Opcje programu')
@drawbutton(66,4,126,25,7,910,'FONTY','Rodzaj fontu')
@DrawButton(127,4,191,25,7,920,'POMOC','Jak korzystaì?')
@DrawButton(4,27,44,68,7,300,'rysuj.rbm','Linie ciagÆe')
@DrawButton(45,27,85,68,7,310,'rysuj2.rbm','Prostokty')
@DrawButton(86,27,126,68,7,320,'rysuj3.rbm','Owale')
@DrawButton(127,27,167,68,7,330,'pen.rbm','Flamaster')
@DrawButton(168,27,208,68,7,340,'fill.rbm','WypeÆnienie')
@DrawButton(209,27,249,68,7,350,'rysuj6.rbm','Gumka selektywna')
@DrawButton(250,27,290,68,7,360,'rysuj7.rbm','Cofnij')
@DrawButton(291,27,331,68,7,370,'rysuj8.rbm','Czy₧ì ekran')
@DrawButton(332,27,372,68,7,380,'stamp.rbm','Pieczåtki')
@DrawButton(373,27,415,68,7,390,'rysuj9.rbm','Linie wspólne')
@DrawButton(416,27,458,68,7,700,'fonty.rbm','Teksty')
@DrawButton(459,27,501,68,7,720,'rysuj10.rbm','Kropki')
@DrawButton(502,27,547,68,7,710,'rysuj22.rbm','Prostokåty wypeÆnione')
@DrawButton(548,27,591,68,7,730,'nozyczki.rbm','Przesuwanie fragmentów')
@DrawButton(592,27,635,68,7,740,'rysuj31.rbm','Owal wypeÆniony')
@return

[procedure STAMP]
@DownArea(4,373,66,460,8)
@setcolors(0,7)
@setposition(16,380)
@fastwrite('IKONA')
@setcolors(15,7)
@setposition(15,379)
@fastwrite('IKONA')
@Bar(8,392,62,455)
@setposition(11,400)
@picture('footblst.pcx')
@setinvisiblebutton(8,392,62,455,800)
@return

[1]
; Program GENPAINT wersja 1.0 beta
; Aplikacja przykÆadowa wykonana caÆkowicie w GENFAÿCIE 2.0
; Kodowanie #PWR, marzec 1996
@defkeyboardhandler(703)
@A:=150;
@B:=150;
@C:=1
@E:=1;
@G:=%X
@H:=%Y
@I:=%G
@J:=%H
; kolor czarny
@K:=0
@L:=15
@DisableStatusBar;
@SetColors(3,8)
@Bar(0,0,639,479)
@DownArea(70,70,635,475,15)
;napis w górnym prawym rogu
@SetColors(15,7)
@SetPosition(446,13)
@FastWrite('POZYCJA KURSORA:')
@SetColors(0,7)
@SetPosition(445,12)
@FastWrite('POZYCJA KURSORA:')
; napis w dolnym lewym rogu
@DownArea(573,8,637,22,15)
@Uparea(4,462,66,475,0)
@setcolors(15,7)
@setposition(8,465)
@fastwrite('GENFAST')
;@setcolors(15,7)
@setposition(252,8)
@picture('paint.cgv')
@setcolors(0,7)
@setposition(250,6)
@picture('paint.cgv')
@call:przyciski
@call:Linie
@Call:Stamp
@Call:Kolory
@DefIdleProc(2)
@showscreen;
@CheckEvents;

[2]
@GetMousePosition;
@If (%G <> %X) then begin
@G:=%X
@if (%G > 70) then gosub:100
@if (%G < 70) then gosub:101
@end
@if (%h <> %Y) then begin
@H:=%Y
@if (%H > 70) then gosub:100
@if (%h < 70) then gosub:101
@end;
@CheckEvents;

[100]
@Clear(575,10,635,20)
@Setcolors(0,7)
@WriteString(575,10,635,20,'[%X-70:0]:[%Y-70:0]')
@Return;
[101]
@Clear(575,10,635,20)
@Return;

[153]
@C:=%C-1
@if (%C < 1) then begin
@C:=1
@end
@Goto:155
[154]
@C:=%C+1
@if (%C > 9) then begin
@C:=9
@end
[155]
; wy₧wietlanie 'stampów'
@setcolors(15,7)
@bar(%a+30,%b+55,%a+165,%b+155)
@setposition(%a+70,%b+80)
@if (%C = 1) then begin
@picture('footblst.pcx')
@gosub:156
@end
@if (%C = 2) then begin
@picture('reka.pcx')
@gosub:156
@end
@if (%C = 3) then begin
@picture('oko2.pcx')
@gosub:156
@end
@if (%C = 4) then begin
@picture('nos.pcx')
@gosub:156
@end
@if (%C = 5) then begin
@picture('noga.pcx')
@gosub:156
@end
@if (%C = 6) then begin
@picture('lisc.pcx')
@gosub:156
@end
@if (%C = 7) then begin
@picture('klaun.pcx')
@gosub:156
@end
@if (%C = 8) then begin
@picture('hat.pcx')
@gosub:156
@end
@if (%C = 9) then begin
@picture('eye1.pcx')
@gosub:156
@end
@checkevents;
[156]
@setcolors(8,7)
@bar(%a+47,%b+166,%a+148,%b+184)
@uparea(%a+37+%C*10,%b+166,%a+57+%C*10,%b+184,7)
@return

[300]
; rysowanie linii ciågÆych
@SaveScreen;
[301]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,302)
@CheckEvents;
[302]
@SetColors(%K,7);
@if (%I = 0) then goto:303
@gosub:500+%E
[303]
@I := %X;
@J := %Y;
@GoTo:301
[501]
@Line(%I,%J,%X,%Y);
@return
[503]
@Line(%I,%J-1,%X,%Y-1);
@Line(%I,%J,%X,%Y);
@Line(%I,%J+1,%X,%Y+1);
@return
[505]
@Line(%I,%J-2,%X,%Y-2);
@Line(%I,%J-1,%X,%Y-1);
@Line(%I,%J,%X,%Y);
@Line(%I,%J+1,%X,%Y+1);
@Line(%I,%J+2,%X,%Y+2);
@return
[507]
@Line(%I,%J-3,%X,%Y-3);
@Line(%I,%J-2,%X,%Y-2);
@Line(%I,%J-1,%X,%Y-1);
@Line(%I,%J,%X,%Y);
@Line(%I,%J+1,%X,%Y+1);
@Line(%I,%J+2,%X,%Y+2);
@Line(%I,%J+3,%X,%Y+3);
@return

[310]
; prostokåty
@SaveScreen;
[311]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,312)
@CheckEvents;
[312]
@SetColors(%K,7);
@if (%I = 0) then goto:313
@Rectangle(%I,%J,%X,%Y);
[313]
@I := %X;
@J := %Y;
@GoTo:311

[320]
; okrægi i elipsy
@SaveScreen;
[321]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,322)
@CheckEvents;
[322]
@SetColors(%K,%K);
@if (%I = 0) then goto:323
@if (%Y > %J) then begin
@if (%X > %I) then begin
@Ellipse(%I+ABS(%X-%I)/2,%J+ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:323
@else
@Ellipse(%I-ABS(%X-%I)/2,%J+ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:323
@end
@end
@if (%Y < %J) then begin
@if (%X > %I) then begin
@Ellipse(%I+ABS(%X-%I)/2,%J-ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:323
@else
@Ellipse(%I-ABS(%X-%I)/2,%J-ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:323
@end
@end
[323]
@I := %X;
@J := %Y;
@GoTo:321

[330]
; flamaster
@SaveScreen;
[331]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,332)
@CheckEvents;
[332]
@I:=%X
@J:=%Y
@SetColors(%K,7);
@Bar(%I-%E,%J-%E,%I+%E,%J+%E);
@GoTo:331

[340]
;wypeÆnianie obszaru
@savescreen
[341]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,342)
@CheckEvents;
[342]
@I:=%X
@J:=%Y
@FillArea(%I,%J,%K);
@setcolors(0,7)
@rectangle(70,70,635,475)
@GoTo:341

[350]
; gumka selektywna
@SaveScreen;
[351]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,352)
@CheckEvents;
[352]
@I:=%X
@J:=%Y
@SetColors(%K,%L);
@reversearea(%I-%E-2,%J-%E-2,%I+%E+2,%J+%E+2);
@GoTo:351

[360]
;@LoadPart(71,71,'ekran.scr')
@LoadScreen;
@CheckEvents;

[370]
;czyszczenie ekranu w wybranym kolorze
@savescreen
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@setcolors(%K,7)
@L:=%K
@bar(72,72,633,473)
@checkevents;

[380]
; pieczåtki
@SaveScreen;
[381]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,382)
@CheckEvents;
[382]
@I := %X;
@J := %Y;
@if (%X < 95) Then goto:381
@if (%X > 605) Then goto:381
@if (%Y < 95) Then goto:381
@if (%Y > 450) Then goto:381
@setposition(%I-20,%J-24)
@if (%C = 1) then begin
@picture('footblst.pcx')
@end
@if (%C = 2) then begin
@picture('reka.pcx')
@end
@if (%C = 3) then begin
@picture('oko2.pcx')
@end
@if (%C = 4) then begin
@picture('nos.pcx')
@end
@if (%C = 5) then begin
@picture('noga.pcx')
@end
@if (%C = 6) then begin
@picture('lisc.pcx')
@end
@if (%C = 7) then begin
@picture('klaun.pcx')
@end
@if (%C = 8) then begin
@picture('hat.pcx')
@end
@if (%C = 9) then begin
@picture('eye1.pcx')
@end
@goto:381

[390]
; linie wspólne ( jeden punkt poczåtkowy )
@SaveScreen;
[391]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,392)
@CheckEvents;
[392]
@SetColors(%K,7);
@if (%I = 0) then goto:393
@line(%I,%J,%X,%Y)
[393]
@GoTo:391

[400..415]
; procedury 400-415 to wybieranie kolorów
; Zmienna K okre₧la kolor
@GetCurrentPage(%K);
@K:=%K-400;
@sound(440,50)
@GoSub:420
@call:czekaj;
@CheckEvents;

[420]
@setcolors(0,7)
@setposition(16,341)
@fastwrite('KOLOR')
@setcolors(15,7)
@setposition(15,340)
@fastwrite('KOLOR')
@SetColors(%K,7)
@Bar(8,355,62,365)
@setcolors(0,7)
@rectangle(7,354,63,366)
@Return

[430]
; button na "rybke" zaraz bedzie skasowany!!!
@SetInvisibleButton(0,0,10,10,431)
@return

[550]
@E:=1
@sound(440,50)
@checkevents;
[551]
@E:=3
@sound(440,50)
@checkevents;
[552]
@E:=5
@sound(440,50)
@checkevents;
[553]
@E:=7
@sound(440,50)
@checkevents;

[700]
; pisanie tekstu na ekranie
@SaveScreen;
[701]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,702)
@CheckEvents;
[702]
@getparam;
@I:=%X
@J:=%Y
@goto:701
[703]
; nacisniæcie ENTER
@if (%Z = $1C0D) then goto:704;
; naci₧niæcie Backspace
@if (%Z = $0E08) then goto:705;
@SetColors(%K,7);
@setposition(%I,%J)
<#%z>
@GetParam;
@I:=%I+8
@checkevents
[704]
@checkevents
[705]
@I:=%I-8
@setcolors(%K,%L)
@reversearea(%I,%J,%I+8,%J+16)
@checkevents

[710]
; prostokåty wypeÆnione
@SaveScreen;
[711]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,712)
@CheckEvents;
[712]
@SetColors(%K,7);
@if (%I = 0) then goto:713
@Bar(%I,%J,%X,%Y);
[713]
@I := %X;
@J := %Y;
@GoTo:711

[720]
; kropki
@SaveScreen;
[721]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,722)
@CheckEvents;
[722]
@I:=%G
@J:=%H
@if (%I = 0) then goto:723
@putpixel(%I,%J,%K)
[723]
@I := %X;
@J := %Y;
@GoTo:721

[730]
; noºyczki
@SaveScreen;
[731]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,732)
@CheckEvents;
[732]
@I := %X;
@J := %Y;
@DeleteButton;
@SetInvisibleButton(71,71,634,474,733)
@sound(200,100)
@CheckEvents;
[733]
@if (%X-%I < 1) then begin
@sound(440,500)
@goto:731
@else
@GetPart(%I,%J,%X,%Y);
@sound(200,100)
@sound(200,100)
@end
[734]
@setcolors(14,0)
@rectangle(%I,%J,%X,%Y)
@Deletebutton
@SetInvisibleButton(71,71,634,474,735)
@CheckEvents;
[735]
@putpart(%X,%Y)
@repeat:3
@sound(200,100)
@next
@goto:731

[740]
; okrægi i elipsy wypeÆnione
@SaveScreen;
[741]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@SetInvisibleButton(71,71,634,474,742)
@CheckEvents;
[742]
@SetColors(%K,%K);
@if (%I = 0) then goto:743
@if (%Y > %J) then begin
@if (%X > %I) then begin
@FillEllipse(%I+ABS(%X-%I)/2,%J+ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:743
@else
@FillEllipse(%I-ABS(%X-%I)/2,%J+ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:743
@end
@end
@if (%Y < %J) then begin
@if (%X > %I) then begin
@FillEllipse(%I+ABS(%X-%I)/2,%J-ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:743
@else
@FillEllipse(%I-ABS(%X-%I)/2,%J-ABS(%Y-%J)/2,ABS(%X-%I)/2,ABS(%Y-%J)/2);
@goto:743
@end
@end
[743]
@I := %X;
@J := %Y;
@GoTo:741

[800]
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@savescreen;
@call:okno_stamp
@checkevents;

[900]
; menu opcje
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@savescreen;
@pushvariables
@a:=4
@b:=26
@setcolors(0,7)
@rectangle(%a,%b,%a+116,%b+84)
@uparea(%a+1,%b+1,%A+115,%B+83,7)
@setposition(15,42)
@FastWrite('Odczytaj...')
@setinvisiblebutton(10,37,114,52,901)
@setposition(15,62)
@FastWrite('Zapisz...')
@setinvisiblebutton(10,57,114,72,902)
@line(10,77,114,77)
@setposition(15,87)
@FastWrite('Zakoñczenie')
@setinvisiblebutton(10,83,114,97,903)
@popvariables
@checkevents
[901]
@downarea(10,37,114,52,4)
@setcolors(14,0)
@setposition(15,42)
@FastWrite('Odczytaj...')
@openuserfile('Odczytaj rysunek','*.rys')
@loadscreen
@if (%Z <> 300) then begin
@loadpart(71,71,'ekran_a.rys')
@loadpart(352,71,'ekran_b.rys')
@end
@repeat:3
@deletebutton
@next
@checkevents
[902]
@setcolors(14,7)
@downarea(10,57,114,72,4)
@setposition(15,62)
@FastWrite('Zapisz...')
@createuserfile('Zapisz rysunek','*.rys')
@loadscreen
@if (%Z <> 300) then begin
@savepart(71,71,351,474,'ekran_a.rys')
@savepart(352,71,643,474,'ekran_b.rys')
@end
@repeat:3
@deletebutton
@next
@checkevents
[903]
@setcolors(14,7)
@downarea(10,83,114,97,4)
@setposition(15,87)
@FastWrite('Zakoñczenie')
@messagebox('ZAKOÑCZENIE','Koniec programu')
@goto:0

[910]
; menu fonty
@pushvariables;
@getparam;
@if (%F > 39) then begin
@deletebutton
@end
@popvariables;
@savescreen;
@pushvariables
@a:=66
@b:=26
@setcolors(0,7)
@rectangle(%a,%b,%a+116,%b+136)
@uparea(%a+1,%b+1,%A+115,%B+135,7)
@setposition(%a+11,42)
@FastWrite('ANTIQUE')
@setinvisiblebutton(%a+6,37,%a+110,52,911)
@setposition(%a+11,62)
@FastWrite('BOLD')
@setinvisiblebutton(%a+6,57,%a+110,72,912)
@setposition(%a+11,82)
@FastWrite('BROADWAY')
@setinvisiblebutton(%a+6,77,%a+110,92,913)
@setposition(%a+11,102)
@FastWrite('COMPUTER')
@setinvisiblebutton(%a+6,97,%a+110,112,914)
@setposition(%a+11,122)
@FastWrite('FUTURE')
@setinvisiblebutton(%a+6,117,%a+110,132,915)
@setposition(%a+11,142)
@FastWrite('SYSTEM')
@setinvisiblebutton(%a+6,137,%a+110,152,916)
@checkevents
[911]
@downarea(%a+6,37,%a+110,52,4)
@setcolors(14,0)
@setposition(%a+11,42)
@FastWrite('ANTIQUE')
@LOADFONT('ANTIQUE.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents
[912]
@setcolors(14,7)
@downarea(%a+6,57,%a+110,72,4)
@setposition(%a+11,62)
@FastWrite('BOLD')
@LOADFONT('BOLD.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents
[913]
@setcolors(14,7)
@downarea(%a+6,77,%a+110,92,4)
@setposition(%a+11,82)
@FastWrite('BROADWAY')
@LOADFONT('BROADWAY.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents
[914]
@downarea(%a+6,97,%a+110,112,4)
@setcolors(14,0)
@setposition(%a+11,102)
@FastWrite('COMPUTER')
@LOADFONT('COMPUTER.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents
[915]
@setcolors(14,7)
@downarea(%a+6,117,%a+110,132,4)
@setposition(%a+11,122)
@FastWrite('FUTURE')
@LOADFONT('FUTURE.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents
[916]
@setcolors(14,7)
@downarea(%a+6,137,%a+110,152,4)
@setposition(%a+11,142)
@FastWrite('SYSTEM')
@LOADFONT('SYSTEM.RSF')
@popvariables
@repeat:6
@deletebutton
@next
@loadscreen
@checkevents

[920]
; help trzeba zrobiì!
@Goto:995
;@ShowHelp('')
@CheckEvents

[995]
@messagebox('NIESTETY!','Opcja nie zrealizowana!')
@CheckEvents;

[998]
@repeat:7
@deletebutton;
@next
@loadscreen
@setcolors(15,7)
@Bar(8,392,62,455)
@setposition(11,400)
@if (%C = 1) then begin
@picture('footblst.pcx')
@end
@if (%C = 2) then begin
@picture('reka.pcx')
@end
@if (%C = 3) then begin
@picture('oko2.pcx')
@end
@if (%C = 4) then begin
@picture('nos.pcx')
@end
@if (%C = 5) then begin
@picture('noga.pcx')
@end
@if (%C = 6) then begin
@picture('lisc.pcx')
@end
@if (%C = 7) then begin
@picture('klaun.pcx')
@end
@if (%C = 8) then begin
@picture('hat.pcx')
@end
@if (%C = 9) then begin
@picture('eye1.pcx')
@end
;@popvariables
@checkevents

[999]
@repeat:7
@deletebutton;
@next
@loadscreen
@checkevents