home *** CD-ROM | disk | FTP | other *** search
/ PC World Komputer 1998 November (B) / pcwk_11_98B.iso / Lotus / EXTRA / CONVERT / WP96TO97.BAT < prev   
Encoding:
DOS Batch File  |  1996-12-31  |  1.4 KB  |  46 lines
  1. @ECHO OFF
  2. REM This is an example of how to use a batch file to easily
  3. REM convert many Word Pro files from WP96 to WP97 format.
  4. REM This batch file takes one parameter, a directory, and
  5. REM converts all the Word Pro files (*.MWP, *.LWP) in that
  6. REM directory.  It will overwrite the existing files, so you
  7. REM may want to backup those files first.
  8. REM 
  9. REM One could change the Word Pro options in the FOR statements
  10. REM below to resave in WP96 format, or to specify a different
  11. REM directory and file to save to, instead of overwriting the 
  12. REM existing file.  See the file convert.txt for details.
  13.  
  14. IF "%1"=="" GOTO USAGE
  15. IF NOT EXIST %1\*.* GOTO BADDIR
  16.  
  17. ECHO This batch file will convert all the Word Pro files in %1
  18. ECHO from WP96 to WP97 format and overwrite the existing files.
  19. ECHO You may want to backup those files before continuing.
  20. ECHO.
  21. CHOICE Continue
  22. IF ERRORLEVEL 2 GOTO END
  23.  
  24. IF NOT EXIST %1\*.LWP GOTO NOLWP
  25. FOR %%F IN (%1\*.LWP) DO START /W WORDPRO /F %%F /KO %%F
  26. :NOLWP
  27.  
  28. IF NOT EXIST %1\*.MWP GOTO NOMWP
  29. FOR %%F IN (%1\*.MWP) DO START /W WORDPRO /F %%F /KO %%F
  30. :NOMWP
  31. GOTO END
  32.  
  33. :USAGE
  34. ECHO Usage: wp96to97 dirname
  35. ECHO Converts all files in dirname to WP97 format and overwrites
  36. ECHO the existing files with the new ones.
  37. ECHO.
  38. GOTO END
  39.  
  40. :BADDIR
  41. ECHO Invalid path, not a directory, or directory empty
  42. ECHO.
  43. GOTO END
  44.  
  45. :END
  46.