home *** CD-ROM | disk | FTP | other *** search
/ Chip: Windows 2000 Professional Resource Kit / W2KPRK.iso / apps / perl / ActivePerl.exe / data.z / Compare.pm < prev    next >
Encoding:
Perl POD Document  |  1999-10-14  |  4.4 KB  |  181 lines
  1. package File::Compare;
  2.  
  3. use strict;
  4. use vars qw($VERSION @ISA @EXPORT @EXPORT_OK $Too_Big *FROM *TO);
  5.  
  6. require Exporter;
  7. use Carp;
  8.  
  9. $VERSION = '1.1002';
  10. @ISA = qw(Exporter);
  11. @EXPORT = qw(compare);
  12. @EXPORT_OK = qw(cmp compare_text);
  13.  
  14. $Too_Big = 1024 * 1024 * 2;
  15.  
  16. sub VERSION {
  17.     # Version of File::Compare
  18.     return $File::Compare::VERSION;
  19. }
  20.  
  21. sub compare {
  22.     croak("Usage: compare( file1, file2 [, buffersize]) ")
  23.       unless(@_ == 2 || @_ == 3);
  24.  
  25.     my ($from,$to,$size) = @_;
  26.     my $text_mode = defined($size) && (ref($size) eq 'CODE' || $size < 0);
  27.  
  28.     my ($fromsize,$closefrom,$closeto);
  29.     local (*FROM, *TO);
  30.  
  31.     croak("from undefined") unless (defined $from);
  32.     croak("to undefined") unless (defined $to);
  33.  
  34.     if (ref($from) && 
  35.         (UNIVERSAL::isa($from,'GLOB') || UNIVERSAL::isa($from,'IO::Handle'))) {
  36.     *FROM = *$from;
  37.     } elsif (ref(\$from) eq 'GLOB') {
  38.     *FROM = $from;
  39.     } else {
  40.     open(FROM,"<$from") or goto fail_open1;
  41.     unless ($text_mode) {
  42.         binmode FROM;
  43.         $fromsize = -s FROM;
  44.     }
  45.     $closefrom = 1;
  46.     }
  47.  
  48.     if (ref($to) &&
  49.         (UNIVERSAL::isa($to,'GLOB') || UNIVERSAL::isa($to,'IO::Handle'))) {
  50.     *TO = *$to;
  51.     } elsif (ref(\$to) eq 'GLOB') {
  52.     *TO = $to;
  53.     } else {
  54.     open(TO,"<$to") or goto fail_open2;
  55.     binmode TO unless $text_mode;
  56.     $closeto = 1;
  57.     }
  58.  
  59.     if (!$text_mode && $closefrom && $closeto) {
  60.     # If both are opened files we know they differ if their size differ
  61.     goto fail_inner if $fromsize != -s TO;
  62.     }
  63.  
  64.     if ($text_mode) {
  65.     local $/ = "\n";
  66.     my ($fline,$tline);
  67.     while (defined($fline = <FROM>)) {
  68.         goto fail_inner unless defined($tline = <TO>);
  69.         if (ref $size) {
  70.         # $size contains ref to comparison function
  71.         goto fail_inner if &$size($fline, $tline);
  72.         } else {
  73.         goto fail_inner if $fline ne $tline;
  74.         }
  75.     }
  76.     goto fail_inner if defined($tline = <TO>);
  77.     }
  78.     else {
  79.     unless (defined($size) && $size > 0) {
  80.         $size = $fromsize;
  81.         $size = 1024 if $size < 512;
  82.         $size = $Too_Big if $size > $Too_Big;
  83.     }
  84.  
  85.     my ($fr,$tr,$fbuf,$tbuf);
  86.     $fbuf = $tbuf = '';
  87.     while(defined($fr = read(FROM,$fbuf,$size)) && $fr > 0) {
  88.         unless (defined($tr = read(TO,$tbuf,$fr)) && $tbuf eq $fbuf) {
  89.         goto fail_inner;
  90.         }
  91.     }
  92.     goto fail_inner if defined($tr = read(TO,$tbuf,$size)) && $tr > 0;
  93.     }
  94.  
  95.     close(TO) || goto fail_open2 if $closeto;
  96.     close(FROM) || goto fail_open1 if $closefrom;
  97.  
  98.     return 0;
  99.     
  100.   # All of these contortions try to preserve error messages...
  101.   fail_inner:
  102.     close(TO) || goto fail_open2 if $closeto;
  103.     close(FROM) || goto fail_open1 if $closefrom;
  104.  
  105.     return 1;
  106.  
  107.   fail_open2:
  108.     if ($closefrom) {
  109.     my $status = $!;
  110.     $! = 0;
  111.     close FROM;
  112.     $! = $status unless $!;
  113.     }
  114.   fail_open1:
  115.     return -1;
  116. }
  117.  
  118. *cmp = \&compare;
  119.  
  120. sub compare_text {
  121.     my ($from,$to,$cmp) = @_;
  122.     croak("Usage: compare_text( file1, file2 [, cmp-function])")
  123.     unless @_ == 2 || @_ == 3;
  124.     croak("Third arg to compare_text() function must be a code reference")
  125.     if @_ == 3 && ref($cmp) ne 'CODE';
  126.  
  127.     # Using a negative buffer size puts compare into text_mode too
  128.     $cmp = -1 unless defined $cmp;
  129.     compare($from, $to, $cmp);
  130. }
  131.  
  132. 1;
  133.  
  134. __END__
  135.  
  136. =head1 NAME
  137.  
  138. File::Compare - Compare files or filehandles
  139.  
  140. =head1 SYNOPSIS
  141.  
  142.       use File::Compare;
  143.  
  144.     if (compare("file1","file2") == 0) {
  145.         print "They're equal\n";
  146.     }
  147.  
  148. =head1 DESCRIPTION
  149.  
  150. The File::Compare::compare function compares the contents of two
  151. sources, each of which can be a file or a file handle.  It is exported
  152. from File::Compare by default.
  153.  
  154. File::Compare::cmp is a synonym for File::Compare::compare.  It is
  155. exported from File::Compare only by request.
  156.  
  157. File::Compare::compare_text does a line by line comparison of the two
  158. files. It stops as soon as a difference is detected. compare_text()
  159. accepts an optional third argument: This must be a CODE reference to
  160. a line comparison function, which returns 0 when both lines are considered
  161. equal. For example:
  162.  
  163.     compare_text($file1, $file2)
  164.  
  165. is basically equivalent to
  166.  
  167.     compare_text($file1, $file2, sub {$_[0] ne $_[1]} )
  168.  
  169. =head1 RETURN
  170.  
  171. File::Compare::compare return 0 if the files are equal, 1 if the
  172. files are unequal, or -1 if an error was encountered.
  173.  
  174. =head1 AUTHOR
  175.  
  176. File::Compare was written by Nick Ing-Simmons.
  177. Its original documentation was written by Chip Salzenberg.
  178.  
  179. =cut
  180.  
  181.