home *** CD-ROM | disk | FTP | other *** search
/ Chip 2007 January, February, March & April / Chip-Cover-CD-2007-02.iso / boot / i386 / rescue / etc / profile.d / profile.csh < prev    next >
Encoding:
Text File  |  2006-11-29  |  3.0 KB  |  133 lines
  1. #
  2. # profile.csh:         Set interactive profile environment
  3. #
  4. # Used configuration files:
  5. #
  6. #     /etc/sysconfig/windowmanager
  7. #     /etc/sysconfig/suseconfig
  8. #     /etc/sysconfig/mail
  9. #     /etc/sysconfig/proxy
  10. #     /etc/sysconfig/console
  11. #     /etc/sysconfig/news
  12. #
  13.  
  14. set noglob
  15. set sysconf=""
  16. foreach sys (/etc/sysconfig/windowmanager    \
  17.          /etc/sysconfig/suseconfig        \
  18.          /etc/sysconfig/mail        \
  19.          /etc/sysconfig/proxy        \
  20.          /etc/sysconfig/console        \
  21.          /etc/sysconfig/news)
  22.     if (! -s ${sys:q} ) continue
  23.     set sysconf="${sysconf} ${sys}"
  24. end
  25. unset sys
  26.  
  27. set val=""
  28. foreach line ( "`grep -vh '^#' $sysconf`" )
  29.     set val="${line:q:s/=/ /}"
  30.     set arr=( $val )
  31.     eval set val="${arr[2-]}"
  32.     switch (${line:q})
  33.     case CWD_IN_ROOT_PATH=*:
  34.     if ( ${line:q} !~ *=*yes* ) continue
  35.     if ( "$path[*]" =~ *.* )    continue
  36.     if ( $uid <  100 ) set -l path=( $path . )
  37.     breaksw
  38.     case CWD_IN_USER_PATH=*:
  39.     if ( ${line:q} !~ *=*yes* ) continue
  40.     if ( "$path[*]" =~ *.* )    continue
  41.     if ( $uid >= 100 ) set -l path=( $path . )
  42.     breaksw
  43.     case FROM_HEADER=*:
  44.     setenv FROM_HEADER ${val:q}
  45.     breaksw
  46.     case SCANNER_TYPE=*:
  47.     setenv SCANNER_TYPE ${val:q}
  48.     breaksw
  49.     case PROXY_ENABLED=*:
  50.     set proxy_enabled=${val:q}
  51.     breaksw
  52.     case HTTP_PROXY=*:
  53.     if (! ${%val} ) continue
  54.     setenv http_proxy ${val:q}
  55.     breaksw
  56.     case HTTPS_PROXY=*:
  57.     if (! ${%val} ) continue
  58.     setenv https_proxy ${val:q}
  59.     breaksw
  60.     case FTP_PROXY=*:
  61.     if (! ${%val} ) continue
  62.     setenv ftp_proxy ${val:q}
  63.     breaksw
  64.     case GOPHER_PROXY=*:
  65.     if (! ${%val} ) continue
  66.     setenv gopher_proxy ${val:q}
  67.     breaksw
  68.     case NO_PROXY=*:
  69.     if (! ${%val} ) continue
  70.     setenv no_proxy ${val:q}
  71.     breaksw
  72.     case DEFAULT_WM=*:
  73.     set default_wm=${val:q}
  74.     breaksw
  75.     case CONSOLE_MAGIC=*:
  76.     set console_magic=${val:q}
  77.     breaksw
  78.     case ORGANIZATION=*:
  79.     if (! ${%val} ) continue
  80.     setenv ORGANIZATION ${val:q}
  81.     breaksw
  82.     case NNTPSERVER=*:
  83.     setenv NNTPSERVER ${val:q}
  84.     if ( ! ${?NNTPSERVER} ) setenv NNTPSERVER news
  85.     breaksw
  86.     default:
  87.     breaksw
  88.     endsw
  89. end
  90. unset sysconf line
  91.  
  92. if ( -d /usr/lib/dvgt_help ) then
  93.     setenv DV_IMMED_HELP /usr/lib/dvgt_help
  94. endif
  95.  
  96. if ( -d /usr/lib/rasmol ) then
  97.     setenv RASMOLPATH /usr/lib/rasmol
  98. endif
  99.  
  100. if ( ${?proxy_enabled} ) then
  101.     if ( "$proxy_enabled" != "yes" ) then
  102.     unsetenv http_proxy https_proxy ftp_proxy gopher_proxy no_proxy
  103.     endif
  104.     unset proxy_enabled
  105. endif
  106.  
  107. #
  108. # Do not use the `which' builtin nor set path to avoid a rehash
  109. #
  110. if (! ${?default_wm} ) set default_wm
  111. if ( ${%default_wm} > 0 && ! ${?WINDOWMANAGER} ) then
  112.     set default_wm=${default_wm:t}
  113.     foreach val ($path /usr/X11R6/bin /opt/gnome/bin /usr/openwin/bin)
  114.     if ( ${val:q} =~ *.* ) continue
  115.     set val=${val:q}/${default_wm:q}
  116.     if ( ! -x ${val:q} ) continue
  117.     setenv WINDOWMANAGER ${val:q}
  118.     break
  119.     end
  120.     unset val
  121. endif
  122. unset default_wm
  123.  
  124. if ( ${?loginsh} && ${?console_magic} && "$tty" =~ tty* ) then
  125.     if ( "$TERM" == "linux" && -o /dev/$tty ) then
  126.     echo -n "\033$console_magic"
  127.     endif
  128. endif
  129.  
  130. unset noglob
  131. #
  132. # end of profile.csh
  133.