home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Chip 1998 March
/
CHIPCD_3_98.iso
/
software
/
testsoft
/
exchange
/
webdata
/
usa
/
finduser
/
fumsg.asp
< prev
next >
Wrap
Text File
|
1997-08-25
|
4KB
|
138 lines
<!--#include file="../constant.inc" -->
<!--#include file="../lib/session.inc" -->
<!--#include file="../lib/getrend.inc" -->
<!--#include file="../lib/jsutil.inc"-->
<%
'<!--Microsoft Outlook Web Access-->
'<!--Find User fumsg.asp : Frame that lists results from find names search. -->
'<!--Copyright (c) Microsoft Corporation 1993-1997. All rights reserved.-->
On Error Resume Next
CheckSession2 bstrVirtRoot + "/finduser/root.asp"
set objRenderApp = Application( bstrRenderApp )
%>
<!DOCTYPE HTML PUBLIC "-//IETF//DTD HTML 3.2//EN">
<HTML>
<HEAD>
</HEAD>
<BODY TEXT=000000 BGCOLOR=ffffff LINK=000000 VLINK=FF0000 ALINK=000000 TOPMARGIN="0">
<BASEFONT <%=bstrFace%> SIZE=2 COLOR=000000>
<%
On Error Resume Next
nPubLimit = objRenderApp.ConfigParameter("Publish GAL Limit")
' No limit enforced by DSA
If CStr(nPubLimit) = "" Then
nPubLimit = 9999
End If
If nPubLimit > 0 Then
strDisplayName = Request.Form("DN")
strFirstName = Request.Form("FN")
strLastName = Request.Form("LN")
strTitle = Request.Form("TL")
strAlias = Request.Form("AN")
strCompany = Request.Form("CP")
strDepartment = Request.Form("DP")
strOffice = Request.Form("OF")
strCity = Request.Form("CY")
Set Hierarchy = objOMSession.AddressLists
' make sure collection is valid
If Hierarchy Is Nothing Then
ReportError1 L_errAddrBookInvalid_ErrorMessage
End If
For i = 1 to Hierarchy.Count
Set objAddressList = Hierarchy.Item(i)
If objAddressList.Fields(ActMsgPR_DISPLAY_TYPE) = ActMsgDT_GLOBAL then
Err.Clear
Exit For
End If
Next
If objAddressList Is Nothing Then
ReportError1 L_errAddrBookInvalid_ErrorMessage
End If
Set objAddrEntries = objAddressList.AddressEntries
If objAddrEntries Is Nothing or Err.Number <> 0 Then
ReportError1 L_errAddrBookInvalid_ErrorMessage
End If
Set objAEFilter = objAddrEntries.Filter
If objAEFilter Is Nothing or Err.Number <> 0 Then
ReportError1 L_errAddrBookInvalid_ErrorMessage
End If
objAEFilter.Or = False
If strDisplayName <> "" Then
objAEFilter.Fields.Add ActMsgPR_DISPLAY_NAME, strDisplayName
End If
If strFirstName <> "" Then
objAEFilter.Fields.Add ActMsgPR_GIVEN_NAME, strFirstName
End If
If strLastName <> "" Then
objAEFilter.Fields.Add ActMsgPR_SURNAME, strLastName
End If
If strTitle <> "" Then
objAEFilter.Fields.Add ActMsgPR_TITLE, strTitle
End If
If strAlias <> "" Then
objAEFilter.Fields.Add ActMsgPR_ACCOUNT, strAlias
End If
If strCompany <> "" Then
objAEFilter.Fields.Add ActMsgPR_COMPANY_NAME, strCompany
End If
If strDepartment <> "" Then
objAEFilter.Fields.Add ActMsgPR_DEPARTMENT_NAME, strDepartment
End If
If strOffice <> "" Then
objAEFilter.Fields.Add ActMsgPR_OFFICE_LOCATION, strOffice
End If
If strCity <> "" Then
objAEFilter.Fields.Add ActMsgPR_LOCALITY, strCity
End If
If nPubLimit >= objAddrEntries.Count Then
If 1 > objAddrEntries.Count Then %>
<strong>No entry found for this item!</strong><br><br>
Check the details to your search and click 'Find' again.
<% Else
Set objRender = GetAddressContainerRenderer
objRender.RowsPerPage = objAddrEntries.Count
objRender.DataSource = objAddrEntries
objRender.Render 1, 1, 0, Response
End If
Else %>
<strong>This query would return too many addresses!</strong><br>
Please add more details to narrow your search and click 'Find' again.
<% End If %>
</table>
<% Else %>
<strong>No information is available.</strong><br>
Contact your System Adminstrator for more information.
<% End If %>
</FONT>
</BODY>
</HTML>