Chip 1998 February/CHIP_2_98.iso/software/pelne/optionp/ims.cab/smdomhd.asp

Text File | 1997-10-19 | 11KB | 413 lines

<%
'----------------------------------------------------------------------------
'
'   File: smdomhd.asp
'
'   Description: Header file Domains page for SMTP Web Admin.  This page counts
'                and gets the information from all the domains in the Service.  Puts
'                this information into a javascript array so it can be used
'
'   Copyright (C) 1997 Microsoft Corporation
'
'------------------------------------------------------------------------------%>

<% Response.Expires = 0 %>
<%

L_PAGETITLE_TEXT        = "Microsoft SMTP Server Administration"
L_DOMAINNAME_TEXT        = "Domain Name:"
L_DOMAINSON_TEXT        = "Domains on"
L_TYPE_TEXT                = "Type:"

L_DEFAULTLOCAL_TEXT        = "Default Local"
L_NORMALLOCAL_TEXT        = "Normal Local"
L_ALIASLOCAL_TEXT        = "Alias Local"
L_REMOTE_TEXT            = "Remote"

L_CANNOT_REMV_DOMAIN_TEXT        = "Cannot remove domain. A minimum of one domain is required."
L_CONFIRM_REMV_DEFAULT_TEXT        = "If you remove the default Domain, you may not be able to configure the server in the future. Are you sure you want to remove the default Domain?"
L_CONFIRM_REMV_DOMAIN_TEXT        = "Are you sure you want to remove this Domain?"
L_CANNOT_REMOVE_DEFAULT_ERRORMESSAGE = "You cannot remove the default domain.  To remove the default domain you must make another domain the default."


'-------------------------------------------------------------------------------
'
'    BitMask Values
'
'-------------------------------------------------------------------------------
%>
<% SMTP_DROP         = 1 REM local, norma w/non-empty drop dir %>
<% SMTP_SMARTHOST     = 2 REM remote w/ UseSSL not checked %>
<% SMTP_SSL         = 4 REM remote w/ UseSSL checked %>
<% SMTP_ALIAS        = 16 REM local, alias %>
<% SMTP_DELIVER        = 32 REM local, normal w/ empty drop dir %>
<% SMTP_DEFAULT        = 64 REM local, default %>

<!--#include file="smerrors.asp" -->

<% REM Domians Page head frame (in frameset with head, list) %>

<% REM Get variables %>
<% REM svr = Server name %>
<% REM a = Action to be performed by server-side code (remove) %>
<% REM SelectedDom = Domain edited by smdired.asp %>

<% svr = Session("svr") %>
<% a = Request("a") %>
<% SelectedDom = Request("SelectedDom")
ServerInstance = Session("ServiceInstance")
Session("ServiceInstance") = ServerInstance

if (Session("svr") = "") then
    Session("svr") = Request.ServerVariables("SERVER_NAME")
end if
svr            = UCase(Session("svr"))

if (dpath = "") then
    dpath = "IIS://" & svr & "/SmtpSvc"
end if
Session("dpath") = dpath

szServerString = dpath & "/" & ServerInstance
szDomainString = szServerString & "/" & "Domain"
szDomainClassString = "IIsSmtpDomain"

%>
<% REM Index of Domian to Remove %>
<% removeIndex = Request("removeIndex") %>
<% REM Include _cnst file to force logon by anonymous users (if access denied, body of file ignored) %>

<!--#include file="_cnst.asp" -->
<script language="javascript">
<% if (cont = true) then %>
<%
On Error Resume Next
Set admin = GetObject(dpath)
if (Err <> 0) then
    szError = GetErrorMessage(Err) %>
    alert("<% = szError %>");
<% end if %>

<% REM Instantiate Virtual Server object %>
<% On Error Resume Next %>
<% Set VServer = GetObject(szServerString) %>
<% if (Err <> 0) then
    szError = GetErrorMessage(Err) %>
    alert("<% = szError %>");
<% end if %>

<% REM Get pointer to Domains %>
<% On Error Resume Next %>
<% set smtpDomain = GetObject(szDomainString) %>
<% if (Err <> 0) then
    szError = GetErrorMessage(Err) %>
    alert("<% = szError %>");
<% end if %>

<% REM Enumerate Domains
Dim szDomains() REM Arry to hold domain names

iCount = 0
for each child in smtpDomain
    if (child.KeyType = szDomainClassString) then
        iCount = iCount + 1
    end if
next

ReDim szDomains(iCount)
iLoop = 0
szDomains(0) = VServer.DefaultDomain
for each child in smtpDomain
    if (child.KeyType = szDomainClassString) then
        iLoop = iLoop + 1
        szDomains(iLoop) = child.name
        if (child.name = "") then
            szDomains(iLoop) = " "
        end if
    end if
next
%>

<% REM Perform remove action %>

<% if (a = "remove") then %>
<%
    szDomainToRemove = szDomains(removeIndex) %>
    <% On Error Resume Next %>
    <% smtpDomain.Delete szDomainClassString, szDomainToRemove %>
        <% if (Err <> 0) then
            szError = GetErrorMessage(Err) %>
            alert("<% = szError %> : Line #129");
    <% end if %>

    <% On Error Resume Next %>
    <% smtpDomain.SetInfo %>
    <% if (Err <> 0) then
        szError = GetErrorMessage(Err) %>
        alert("<% = szError %> : Line #137");
    <% end if %>

<% end if %>
</script>
<HTML>
<HEAD>
<TITLE><%= L_PAGETITLE_TEXT %></TITLE>

<SCRIPT LANGUAGE="javascript">

<% REM Create uForm object and methods %>

    var uForm = new Object();
    uForm.itemList = new Array();
    uForm.DirHome = "false";
    uForm.selectedItem = 0;
    uForm.selectItem = selectItem;
    uForm.addItem = addItem;
    uForm.removeItem = removeItem;
    uForm.editItem = editItem;

<% REM Get count of Domains
iCount = 0
for each child in smtpDomain
    if (child.KeyType = szDomainClassString) then
        iCount = iCount + 1
    end if
next

ReDim szDomains(iCount)
iLoop = 0
szDomains(0) = VServer.DefaultDomain
for each child in smtpDomain
    if (child.KeyType = szDomainClassString) then
        iLoop = iLoop + 1
        szDomains(iLoop) = child.name
        if (child.name = "") then
            szDomains(iLoop) = " "
        end if
    end if
next

low = LBound(szDomains)
high = HBound(szDomains)

iNumOfDomains = iCount + 1 %>



<% if (iNumOfDomains = 1) then %>
    uForm.selectedItem = 0;
<% end if %>

<% For i = 0 to (iNumOfDomains - 1) %>
<%
    if (i = 0) then
        DomainName = VServer.DefaultDomain
        actiontype = SMTP_DEFAULT
    else
        set myDomain = GetObject(szDomainString & "/" & szDomains(i))
        DomainName = myDomain.Name
        actionType = myDomain.RouteAction
    end if

    icomp        = 0
    icomp = actionType And SMTP_DROP
    if (icomp) then
        Domaintype = L_NORMALLOCAL_TEXT
    end if

    icomp        = 0
    icomp = actionType And SMTP_SMARTHOST
    if (icomp) then
        Domaintype = L_REMOTE_TEXT
    end if

    icomp        = 0
    icomp = actionType And SMTP_SSL
    if (icomp) then
        Domaintype = L_REMOTE_TEXT
    end if

    icomp        = 0
    icomp = actionType And SMTP_ALIAS
    if (icomp) then
        Domaintype = L_ALIASLOCAL_TEXT
    end if

    icomp        = 0
    icomp = actionType And SMTP_DELIVER
    if (icomp) then
        Domaintype = L_NORMALLOCAL_TEXT
    end if

    icomp        = 0
    icomp = actionType And SMTP_DEFAULT
    if (icomp) then
        Domaintype = L_DEFAULTLOCAL_TEXT
    end if

%>

    <% REM SelectedDom variable (passed from pop-up) indicates which item had been selected before page was reloaded %>
    <% REM If SelectedDom equals current Domainname, set selectedItem variable to current index %>

    <% if ((DomainName = Request("SelectedDom")) AND (Request("SelectedDom") <> "")) then %>
    uForm.selectedItem = <% = i %>;
    <% end if %>

    uForm.itemList[<% = i %>] = new Object();
    uForm.itemList[<% = i %>].DomDomainName = "<% = DomainName %>";
    uForm.itemList[<% = i %>].DomainType = "<% = Domaintype %>";

<% Next %>


<% REM Determine browser to set pop-up window size %>

<% if Instr(Request.ServerVariables("HTTP_USER_AGENT"),"IE") then %>
    var winstr = "width=420,height=560,directories=no,status=no,scrollbars=auto,resize=no";
<% else %>
    var winstr = "width=450,height=580,directories=no,status=no,scrollbars=auto,resize=no";
<% end if %>

<% REM Javascript function selectItem changes selectedItem value, reloads list at specified position %>

    function selectItem(index)
    {
        uForm.selectedItem = index;
        parent.list.location = "smdomls.asp"
    }



<% REM Javascript function addItem opens pop-up window %>
<% REM DirHome variable (true/false) specifies whether a home directory already exists %>

    function addItem()
    {
        winstr = "width=420,height=560,directories=no,status=no,scrollbars=auto,resize=no";
        win = window.open("smdomed.asp?a=new&svr=<% = svr %>&ServiceInstance=<% = ServerInstance %>&DirHome=" + uForm.DirHome,"PropWindow",winstr);
        if (win.opener == null)
        {
            win.opener = self;
        }
    }


<% REM Javascript function removeItem displays confirm, reloads head frame with "a=remove" parameter %>
<% REM Displays alert message if user attempts to remove last directory; displays confirm if user attempts to remove home directory %>

    function removeItem()
    {
        index = uForm.selectedItem;
        DomainName = uForm.itemList[index].DomDomainName;

        if (uForm.itemList.length == 1)
        {
            alert("<%= L_CANNOT_REMV_DOMAIN_TEXT %>");
            return;
        }
        else if(index == 0)
        {
            alert("<% = L_CANNOT_REMOVE_DEFAULT_ERRORMESSAGE %>");
            return;

        }
        else
        {
            index = uForm.selectedItem;
            var DomainName = uForm.itemList[index].DomDomainName;
            if (DomainName == "")
            {
                if (confirm("<%= L_CANNOT_REMV_DEFAULT_TEXT %>"))
                {
                    self.location = "smdomhd.asp?svr=<% = svr %>&ServiceInstance=<% = ServerInstance %>&a=remove&removeIndex=" + index;
                }
            }
            else
            {
                if (confirm("<%= L_CONFIRM_REMV_DOMAIN_TEXT %>"))
                {
                    self.location = "smdomhd.asp?svr=<% = svr %>&ServiceInstance=<% = ServerInstance %>&a=remove&removeIndex=" + index;
                }
            }
        }
    }


<% REM Javascript function editItem opens pop-up with specific parameters %>
<% REM DirHome variable (true/false) specifies whether a Domain already exists %>

    function editItem()
    {
        if(uForm.itemList.length > 0)
        {
            index = uForm.selectedItem;
            DomainName = uForm.itemList[index].DomDomainName;
             if(index == 0)
            {
                winstr = "width=420,height=360,directories=no,status=no,scrollbars=auto,resize=no";
            }
            else
            {
                winstr = "width=420,height=560,directories=no,status=no,scrollbars=auto,resize=no";
            }
            win = window.open("smdomed.asp?svr=<% = svr %>&ServiceInstance=<% = ServerInstance %>&a=edit&DomainName=" + DomainName + "&DirHome=" + uForm.DirHome + "&index=" + (index + 1),"PropWindow",winstr);
            if (win.opener == null)
            {
                win.opener = self;
            }
        }

    }


<% REM Javascript function loadList loads list frame after header is completed %>

    function loadList()
    {
        parent.list.location = "smdomls.asp";
    }

    function loadToolBar()
    {
        top.toolbar.location = "nre.asp";
    }

</SCRIPT>

</HEAD>

<BODY BGCOLOR="#CCCCCC" TEXT="#000000" TOPMARGIN=10 OnLoad="loadToolBar();">

<TABLE BORDER=0 WIDTH=600 CELLPADDING=2>
    <TR>
        <TD COLSPAN=2>
            <IMG SRC="images/gnicttl.gif" ALIGN="textmiddle" HEIGHT=10 WIDTH=10> <FONT SIZE=2 FACE="Arial"><B><%= L_DOMAINSON_TEXT %>  </B></FONT><FONT SIZE=3 FACE="Times New Roman"><I><% = svr %></I><BR> </FONT>
        </TD>
    </TR>
    <TR>
        <TD WIDTH=150><FONT SIZE=2 FACE="Arial"><B><%= L_DOMAINNAME_TEXT %></B></FONT></TD>
        <td width=200><FONT SIZE=2 FACE="Arial"><B><%= L_TYPE_TEXT %></b></FONT></TD>
    </TR>
</TABLE>


<% REM Load list frame after head frame is finished loading %>

<SCRIPT LANGUAGE="javascript">
    timeList = setTimeout('loadList()',500);
</SCRIPT>

</BODY>
</HTML>

<% end if %>