Chip 1998 February/CHIP_2_98.iso/software/pelne/optionp/ims.cab/smaccess.asp

Text File | 1997-10-15 | 10KB | 310 lines

<%'----------------------------------------------------------------------------
'
'
'   File: smaccess.asp
'
'   Description: Set access authentication for Directory Security tab
'
'   Copyright (C) 1997 Microsoft Corporation
'
'------------------------------------------------------------------------------%>

<%

Const L_AuthMethods_HtmlTitle       = "Authentication Methods" 'Title of authentication dialog"
Const L_AuthExp_Text                = "Select one or more Authentication Methods for this resource"
Const L_AllowAnonAuth_Checkbox      = "Allow Anonymous Access"
Const L_AnonAuthExp_Text            = "No User Name/Password Required"
Const L_AllowBasicAuth_Checkbox     = "Basic Authentication (password is sent in clear text)"
Const L_BasicAuthExp_Text           = "Allows client authentication with password sent over the network in clear text using the standard protocol authentication commands."
Const L_SetDefaultAuthDomain_Text   = "Default domain for basic authentication:"
Const L_AllowNTChallResp_Checkbox   = "Windows NT Challenge/Response"
Const L_NTChallRespExp_Text         = "Allows client authentication using Windows NT Challenge/Response.  The client and server negotiate the Windows NT System Security Provider Interface."
Const L_EnterDefaultDomain_EditBox  = "Enter the default logon domain:"
Const L_ErrorPrefix_ErrorMessage    = "SMTP Error:" 'Prefix to SMTP errors encountered on this page
Const L_Help_Text                   = "Help" 'Help "button"
Const L_OK_Text                     = "OK"  'OK "button"
Const L_Cancel_Text                 = "Cancel" 'Cancel "button"
Const L_Edit_Button                 = "Edit..." 'actual button
Const L_NOTSELECTED_TEXT            = "You have not selected an Authentication method, you must select one to save the values."

'----[ szFormatError ]---------------------------------------------------------
'
'   Description:
'       Formats an error string
'   Parameters:
'       ErrorObj    - the VBScript Err object
'                   - Can also be error string
'   Returns:
'       Error String
'------------------------------------------------------------------------------
Function szFormatError(ErrorObj)
    Dim szString
    Dim szPrefix
    szPrefix = L_ErrorPrefix_ErrorMessage & " "
    if IsObject(ErrorObj) then
        if ErrorObj.Description <> "" then
            szString = szPrefix &  Server.HTMLEncode(ErrorObj.Description)
        else
            szString = szPrefix & Hex(ErrorObj.Number)
        end if
        ErrorObj.clear()
    else
        On Error Resume Next
        szString = szPrefix & Server.HTMLEncode(CStr(ErrorObj))
    end if

    'Remove unwanted new line characters
    szString = Replace(szString, vbNewLine, " ", 1, -1)
    szFormatError = szString
End Function

'---[ SetProperty ]---------------------------------------------------------
'
'
'  Description:
'       Set Property on an ADSI  object
'  Parameters:
'       ADSIObj  - the ADSI recipient object to set the property on
'       szPropKey - the key identifying the property
'       szPropValue - the value to set the property to
'  Returns:
'       -
'-----------------------------------------------------------------------------
Sub SetProperty(ADSIObj, szPropKey, szPropValue)
    On Error Resume Next

    if IsEmpty(szPropValue) or szPropValue = "" then
        ADSIObj.Get(szPropKey)
        if Err.Number = E_ADS_PROPERTY_NOT_FOUND then
            Err.Clear()
        else
            ADSIObj.PutEx 1, szPropKey, szPropValue
        end if
        'Otherwise data is already clear
    else
        ADSIObj.Put szPropKey, Array(szPropValue)
    end if
End Sub


Const AuthBasicFlag                 = "AuthBasic"
Const AuthAnonFlag                  = "AuthAnonymous"
Const AuthNTLMFlag                  = "AuthNTLM"
Const DefaultAuthDomain             = "SASLLogonDomain"
Const E_ADS_PROPERTY_NOT_FOUND = &H8000500d


if Request("ServiceInstance") <> "" then
    Session("ServiceInstance") = Request("ServiceInstance")
elseif Session("ServiceInstance") = "" then
    Session("ServiceInstance") = "1"
end if

if Request("svr") <> "" then
    Session("svr") = Request("svr")
elseif Session("svr") = "" then
    Session("svr") = Request.ServerVariables("SERVER_NAME")
end if


%>

<HTML>
<HEAD>
<TITLE><% =L_AuthMethods_HtmlTitle%></TITLE>
<SCRIPT LANGUAGE="javascript">

<%
    On Error Resume Next
    Dim szAnonChecked
    Dim szBasicChecked
    Dim szNTChecked
    Dim szDefaultLogonDomain
    set ServiceObj = GetObject("IIS://" & Session("svr") & "/SmtpSvc/" & Session("ServiceInstance"))
    if (Err <> 0 ) then
        %>alert("<% =szFormatError(Err)%>");<%
    else
        if Request("a") = "submit" then 'save data
            if Request("chkAuthAnonymous") then
                Call ServiceObj.Put(AuthAnonFlag, true)
                szAnonChecked = "CHECKED"
            else
                Call ServiceObj.Put(AuthAnonFlag, false)
            end if
            if Request("chkAuthBasic") then
                Call ServiceObj.Put(AuthBasicFlag, true)
                szBasicChecked = "CHECKED"
            else
                Call ServiceObj.Put(AuthBasicFlag, false)
            end if
            if Request("chkAuthNT") then
                Call ServiceObj.Put(AuthNTLMFlag, true)
                szNTChecked = "CHECKED"
            else
                Call ServiceObj.Put(AuthNTLMFlag, false)
            end if
            Call SetProperty(ServiceObj, DefaultAuthDomain, CStr(Request("szDefaultLogonDomain")))
            szDefaultLogonDomain = Request("szDefaultLogonDomain")
            ServiceObj.SetInfo
            szOnLoad = "OnLoad=""close();"""
        else
            if ServiceObj.Get(AuthAnonFlag) = true then szAnonChecked = "CHECKED"
            if ServiceObj.Get(AuthBasicFlag) = true then szBasicChecked = "CHECKED"
            if ServiceObj.Get(AuthNTLMFlag) = true then szNTChecked = "CHECKED"
            szDefaultLogonDomain = ServiceObj.Get(DefaultAuthDomain)
        end if
        if Err.Number = E_ADS_PROPERTY_NOT_FOUND then Err.Clear()
        if (Err <> 0 ) then
            szOnLoad = ""
            %>alert("<% =szFormatError(Err)%>");<%
        end if
        Set ServiceObj = nothing
    end if
%>


<% REM Javascript function editItem %>
function SetDomain()
{
    var name;
    name = prompt("<% =L_EnterDefaultDomain_EditBox%>",document.userform.szDefaultLogonDomain.value);
    document.userform.szDefaultLogonDomain.value = name;
}

function helpBox()
{
    window.open("help/smsech.htm","help","toolbar=no,scrollbars=yes,directories=no,menubar=no,width=300,height=425");
}

function onOK()
{
    if(checkControls())
    {
        document.userform.submit();
    }
}

function checkControls()
{
    uform = document.userform;
    if((uform.chkAuthNT.checked != true) && (uform.chkAuthBasic.checked != true) && (uform.chkAuthAnonymous.checked != true))
    {
        alert("<% = L_NOTSELECTED_TEXT %>");
        return false;
    }

    return true;

}

</SCRIPT>

</HEAD>
<BODY BACKGROUND="images\black.gif" LINK="#FFFFFF" <% =szOnLoad%>>
<FORM NAME="userform" action="smaccess.asp" METHOD=POST>
<INPUT TYPE=HIDDEN NAME="szDefaultLogonDomain" VALUE="<% =szDefaultLogonDomain%>">
<INPUT TYPE=HIDDEN NAME="a" VALUE="submit">
<TABLE BORDER=1 BGCOLOR="#CCCCCC" WIDTH=100% CELLPADDING=10>

<TR><TD>
<P>
<TABLE BORDER="0" BGCOLOR="#CCCCCC" WIDTH="99%" CELLPADDING=5 CELLSPACING="5" ROWS=8 COLS=2>
    <TR>
        <TD COLSPAN=2><% =L_AuthExp_Text%></TD>
    </TR>
    <TR>
        <TD><INPUT TYPE="CHECKBOX" NAME="chkAuthAnonymous" <% =szAnonChecked%> VALUE="on" ></TD>
        <TD><% =L_AllowAnonAuth_Checkbox%></TD>
    </TR>
    <TR>
        <TD> </TD>
        <TD><% =L_AnonAuthExp_Text%></TD>
    </TR>
    <TR>
        <TD><INPUT TYPE="CHECKBOX" NAME="chkAuthBasic" <% =szBasicChecked%> VALUE="on"></TD>
        <TD><% =L_AllowBasicAuth_Checkbox%></TD>
    </TR>
    <TR>
        <TD> </TD>
        <TD><% =L_BasicAuthExp_Text%></TD>
    </TR>
    <TR>
        <TD> </TD>
        <TD>
            <% =L_SetDefaultAuthDomain_Text%>

            <INPUT TYPE=BUTTON NAME="edit" VALUE="<% =L_Edit_Button%>" OnClick="SetDomain();">
        </TD>
    </TR>
    <TR>
        <TD><INPUT TYPE="CHECKBOX" NAME="chkAuthNT" <% =szNTChecked%> VALUE="on" ></TD>
        <TD><% =L_AllowNTChallResp_Checkbox%></TD>
    </TR>
    <TR>
        <TD> </TD>
        <TD><% =L_NTChallRespExp_Text%></TD>
    </TR>
</TABLE>
<P>
</TD></TR>
</TABLE>
<P>
<TABLE ALIGN="right" CELLPADDING=1 CELLSPACING=1>

<TR>
    <TD><TABLE VALIGN="top" BORDER=0 CELLPADDING=5 CELLSPACING=0 BGCOLOR="#FFCC00">

        <TR>
            <TD VALIGN="middle">
                <FONT FACE="Arial" SIZE=2>
                <B><A HREF="javascript:onOK();">
                <IMG SRC="images/gnicok.gif" BORDER=0 ALIGN="top" HEIGHT=16 WIDTH=16></A>
                <A HREF="javascript:onOK();"><% =L_OK_Text%></A></B>
                </FONT>
            </TD>

        </TR>

    </TABLE></TD>

    <TD><TABLE VALIGN="top" BORDER=0 CELLPADDING=5 CELLSPACING=0 BGCOLOR="#FFCC00">

        <TR>

            <TD VALIGN="middle">
                <FONT FACE="Arial" SIZE=2>
                <B><A HREF="javascript:close();">
                <IMG SRC="images/gniccncl.gif" BORDER=0 ALIGN="top" HEIGHT=16 WIDTH=16></A>
                <A HREF="javascript:close();"><% =L_Cancel_Text%></A></B>
                </FONT>
            </TD>

        </TR>

    </TABLE></TD>

    <TD><TABLE VALIGN="top" BORDER=0 CELLPADDING=5 CELLSPACING=0 BGCOLOR="#FFCC00">

        <TR>

            <TD VALIGN="middle">
                <FONT FACE="Arial" SIZE=2><A HREF="javascript:helpBox();">
                <IMG SRC="images/gnichelp.gif" BORDER=0 ALIGN="top" HEIGHT=16 WIDTH=16></A>
                <B><A HREF="javascript:helpBox();"><% =L_Help_Text%></A></B>
                </FONT>
            </TD>

        </TR>

    </TABLE></TD>

    <TD> </TD>

</TR>
</TABLE>
</FORM>
</BODY>
</HTML>