home *** CD-ROM | disk | FTP | other *** search
/ Chip 1998 February / CHIP_2_98.iso / software / pelne / optionp / iis4_07.cab / metabackdel.vbs < prev    next >
Text File  |  1997-10-25  |  3KB  |  113 lines
  1. '''''''''''''''''''''''''''''''''''''''''''''
  2. '
  3. '  Metabase Backup Deletion Utility   
  4. '
  5. '''''''''''''''''''''''''''''''''''''''''''''
  6.  
  7. '  Description:
  8. '  ------------
  9. '  This sample admin script allows you to delete a Metabase backup.
  10. '
  11. '  To Run:  
  12. '  -------
  13. '  This is the format for this script:
  14. '  
  15. '      cscript metabackdel.vbs 
  16. '  
  17. '  NOTE:  If you want to execute this script directly from Windows, use 
  18. '  'wscript' instead of 'cscript'. 
  19. '
  20. '''''''''''''''''''''''''''''''''''''''''''''
  21.  
  22. ' Initialize error checking
  23. On Error Resume Next
  24.  
  25. ' Initialize variables
  26. Dim ArgCount, BuName, BuVersion, CompObj, VersionMsg
  27.  
  28. ' Default values
  29. ArgCount = 0
  30. BuName = ""  ' Default backup, but will not be allowed
  31. BuVersion = &HFFFFFFFE  ' Designates highest existing version
  32.  
  33.  
  34.  
  35.   ' ** Parse Command Line
  36.  
  37.     ' Loop through arguments
  38.     While ArgCount < Wscript.Arguments.Count
  39.       
  40.       ' Determine switches used
  41.       Select Case Wscript.Arguments(ArgCount)
  42.  
  43.          Case "-v":   ' Designate backup version to be deleted
  44.             ' Move to next arg, which should be parameter
  45.             ArgCount =  ArgCount + 1  
  46.             If ArgCount => Wscript.Arguments.Count Then
  47.                   Call UsageMsg
  48.             Else
  49.                BuVersion = Wscript.Arguments(ArgCount)
  50.             End If
  51.  
  52.          Case "-h", "/?", "-?":
  53.             Call UsageMsg
  54.  
  55.          Case Else:
  56.             If BuName <> "" Then ' Only one name allowed
  57.                 Call UsageMsg
  58.             Else
  59.                 BuName = Wscript.Arguments(ArgCount)
  60.             End If
  61.  
  62.       End Select
  63.  
  64.       ' Move pointer to next argument
  65.       ArgCount = ArgCount + 1
  66.  
  67.     Wend
  68.  
  69.  
  70.   ' If no location name was selected, generate error 
  71.   If BuName = "" Then 
  72.     Call UsageMsg
  73.   End If
  74.  
  75.   ' Get instance of computer object
  76.   Set CompObj = GetObject("IIS://Localhost")
  77.  
  78.   ' Try to delete backup
  79.   CompObj.DeleteBackup BuName, BuVersion
  80.  
  81.   ' Make version string pretty
  82.   If BuVersion = &HFFFFFFFE Then
  83.         VersionMsg = "highest version"
  84.   Else
  85.         VersionMsg = "version " & BuVersion
  86.   End If
  87.  
  88.   If Err.Number <> 0 Then   ' Errors!
  89.          If Err.Number = &H80070002 Then  ' Version doesn't exist
  90.              Wscript.Echo "Error deleting backup: '" & BuName & "' (" & VersionMsg & ") does not exist."
  91.          Else  ' Some other error
  92.              Wscript.Echo "Error deleting backup: '" & BuName & "' (" & VersionMsg & ")."
  93.              Wscript.Echo "Error number: " & Hex(Err.Number)
  94.          End If
  95.  
  96.   Else   ' No errors!
  97.          Wscript.Echo "Backup deleted: '" & BuName & "' (" & VersionMsg & ")."
  98.   End If
  99.  
  100.  
  101.  
  102. ' Displays usage message, then QUITS
  103. Sub UsageMsg
  104.   Wscript.Echo "Usage:  cscript metabackdel.vbs <backupname> [-v <versionnum>]"
  105.   Wscript.Quit
  106. End Sub
  107.  
  108.  
  109.  
  110.  
  111.  
  112.  
  113.