home *** CD-ROM | disk | FTP | other *** search
/ Chip 2011 November / CHIP_2011_11.iso / Programy / Narzedzia / AIMP2 / aimp_2.61.583.exe / $TEMP / YandexPackSetup.msi / fil469815FF3F72C0C9FDF7624E68BD3875 < prev    next >
Encoding:
Extensible Markup Language  |  2010-07-12  |  3.1 KB  |  103 lines
  1. <?xml version="1.0" encoding="UTF-8"?>
  2. <!DOCTYPE stylesheet SYSTEM "chrome://yasearch/locale/yasearch.dtd">
  3.  
  4. <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  5.   xmlns:data="urn:data"
  6.   xmlns="http://www.mozilla.org/keymaster/gatekeeper/there.is.only.xul"
  7.   extension-element-prefixes="data"
  8. >
  9.  
  10. <xsl:output method="xml" encoding="UTF-8" indent="no"/>
  11.  
  12. <xsl:variable name="id" select="'yandex-menu'"/>
  13. <xsl:variable name="domain" select="'.yandex.ru/'"/>
  14. <xsl:variable name="images" select="'chrome://yasearch/skin/images/'"/>
  15. <xsl:variable name="id-prefix" select="'yasearchMenuIdPrefix-'"/>
  16.  
  17. <xsl:template match="data:services">
  18.   <menu>
  19.     <xsl:apply-templates select="@*"/>
  20.     <menupopup>
  21.       <xsl:apply-templates select="data:group/data:service[@search-url]">
  22.         <xsl:sort select="@stat" order="descending" data-type="number"/>
  23.       </xsl:apply-templates>
  24.       <xsl:apply-templates select="data:group/data:complex[data:complex/data:service[@search-url] | data:service[@search-url]]"/>
  25.     </menupopup>
  26.   </menu>
  27. </xsl:template>
  28.  
  29. <xsl:template match="data:complex">
  30.   <menu>
  31.     <xsl:apply-templates select="@*"/>
  32.     <menupopup>
  33.       <xsl:apply-templates select="data:complex | data:service | data:separator">
  34.         <xsl:sort select="@stat" order="descending" data-type="number"/>
  35.       </xsl:apply-templates>
  36.     </menupopup>
  37.   </menu>
  38. </xsl:template>
  39.  
  40. <xsl:template match="data:separator">
  41.   <menuseparator/>
  42. </xsl:template>
  43.  
  44. <xsl:template match="data:service">
  45.   <menuitem oncommand="Ya.search('{@id}', event);">
  46.     <xsl:apply-templates select="@*"/>
  47.     <xsl:apply-templates />
  48.   </menuitem>
  49. </xsl:template>
  50.  
  51. <xsl:template match="@*">
  52.   <xsl:copy-of select="."/>
  53. </xsl:template>
  54.  
  55. <xsl:template match="@mode">
  56.   <xsl:if test="not(contains(.,$id))">
  57.     <xsl:attribute name="style">
  58.       <xsl:text>display: none !important;</xsl:text>
  59.     </xsl:attribute>
  60.   </xsl:if>
  61. </xsl:template>
  62.  
  63. <xsl:template match="@id">
  64.   <xsl:attribute name="id">
  65.     <xsl:value-of select="concat($id-prefix, .)"/>
  66.   </xsl:attribute>
  67. </xsl:template>
  68.  
  69. <xsl:template match="data:services/@id">
  70.   <xsl:attribute name="id">
  71.     <xsl:value-of select="concat($id-prefix, $id)"/>
  72.   </xsl:attribute>
  73. </xsl:template>
  74.  
  75. <xsl:template match="data:services/@image | data:complex/@image | data:group/@image">
  76.   <xsl:attribute name="class">
  77.     <xsl:text>menu-iconic</xsl:text>
  78.   </xsl:attribute>
  79.   <xsl:apply-templates select="." mode="image"/>
  80. </xsl:template>
  81.  
  82. <xsl:template match="data:service/@image">
  83.   <xsl:attribute name="class">
  84.     <xsl:text>menuitem-iconic</xsl:text>
  85.   </xsl:attribute>
  86.   <xsl:apply-templates select="." mode="image"/>
  87. </xsl:template>
  88.  
  89. <xsl:template match="@image" mode="image">
  90.   <xsl:attribute name="image">
  91.     <xsl:value-of select="concat($images, ., '.png')"/>
  92.   </xsl:attribute>
  93. </xsl:template>
  94.  
  95. <xsl:template match="@desc[. != '']">
  96.   <xsl:attribute name="tooltiptext">
  97.     <xsl:value-of select="."/>
  98.   </xsl:attribute>
  99. </xsl:template>
  100.  
  101. <xsl:template match="@desc | @service-timestamp | @search-url | @host | @https"/>
  102.  
  103. </xsl:stylesheet>