home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Chip 2005 November
/
CDVD1105.ISO
/
Util
/
Winamp
/
Skins
/
Anime_Shogo.wal
/
scripts
/
actionsscrpt.m
next >
Wrap
Text File
|
2004-08-09
|
3KB
|
129 lines
#include "../../../lib/std.mi"
Function SetRepeat();
Function SetTempText(String TempText);
Global Button Mute;
Global Togglebutton Shuffle, Repeat;
Global Text Songticker, StatusTxt;
Global Timer TempTextTimer;
Global Boolean MuteState;
Global Int MuteLevel;
System.onScriptLoaded() {
Group ActionGrp = System.getScriptGroup();
Mute = ActionGrp.findObject("MuteButton");
Shuffle = ActionGrp.findObject("ShuffleButton");
Repeat = ActionGrp.findObject("RepeatButton");
Songticker = ActionGrp.findObject("Songticker");
StatusTxt = ActionGrp.findObject("Status");
TempTextTimer = new Timer;
TempTextTimer.setDelay(1000);
if (Shuffle.getActivated()) {
Shuffle.setXmlParam("hoverimage", "shogo.shuffle.on.hover");
Shuffle.setXmlParam("tooltip", "Shuffle Status: On");
}
MuteState = 0;
SetRepeat();
}
System.onScriptUnloading() {
delete TempTextTimer;
}
Repeat.onToggle(boolean on) {
SetRepeat();
int v = Repeat.getXmlParam("cfgval");
if (v == 0){
SetTempText("Repeat Off");
} else if (v == 1){
SetTempText("Repeat All");
} else if (v == 2){
SetTempText("Repeat One");
} else if (v == -1){
SetTempText("PLay One");
}
}
Mute.onLeftButtonUp(int x, int y) {
if (!MuteState && getVolume()>0) {
MuteLevel = getVolume();
System.setVolume(0);
MuteState = 1;
Mute.setXmlParam("tooltip", "Mute Status: On");
SetTempText("Mute On");
} else {
MuteState = 0;
System.setVolume(MuteLevel);
Mute.setXmlParam("tooltip", "Mute Status: Off");
SetTempText("Mute Off");
}
}
Shuffle.ontoggle(boolean on){
if (on) {
Shuffle.setXmlParam("hoverimage", "shogo.shuffle.on.hover");
Shuffle.setXmlParam("tooltip", "Shuffle Status: On");
SetTempText("Shuffle On");
} else {
Shuffle.setXmlParam("hoverimage", "shogo.shuffle.hover");
Shuffle.setXmlParam("tooltip", "Shuffle Status: Off");
SetTempText("Shuffle Off");
}
}
SetRepeat() {
int v = Repeat.getXmlParam("cfgval");
if (v == 0){
Repeat.setXMLParam("hoverimage", "shogo.repeat.hover");
Repeat.setXMLParam("tooltip", "Repeat Status: Off");
} else if (v == 1){
Repeat.setXMLParam("hoverimage", "shogo.repeat.on.hover");
Repeat.setXMLParam("tooltip", "Repeat Status: Repeat All");
} else if (v == 2){
Repeat.setXMLParam("hoverimage", "shogo.repeat.on.hover");
Repeat.setXMLParam("tooltip", "Repeat Status: Repeat One");
} else if (v == -1){
Repeat.setXMLParam("hoverimage", "shogo.repeat.on.hover");
Repeat.setXMLParam("tooltip", "Repeat Status: Play One");
}
}
SetTempText(String TempText) {
Songticker.setTargetA(0);
Songticker.setTargetSpeed(0.5);
Songticker.gotoTarget();
StatusTxt.setTargetA(255);
StatusTxt.setTargetSpeed(0.5);
StatusTxt.gotoTarget();
StatusTxt.setText(TempText);
TempTextTimer.start();
}
TempTextTimer.onTimer() {
StatusTxt.setTargetA(0);
StatusTxt.setTargetSpeed(0.5);
StatusTxt.gotoTarget();
Songticker.setTargetA(255);
Songticker.setTargetSpeed(0.5);
Songticker.gotoTarget();
TempTextTimer.stop();
}
System.onVolumeChanged(int newvol) {
if (MuteState && newvol > 0) {
MuteState = 0;
Mute.setXmlParam("tooltip", "Mute Status: Off");
}
}