home *** CD-ROM | disk | FTP | other *** search
NSIS script | 2003-12-02 | 2.5 KB | 89 lines |
- ; example2.nsi
- ;
- ; This script is based on example1.nsi, but it remember the directory,
- ; has uninstall support and (optionally) installs start menu shortcuts.
- ;
- ; It will install makensisw.exe into a directory that the user selects,
-
- ;--------------------------------
-
- ; The name of the installer
- Name "Example2"
-
- ; The file to write
- OutFile "example2.exe"
-
- ; The default installation directory
- InstallDir $PROGRAMFILES\Example2
-
- ; Registry key to check for directory (so if you install again, it will
- ; overwrite the old one automatically)
- InstallDirRegKey HKLM "Software\NSIS_Example2" "Install_Dir"
-
- ;--------------------------------
-
- ; Pages
-
- Page components
- Page directory
- Page instfiles
-
- UninstPage uninstConfirm
- UninstPage instfiles
-
- ;--------------------------------
-
- ; The stuff to install
- Section "Example2 (required)"
-
- SectionIn RO
-
- ; Set output path to the installation directory.
- SetOutPath $INSTDIR
-
- ; Put file there
- File "..\makensisw.exe"
-
- ; Write the installation path into the registry
- WriteRegStr HKLM SOFTWARE\NSIS_Example2 "Install_Dir" "$INSTDIR"
-
- ; Write the uninstall keys for Windows
- WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2" "DisplayName" "NSIS Example2"
- WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2" "UninstallString" '"$INSTDIR\uninstall.exe"'
- WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2" "NoModify" 1
- WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2" "NoRepair" 1
- WriteUninstaller "uninstall.exe"
-
- SectionEnd
-
- ; Optional section (can be disabled by the user)
- Section "Start Menu Shortcuts"
-
- CreateDirectory "$SMPROGRAMS\Example2"
- CreateShortCut "$SMPROGRAMS\Example2\Uninstall.lnk" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0
- CreateShortCut "$SMPROGRAMS\Example2\Example2 (MakeNSISW).lnk" "$INSTDIR\makensisw.exe" "" "$INSTDIR\makensisw.exe" 0
-
- SectionEnd
-
- ;--------------------------------
-
- ; Uninstaller
-
- Section "Uninstall"
-
- ; Remove registry keys
- DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\Example2"
- DeleteRegKey HKLM SOFTWARE\NSIS_Example2
-
- ; Remove files and uninstaller
- Delete $INSTDIR\makensisw.exe
- Delete $INSTDIR\uninstall.exe
-
- ; Remove shortcuts, if any
- Delete "$SMPROGRAMS\Example2\*.*"
-
- ; Remove directories used
- RMDir "$SMPROGRAMS\Example2"
- RMDir "$INSTDIR"
-
- SectionEnd