home *** CD-ROM | disk | FTP | other *** search
/ Chip 2004 March / CMCD0304.ISO / Software / Freeware / Programare / nullsoft / nsis20.exe / Contrib / System / System.nsi < prev    next >
Encoding:
Text File  |  2003-09-11  |  4.8 KB  |  143 lines
  1. ; This is just an example of System Plugin
  2. ; 
  3. ; (c) brainsucker, 2002
  4. ; (r) BSForce
  5.  
  6. Name "System Plugin Example"
  7. OutFile "System.exe"
  8. SetPluginUnload  alwaysoff
  9.  
  10. !include "${NSISDIR}\Contrib\System\sysfunc.nsh"
  11.  
  12. Section "ThisNameIsIgnoredSoWhyBother?"
  13.      SetOutPath $TEMP
  14.  
  15.      ; ----- Sample 1 ----- Message box with custom icon -----
  16.  
  17.      ; there are no default beeps for custom message boxes, use sysMessageBeep
  18.      ; in case you need it (see next message box example)
  19.      !insertmacro smMessageBox "i 0" "Message box with custom icon!" "System Example 1a" ${MB_OK} "i 103"
  20.      ; i 0 - installer exe as module
  21.      ; i 103 - icon ID
  22.  
  23.      ; The same example but using icon from resource.dll.
  24.      ; You could use this dll for storing your resources, just replace FAR icon
  25.      ; with something you really need.   
  26.      File "${NSISDIR}\Contrib\System\Resource.dll"
  27.      System::Call '${sysMessageBeep} (${MB_ICONHAND})'  ; custom beep
  28.      !insertmacro smMessageBox "`$TEMP\resource.dll`" "Message box with custom icon from resource.dll!" "System Example 1b" ${MB_OKCANCEL} "i 103"
  29.      Delete $TEMP\resource.dll
  30.  
  31.      ; ----- Sample 2 ----- Fixed disks size/space -----
  32.  
  33.      StrCpy $7 '               Disk,                Size,                Free,                Free for user:$\n$\n'
  34.  
  35.      ; Memory for paths   
  36.      System::Alloc 1024
  37.      Pop $1
  38.      ; Get drives   
  39.      System::Call '${sysGetLogicalDriveStrings}(1024, r1)'
  40. enumok:
  41.      ; One more drive?   
  42.      System::Call '${syslstrlen}(i r1) .r2'
  43.      IntCmp $2 0 enumex
  44.  
  45.      ; Is it DRIVE_FIXED?
  46.      System::Call '${sysGetDriveType} (i r1) .r3'
  47.      StrCmp $3 ${DRIVE_FIXED} 0 enumnext
  48.  
  49.      ; Drive space   
  50.      System::Call '${sysGetDiskFreeSpaceEx}(i r1, .r3, .r4, .r5)'
  51.  
  52.      ; Pretty KBs will be saved on stack
  53.      System::Int64Op $3 / 1048576
  54.      System::Int64Op $5 / 1048576
  55.      System::Int64Op $4 / 1048576
  56.  
  57.      ; Get pretty drive path string   
  58.      System::Call '*$1(&t1024 .r6)'
  59.      System::Call '${syswsprintf} (.r7, "%s%20s    %20s mb    %20s mb    %20s mb$\n", tr7, tr6, ts, ts, ts)'
  60.  
  61. enumnext:
  62.      ; Next drive path       
  63.      IntOp $1 $1 + $2
  64.      IntOp $1 $1 + 1
  65.      goto enumok   
  66. enumex: ; End of drives or user cancel
  67.      ; Free memory for paths   
  68.      System::Free $1   
  69.  
  70.      ; Message box      
  71.      System::Call '${sysMessageBox}($HWNDPARENT, s, "System Example 2", ${MB_OKCANCEL})' "$7"
  72.  
  73.      ; ----- Sample 3 ----- Direct proc defenition -----
  74.  
  75.      ; Direct specification demo
  76.      System::Call 'user32::MessageBoxA(i $HWNDPARENT, t "Just direct MessageBoxA specification demo ;)", t "System Example 3", i ${MB_OK}) i.s'
  77.      Pop $0
  78.  
  79.      ; ----- Sample 4 ----- Int64, mixed definition demo -----
  80.  
  81.      ; Long int demo
  82.      StrCpy $2 "12312312"
  83.      StrCpy $3 "12345678903"
  84.      System::Int64Op $2 "*" $3
  85.      Pop $4
  86.  
  87.      ; Cdecl demo (uses 3 defenitions (simple example))
  88.      System::Call "${syswsprintf}(.R1, s,,, t, ir0) .R0 (,,tr2,tr3,$4_)" "Int64 ops and strange defenition demo, %s x %s == %s, and previous msgbox result = %d"
  89.      MessageBox MB_OKCANCEL "Cool: '$R1'"
  90.  
  91.      ; ----- Sample 5 ----- Small structure example -----
  92.  
  93.      ; Create & Fill structure
  94.      System::Call "*(i 123123123, &t10 'Hello', &i1 0x123dd, &i2 0xffeeddccaa) i.s"
  95.      Pop $1
  96.      ; Read data from structure   
  97.      System::Call "*$1(i .r2, &t10 .r3, &i1 .r4, &i2 .r5, &l0 .r6)"
  98.      ; Show data and delete structure
  99.      MessageBox MB_OK "Structure example: $\nint == $2 $\nstring == $3 $\nbyte == $4 $\nshort == $5 $\nsize == $6"
  100.      System::Free $1
  101.  
  102.      ; ----- Sample 6 ----- systemGetFileSysTime demo -----
  103.      Call       GetInstallerExeName
  104.      pop        $0
  105.  
  106.      !insertmacro smGetFileSysTime $0
  107.      System::Call '*$R0${stSYSTEMTIME}(.r1, .r2, .r3, .r4, .r5, .r6, .r7, .r8)'
  108.  
  109.      MessageBox MB_OK "GetFileSysTime example: file '$0', year $1, month $2, dow $3, day $4, hour $5, min $6, sec $7, ms $8"     
  110.  
  111.      ; free memory from SYSTEMTIME
  112.      System::Free $R0   
  113.  
  114.      ; ----- Sample 7 ----- systemSplash -> Callbacks demonstration -----
  115.  
  116.      ; Logo
  117.      File /oname=spltmp.bmp "${NSISDIR}\Contrib\Makensisw\logo.bmp"
  118. ;     File /oname=spltmp.wav "d:\Windows\Media\tada.wav"
  119.  
  120.      ; I. systemSplash variant
  121.      !insertmacro smSystemSplash 2000 "$TEMP\spltmp"
  122.  
  123.      ; II. Splash Plugin variant
  124. ;    splash::show 2000 $TEMP\spltmp
  125. ;    Pop $R0 ; $R0 has '1' if the user closed the splash screen early,
  126.  
  127.      ; remove logo
  128.      Delete $TEMP\spltmp.bmp
  129. ;     Delete $TEMP\spltmp.wav
  130.  
  131.      ; Display splash result
  132.      pop $0
  133.      MessageBox MB_OK "Splash (callbacks) demo result $R0"
  134.  
  135.      ; last plugin call must not have /NOUNLOAD so NSIS will be able to delete the temporary DLL
  136.      SetPluginUnload manual
  137.      ; do nothing
  138.      System::Free 0
  139.  
  140. SectionEnd 
  141.  
  142. ; eof
  143.