home *** CD-ROM | disk | FTP | other *** search
/ GameStar 2006 January / Gamestar_80_2006-01_dvd.iso / Utility / 5-11_xp-2k_dd_ccc_wdm_enu_27345.exe / Data1.cab / _575A79A667DB4E1686331BC1E75DBB57 < prev    next >
Text File  |  2004-01-22  |  6KB  |  197 lines
  1. !!ARBvp1.0
  2. # road vertex shader
  3. PARAM WORLD_VIEW_PROJECTION[4] = { program.env[0..3] };
  4. PARAM WORLD_VIEW[4] = { program.env[4..7] };
  5. PARAM WORLD[4] = { program.env[8..11] };
  6.  
  7. PARAM SUN_DIRECTION = program.env[12];            #(.w = intensity)        
  8. PARAM SUN_ANGLE = program.env[14];
  9. PARAM SUN_COLOR = program.env[15];
  10. PARAM TERRAIN_REFLECTANCE = program.env[13];
  11.  
  12. PARAM BETA_1 = program.env[30];
  13. PARAM BETA_2 = program.env[29];
  14. PARAM BETA_DASH_1 = program.env[27];
  15. PARAM BETA_DASH_2 = program.env[26];
  16. PARAM BETA_1_PLUS_2 = program.env[24];
  17. PARAM ONE_OVER_BETA_1_PLUS_2 = program.env[23];
  18.  
  19. PARAM HG = program.env[28];        # = 1-g^2, 1+g, 2g, 0
  20. PARAM CONSTANTS = program.env[31];        # = 1.0, log_2 e, 0.5, 0
  21. PARAM TERM_MULTIPLIERS = program.env[25];        # = frac_ext, frac_ins.
  22.  
  23. PARAM ZERO = program.env[20];
  24. PARAM ONE = program.env[21];
  25. PARAM SHADOWSHARPNESS = program.env[32];
  26. PARAM AMBIENT = program.env[33];      # Ambient term to add to the rendering
  27. PARAM INSCATTERINGMULTIPLIER = program.env[34];      # Term to attenuate the inscattering
  28.  
  29. PARAM BASE_TEX_PROJECTION = program.env[16];
  30. PARAM DETAIL_TEX_PROJECTION = program.env[17];
  31. PARAM CLOUD_TEX_PROJECTION_0 = program.env[18];
  32. PARAM CLOUD_TEX_PROJECTION_1 = program.env[19];
  33.  
  34. PARAM EYE_POSITION = program.env[22];
  35.  
  36. PARAM SPECULAR_POWER = program.env[35];
  37. PARAM DIFFUSE_COLOUR = program.env[36];
  38. PARAM SPECULAR_COLOUR = program.env[37];
  39.  
  40. PARAM CARCOLOR0 = program.env[38];
  41. PARAM CARCOLOR1 = program.env[39];
  42. PARAM CARCOLOR2 = program.env[40];
  43.  
  44. ATTRIB iPos = vertex.position;
  45. ATTRIB iNormal = vertex.normal;
  46. ATTRIB iTexCoord0 = vertex.texcoord[0];
  47. ATTRIB iTexCoord1 = vertex.texcoord[1];
  48. ATTRIB iTexCoord2 = vertex.texcoord[2];
  49.  
  50. OUTPUT oPos = result.position;
  51. OUTPUT oD0 = result.color.primary;
  52. OUTPUT oD1 = result.color.secondary;
  53. OUTPUT oT0 = result.texcoord[0];
  54. OUTPUT oT1 = result.texcoord[1];
  55. OUTPUT oT2 = result.texcoord[2];
  56. OUTPUT oT3 = result.texcoord[3];
  57.  
  58. #line 1 "ScatterVS10.vsh"
  59. # Scattering Vertex shader
  60. # (c) 2002 Nathaniel Hoffman, Kenneth J. Mitchell and Arcot J. Preetham
  61. #
  62. # 
  63. # 
  64. # V - View direction
  65. # L - Sun direction
  66. # Theta - Scattering angle
  67. # s - Distance
  68. # E - Total extinction (including reflectance).
  69.  
  70. TEMP r0, r1, r2, r3, r4, r5, r6, r7;
  71.  
  72. # Transformation.
  73. DP4     oPos.x, iPos, WORLD_VIEW_PROJECTION[0];
  74. DP4     oPos.y, iPos, WORLD_VIEW_PROJECTION[1];
  75. DP4     oPos.z, iPos, WORLD_VIEW_PROJECTION[2];
  76. DP4     oPos.w, iPos, WORLD_VIEW_PROJECTION[3];
  77.  
  78. # Dot product sun direction with vertex normal
  79. DP3 r0.xyzw, iNormal, SUN_DIRECTION;
  80. # scale by sun color
  81. MUL     r0.xyz, r0, SUN_COLOR;
  82.  
  83. # Sun angle information is in constant 14
  84. # x component is the angle
  85. # y component is the multiplier for the +ve horizon angle (0 or 1)
  86. # z component is the multiplier for the -ve horizon angle (inverse of above)
  87. # Get appropriate horizon information into r0.w
  88.  
  89. MUL     r0.w, iTexCoord0.x, SUN_ANGLE.y;
  90. MUL     r1.w, iTexCoord0.y, SUN_ANGLE.z;
  91. ADD     r1.w, r0.w, r1.w;
  92.  
  93. # Set r0.w if light angle is > horizon angle, otherwise clear it
  94. #sge    r0.w, SUN_ANGLE.x, r1.w
  95.  
  96. # Now calculate the 'shadow intensity'
  97.  
  98. SUB        r1.w, SUN_ANGLE.x, r1.w;    # (light angle - horizon angle)
  99. MUL        r1.w, r1.w, SHADOWSHARPNESS.x; # (Sharpness factor) * (angle delta)
  100. ADD        r1.w, r1.w, ONE.x; # 1 + (5 * angle delta)
  101.  
  102. MAX        r1.w, r1.w, ZERO.x; # Clamp to zero
  103. MIN        r0.w, r1.w, ONE.x; # clamp to one
  104.  
  105. MUL     r0.xyz, r0, r0.w;  # Multiply shadowing result through into output colour
  106. ADD     oT2, r0, AMBIENT;  # Add ambient term
  107.  
  108. # Texture Coordinates.
  109. # 0 - Billboard texture
  110. # 1 - Lightmap texture
  111. MOV     oT0.xy, iTexCoord1;
  112. MOV     oT1.xy, iTexCoord1;
  113.  
  114. MOV     r1.xy, iTexCoord1;
  115. ADD     r1.xy, r1, r1;
  116. ADD     r1.xy, r1, r1;
  117. ADD     r1.xy, r1, r1;
  118. MOV     oT3.xy, r1;
  119.  
  120. DP4     r1.x, iPos, WORLD[0];
  121. DP4     r1.y, iPos, WORLD[1];
  122. DP4     r1.z, iPos, WORLD[2];
  123. DP4     r1.w, iPos, WORLD[3];
  124.  
  125. # Calculate V
  126. SUB     r1, EYE_POSITION, r1;            # V = eye - position
  127. DP3     r1.w, r1, r1;            # Normalize V.
  128. RSQ     r1.w, r1.w;                            
  129. MUL     r1, r1, r1.w;
  130.  
  131. # Angle (theta) between sun direction (L) and view direction (V).
  132. DP3     r0.x, r1, SUN_DIRECTION;       # r0.x = [cos(theta)] = V.L
  133. MAD     r0.y, r0.x, r0.x, CONSTANTS.x;    # r0.y = [1+cos^2(theta)] = Phase1(theta)
  134.  
  135.  
  136. # Distance (s)
  137. DP4     r1.x, iPos, WORLD_VIEW[0]; # r1.z = s
  138. DP4     r1.y, iPos, WORLD_VIEW[1];
  139. DP4     r1.z, iPos, WORLD_VIEW[2];
  140. DP4     r1.w, iPos, WORLD_VIEW[3];
  141. MOV     r0.z, r1.z;                            # store in r0.z for future use.
  142.  
  143. # Terms used in the scattering equation.
  144. # r0 = [cos(theta), 1+cos^2(theta), s] 
  145.  
  146. # Extinction term E
  147. MUL     r1, BETA_1_PLUS_2, -r0.z;       # -(beta_1+beta_2) * s
  148. MUL     r1, r1, CONSTANTS.y;           # -(beta_1+beta_2) * s * log_2 e
  149. EX2     r1.x, r1.x;                    
  150. EX2     r1.y, r1.y;                    
  151. EX2     r1.z, r1.z;                          # r1 = e^(-(beta_1 + beta_2) * s) = E1
  152.  
  153. # Apply Reflectance to E to get total net effective E
  154. MUL     r3, r1, TERRAIN_REFLECTANCE;   #r3 = E (Total extinction) 
  155.  
  156. # Phase2(theta) = (1-g^2)/(1+g-2g*cos(theta))^(3/2)
  157. # theta is 180 - actual theta (this corrects for sign)
  158. # HG = [1-g^2, 1+g, 2g]
  159. MAD     r4.x, HG.z, r0.x, HG.y;# 
  160.  
  161. RSQ     r4.x, r4.x;
  162. MUL     r4.y, r4.x, r4.x;
  163. MUL     r4.x, r4.y, r4.x;
  164. MUL     r0.w, r4.x, HG.x;              # r0.w = Phase2(theta)
  165.  
  166.  
  167. # Inscattering (I) = (Beta'_1 * Phase_1(theta) + Beta'_2 * Phase_2(theta)) * 
  168. #        [1-exp(-Beta_1*s).exp(-Beta_2*s)] / (Beta_1 + Beta_2)
  169.  
  170. MUL     r4, BETA_DASH_1, r0.y;
  171. MUL     r5, BETA_DASH_2, r0.w;
  172. SUB     r6, CONSTANTS.x, r1;
  173. MOV     r7, BETA_1_PLUS_2;
  174.  
  175. ADD     r4, r4, r5;
  176. MUL     r4, r4, r6;
  177. MUL     r4, r4, ONE_OVER_BETA_1_PLUS_2;    # r4 = I (inscattering)
  178.  
  179.  
  180. # Apply Inscattering contribution factors.
  181.  
  182. MUL     r4, r4, TERM_MULTIPLIERS.y;
  183.  
  184. # Scale with Sun color & intesity.
  185. MUL     r4, r4, SUN_COLOR;
  186. MUL     r4, r4, SUN_COLOR.w;
  187.  
  188. MUL     r3, r3, SUN_COLOR;
  189. MUL     r3, r3, SUN_COLOR.w;
  190.  
  191. # Outputs.
  192. MOV     oD0, r3;                             # Extinction
  193. MOV     oD1, r4;                      # Inscattering
  194.  
  195. END
  196.  
  197.