home *** CD-ROM | disk | FTP | other *** search
/ Personal Computer World 1995 January / pcw-0195.iso / polyray / dat / person / person.inc < prev    next >
Text File  |  1994-12-31  |  5KB  |  185 lines
  1. // A person created with CSG.
  2. // Created by Will Wagner.
  3. // Thanks to Alexander Enzmann and Ken Boyce for their help.
  4.  
  5. include "rots.inc"
  6.  
  7. define head                //origin: top of neck
  8. object {
  9.     object{sphere<0,-0.15,0.5>,1}+
  10.     (object{cylinder<0,-0.15,-1.5>,<0,-0.15,0.5>,1}*
  11.     object{sphere<0,-1.025,0.5>,1.375})
  12.     head_rotation
  13.     translate<0,-0.45,1.5>
  14.     }
  15. define neck                //origin: base of neck
  16. object {
  17.     head+
  18.     object{sphere<0,0,0>,0.575}+
  19.     object{cylinder<0,0,0>,<0,-0.45,1.5>,0.575}+
  20.     object{sphere<0,-0.45,1.5>,0.675}
  21.     scale <0.85,1,1>
  22.     neck_rotation
  23.     translate<0,0.3,2.6>
  24.     }
  25. define r_fingers            //origin: palm/knuckles
  26. object {
  27.     object{cone<0,0,0>,0.15,<0,0,-0.65>,0.1 scale<1,3,1>}
  28.     right_finger_rotation
  29.     translate <0,0,-0.8>
  30.     }
  31. define l_fingers            //origin: palm/knuckles
  32. object {
  33.     object{cone<0,0,0>,0.15,<0,0,-0.65>,0.1 scale<1,3,1>}
  34.     left_finger_rotation
  35.     translate <0,0,-0.8>
  36.     }
  37. define r_hand                //origin: wrist
  38. object {
  39.     r_fingers+
  40.     object{cone<0,0,0>,0.075,<0,0,-0.25>,0.15 scale<1,3,1>}+
  41.     object{cylinder<0,0,-0.25>,<0,0,-0.8>,0.15 scale<1,3,1>}+
  42.     object{sphere<0,0,-0.8>,0.15 scale<1,3,1>}
  43.     right_hand_rotation
  44.     translate<0,0,-2.25>
  45.     }
  46. define l_hand                //origin: wrist
  47. object {
  48.     l_fingers+
  49.     object{cone<0,0,0>,0.075,<0,0,-0.25>,0.15 scale<1,3,1>}+
  50.     object{cylinder<0,0,-0.25>,<0,0,-0.8>,0.15 scale<1,3,1>}+
  51.     object{sphere<0,0,-0.8>,0.15 scale<1,3,1>}
  52.     left_hand_rotation
  53.     translate<0,0,-2.25>
  54.     }
  55. define r_lower_arm            //origin: elbow
  56. object {
  57.     r_hand+
  58.     object{sphere<0,0,0>,0.5}+
  59.     object{cone<0,0,0>,0.45,<0,0,-2.25>,0.2}+
  60.     object{sphere<0,0,-2.25>,0.2}
  61.     right_lower_rotation
  62.     translate<0,0,-2.575>
  63.     }
  64. define l_lower_arm            //origin: elbow
  65. object {
  66.     l_hand+
  67.     object{sphere<0,0,0>,0.5}+
  68.     object{cone<0,0,0>,0.45,<0,0,-2.25>,0.2}+
  69.     object{sphere<0,0,-2.25>,0.2}
  70.     left_lower_rotation
  71.     translate<0,0,-2.575>
  72.     }
  73. define r_upper_arm            //origin: shoulder
  74. object {
  75.     r_lower_arm+
  76.     object{sphere<0,0,0>,0.55}+
  77.     object{cone<0,0,0>,0.55,<0,0,-2.575>,0.5}
  78.     scale <0.925,1,1>
  79.     right_upper_rotation
  80.     translate<2.35,0,2.25>
  81.     }
  82. define l_upper_arm            //origin: shoulder
  83. object {
  84.     l_lower_arm+
  85.     object{sphere<0,0,0>,0.55}+
  86.     object{cone<0,0,0>,0.55,<0,0,-2.575>,0.5}
  87.     scale <0.925,1,1>
  88.     left_upper_rotation
  89.     translate<-2.35,0,2.25>
  90.     }
  91. define torso                //origin: lower back
  92. object {
  93.     neck+
  94.     r_upper_arm+
  95.     l_upper_arm+
  96.     object{sphere<0,0,2>,1.2 scale<1.665,1,1>}+
  97.     object{cylinder<0,0,2>,<0,0,1.75>,1.2 scale<1.665,1,1>}+
  98.     object{parabola<0,0,-1>,<0,0,1.75>,1.2 scale<1.665,1,1>}
  99.     torso_rotation
  100.     }
  101. define r_foot                //origin: ankle
  102. object {
  103.     object{sphere<0,0,0>,0.4}+
  104.     object{sphere<0,0.45,-0.5>,0.4}+
  105.     object{polygon 4,<0.35,0.6,-0.6>,<-0.35,0.6,-0.6>,<-0.6,-2.25,-0.9>,
  106.         <0.6,-2.25,-0.9>}+
  107.     object{polygon 4,<-0.6,-2.25,-0.8>,<0.6,-2.25,-0.8>,<0.1,0,0>,
  108.         <-0.1,0,0>}+
  109.     object{polygon 4,<-0.35,0.6,-0.6>,<-0.6,-2.25,-0.9>,<-0.6,-2.25,-0.8>,
  110.         <-0.1,0,0>}+
  111.     object{polygon 4,<0.35,0.6,-0.6>,<0.6,-2.25,-0.9>,<0.6,-2.25,-0.8>,
  112.         <0.1,0,0>}+
  113.     object{polygon 4,<0.1,0,0>,<-0.1,0,0>,<-0.35,0.6,-0.6>,<0.35,0.6,-0.6>}+
  114.     object{polygon 4,<-0.6,-2.25,-0.9>,<-0.6,-2.25,-0.8>,<0.6,-2.25,-0.8>,
  115.         <0.6,-2.25,-0.9>}
  116.     right_foot_rotation
  117.     translate<0,0,-2.75>
  118.     }
  119. define l_foot                //origin: ankle
  120. object {
  121.     object{sphere<0,0,0>,0.4}+
  122.     object{sphere<0,0.45,-0.5>,0.4}+
  123.     object{polygon 4,<0.35,0.6,-0.6>,<-0.35,0.6,-0.6>,<-0.6,-2.25,-0.9>,
  124.         <0.6,-2.25,-0.9>}+
  125.     object{polygon 4,<-0.6,-2.25,-0.8>,<0.6,-2.25,-0.8>,<0.1,0,0>,
  126.         <-0.1,0,0>}+
  127.     object{polygon 4,<-0.35,0.6,-0.6>,<-0.6,-2.25,-0.9>,<-0.6,-2.25,-0.8>,
  128.         <-0.1,0,0>}+
  129.     object{polygon 4,<0.35,0.6,-0.6>,<0.6,-2.25,-0.9>,<0.6,-2.25,-0.8>,
  130.         <0.1,0,0>}+
  131.     object{polygon 4,<0.1,0,0>,<-0.1,0,0>,<-0.35,0.6,-0.6>,<0.35,0.6,-0.6>}+
  132.     object{polygon 4,<-0.6,-2.25,-0.9>,<-0.6,-2.25,-0.8>,<0.6,-2.25,-0.8>,
  133.         <0.6,-2.25,-0.9>}
  134.     left_foot_rotation
  135.     translate<0,0,-2.75>
  136.     }
  137. define r_calf                //origin: knee
  138. object {
  139.     r_foot+
  140.     object{sphere<0,0,0>,0.8}+
  141.     object{cone<0,0,0>,0.75,<0,0,-2.75>,0.4}
  142.     right_calf_rotation
  143.     translate<0,0,-2.75>
  144.     }
  145. define l_calf                //origin: knee
  146. object {
  147.     l_foot+
  148.     object{sphere<0,0,0>,0.8}+
  149.     object{cone<0,0,0>,0.75,<0,0,-2.75>,0.4}
  150.     left_calf_rotation
  151.     translate<0,0,-2.75>
  152.     }
  153. define r_thigh                //origin: hip
  154. object {
  155.     r_calf+
  156.     object{sphere<0,0,0>,0.825}+
  157.     object{cylinder<0,0,0>,<0,0,-2.75>,0.8}
  158.     scale <0.925,1,1>
  159.     right_thigh_rotation
  160.     translate<0.9,0,-0.25>
  161.     }
  162. define l_thigh                //origin: hip
  163. object {
  164.     l_calf+
  165.     object{sphere<0,0,0>,0.825}+
  166.     object{cylinder<0,0,0>,<0,0,-2.75>,0.8}
  167.     scale <0.925,1,1>
  168.     left_thigh_rotation
  169.     translate<-0.9,0,-0.25>
  170.     }
  171. define abdomen                //origin: center of hips
  172. object {
  173.     r_thigh+
  174.     l_thigh+
  175.     object {lathe 2,<0,1,0>,6,<0,1,0>,<0.5,1,0>,<1,0.75,0>,<1,0,0>,
  176.         <0.25,-1,0>,<0,-1,0> rotate<90,0,0> root_solver Sturm
  177.         scale<1.665,1,1>}
  178.     abdomen_rotation
  179.     translate<0,0,-1.75>
  180.     }
  181. define person
  182. object {
  183.     torso+
  184.     abdomen
  185.     }