home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #7 / amigamamagazinepolishissue1998.iso / varia / povray3 / povray3_fpu / pov3demo / surfaces / warp1.pov < prev    next >
Text File  |  1997-12-12  |  2KB  |  73 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // Texture warp example
  3.  
  4. #version 3
  5. global_settings { assumed_gamma 2.2 }
  6.  
  7. #include "colors.inc"
  8.  
  9. camera { 
  10.   location <0,3,-31>
  11.   direction 3*z
  12. } 
  13.  
  14. plane {  y,-1.01  pigment {checker Yellow,White}}
  15.  
  16. plane {  z, 4.01  pigment {checker Yellow,White}}
  17.  
  18. light_source { <300, 500, -500> color Gray65}
  19. light_source { <-50,  10, -500> color Gray65}
  20.  
  21. #declare Thing = plane{z,0.1 clipped_by{box{-2,2}}}
  22. #declare Test = pigment{image_map{gif "test.gif"} translate -1/2 scale 4}
  23.  
  24. object{Thing
  25.   pigment { Test
  26.  
  27. //This is the traditional non-warp turbulence in the X direction only
  28.     turbulence 0.4*x octaves 2  
  29.  
  30. // followed by a rotate left 90 degrees.  The result is a rotated image
  31. // with the turbulence rotated with it as see in the upper left
  32.     rotate 90*z
  33.   }
  34.   translate <-3,5.5,0>
  35. }
  36.  
  37. object{Thing
  38.   pigment { Test
  39. // Here we rotate first, then do X turbulence.  However the upper
  40. //  right image shows that traditional POV-Ray syntax always transforms
  41. //  the turbulence with the pattern, regardless of the order specified.
  42.  
  43.     rotate 90*z
  44.     turbulence 0.4*x octaves 2
  45.   }
  46.   translate <3,5.5,0>
  47. }
  48.  
  49. object{Thing
  50.   pigment { Test
  51. // Here we do the rotation first
  52.     rotate 90*z
  53.  
  54. // and then do the turbulence in a new warp statement.  The results in the 
  55. // lower left are what we wanted all along.
  56.     warp{turbulence 0.4*x octaves 2}
  57.   }
  58.   translate <-3,1,0>
  59. }
  60.  
  61. object{Thing
  62.   pigment { Test
  63. // This lower right image shows that putting the warp statement first,
  64. //  reverses the order and behaves the same as the upper images.
  65. //  The turbulence is rotated with the pattern.  The results are slightly
  66. //  different than the upper images.  That is because here, the turb happens
  67. //  after the transformations that are inside the declared Test pigment.
  68.     warp{turbulence 0.4*x octaves 2}
  69.     rotate 90*z
  70.   }
  71.   translate <3,1,0>
  72. }
  73.