home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #7 / amigamamagazinepolishissue1998.iso / varia / povray3 / povray3_fpu / pov3demo / showoff / sombrero.pov < prev    next >
Text File  |  1997-12-12  |  2KB  |  84 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // File: Sombrero.POV
  3. // Vers: 3
  4. // Desc: Create the famous Sinusoidal rippled surface,
  5. //       using a 3-D sheet of spheres.
  6. //       Shows off the use of the while loop for creating a surface,
  7. //       and for smoothly changing colors.
  8. // Date: 10/1/95
  9. // Auth: Eduard Schwan
  10.  
  11.  
  12. #version 3.0
  13. global_settings { assumed_gamma 1.0 }
  14.  
  15. // ------------------------------------------------------------------
  16. // Look down at an angle at our creation
  17. camera
  18. { 
  19.   location  <0,1.5,-2>
  20.   direction 1*z
  21.   look_at   <0,-0.2,0>
  22. } 
  23.  
  24.  
  25. // ------------------------------------------------------------------
  26. // Simple background for a simple scene
  27. background { color rgb <0.9, 0.8, 0.7> }
  28.  
  29.  
  30. // ------------------------------------------------------------------
  31. // A light source
  32. light_source { <20, 20, -10> colour 1 }
  33.  
  34.  
  35. // ------------------------------------------------------------------
  36. // create a simple shape to use as a dot
  37. #declare BasicShape = sphere {  0, 1 }
  38.  
  39.  
  40. // ------------------------------------------------------------------
  41. // Set up the loop variables:
  42. // the Xc & Zc variables will go from -1.0 to +1.0
  43. // in NumIterations loops.
  44. #declare NumIterations = 8 // try 6 to 16
  45. #declare Increment     = 1.0/(NumIterations*2)
  46.  
  47.  
  48. // ------------------------------------------------------------------
  49. // Create a surface built from our basic shape
  50. // Zc goes from -1 to +1
  51. #declare Zc = -1.0
  52. #while (Zc<=1.0)
  53.   union
  54.   {
  55.  
  56.   // Xc goes from -1 to +1
  57.   #declare Xc = -1.0
  58.   #while (Xc<=1.0)
  59.     // precalculate height, since it is used several places below
  60.     #declare YHeight = sin(sqrt(Xc*Xc+Zc*Zc)*6.28*2)
  61.     object
  62.     {
  63.       BasicShape scale Increment
  64.       translate <Xc, YHeight/4, Zc>
  65.       texture
  66.       {
  67.         // colors change across the object, and also go from black
  68.         // in the valleys to full saturation at the peaks
  69.         pigment { color rgb <Xc/2+1, 1-Zc/2, YHeight/2+1>*YHeight }
  70.         finish { ambient 0.2 specular 0.5 roughness 0.05 reflection 0.2 }
  71.       }
  72.     }
  73.     // manually increment our counter inside the loop
  74.     #declare Xc=Xc+Increment
  75.   #end
  76.   }
  77.  
  78.   // manually increment our counters inside the loop
  79.   #declare Zc=Zc+Increment
  80.  
  81. #end
  82.  
  83.  
  84.