home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #7 / amigamamagazinepolishissue1998.iso / varia / povray3 / povray3_fpu / pov3demo / camera / focalb1.pov < prev   
Text File  |  1997-12-12  |  2KB  |  88 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // Focal blur camera example
  3. // File by Dan Farmer
  4.  
  5. #version 3.0
  6. global_settings { assumed_gamma 2.2 }
  7.  
  8. #include "colors.inc"
  9. #include "shapes.inc"
  10.  
  11. #declare FB_Quality_Off  = 0
  12. #declare FB_Quality_Fast = 1
  13. #declare FB_Quality_Default = 2
  14. #declare FB_Quality_High = 3
  15.  
  16. #declare FB_Quality= FB_Quality_High
  17.  
  18. camera {
  19.    location <2, 2, -11 >
  20.    up y
  21.    right <1.3333, 0, 0>
  22.    direction z
  23.    angle 37
  24.    look_at <-1.75,0,0>
  25.  
  26.    aperture 2
  27.    focal_point <0, 0, 0>
  28.  
  29. #switch(FB_Quality)
  30. #case(FB_Quality_Off)
  31.    aperture 0
  32.    #warning "\nNo focal blur used...\n"
  33.    #break
  34. #case (FB_Quality_Fast)
  35.    blur_samples 7
  36.    confidence 0.5             // default is 0.9
  37.    variance 1/64              // default is 1/128 (0.0078125)
  38.    #warning "\nFast focal blur used...\n"
  39.    #break
  40. #case(FB_Quality_Default)
  41.    blur_samples 19
  42.    confidence 0.90            // default is 0.9
  43.    variance 1/128             // default is 1/128 (0.0078125)
  44.    #warning "\nDefault focal blur used...\n"
  45.    #break
  46. #case(FB_Quality_High)
  47.    blur_samples 37
  48.    confidence 0.975           // default is 0.9
  49.    variance 1/255             // default is 1/128 (0.0078125)
  50.    #warning "\nHigh Quality focal blur used...\n"
  51.    #break
  52. #else
  53.    #warning "\nError! Switch condition skipped!...\n"
  54. #end
  55. }
  56.  
  57. background { color Black }
  58.  
  59. light_source { <30, 60, -100> color White }
  60.  
  61.  
  62. #declare Obj = cylinder { -y*2, y*2, 0.2 }
  63. union {
  64.     object { Obj pigment{ Blue   } translate <-1,0,-8>}
  65.     object { Obj pigment{ Green  } translate <-1,0,-6>}
  66.     object { Obj pigment{ Yellow } translate <-1,0,-4>}
  67.     object { Obj pigment{ Orange } translate <-1,0,-2>}
  68.     object { Obj pigment{ Red    } translate <-1,0, 0>}
  69.     object { Obj pigment{ Orange } translate <-1,0, 2>}
  70.     object { Obj pigment{ Yellow } translate <-1,0, 4>}
  71.     object { Obj pigment{ Green  } translate <-1,0, 6>}
  72.     object { Obj pigment{ Blue   } translate <-1,0, 8>}
  73.     translate y*1
  74.     texture {
  75.         finish { specular 0.75 roughness 0.005 metallic }
  76.     }
  77. }
  78. plane { y, 0 pigment { checker White, Gray90 }  scale 2}
  79.  
  80.  
  81.  
  82.  
  83.  
  84.  
  85.  
  86.  
  87.  
  88.