home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #7 / amigamamagazinepolishissue1998.iso / varia / povray3 / povray3_060 / pov3demo / other / crat_dat.pov < prev    next >
Text File  |  1997-12-12  |  984b  |  46 lines
  1. // Persistence Of Vision raytracer version 3.0 sample file.
  2. // Render this file to create CRAT_DAT.TGA and then render CRATER.POV
  3. // Use special 16-bit gray output
  4.  
  5. #version 3.0
  6. global_settings { assumed_gamma 2.2 hf_gray_16 }
  7.  
  8. #include "colors.inc"
  9.  
  10. // a wrinkle colored plane
  11.  
  12. plane {z,10 
  13.  pigment{wrinkles
  14.   color_map{
  15.    [0 White*0.3]
  16.    [1 White]
  17.   }
  18.  }
  19. }
  20.  
  21. // Main spotlight creates crater mountain
  22. light_source {0 color 1  spotlight point_at z*10
  23.   radius 7 falloff 11
  24. }
  25.  
  26. // Dim spotlight softens outer edges further
  27. light_source {0 color .25  spotlight point_at z*10
  28.   radius 2 falloff 15
  29. }
  30.  
  31. // Narrow spotlight creates central peak
  32. light_source {0 color .1  spotlight point_at z*10
  33.   radius 0 falloff 1.3
  34. }
  35.  
  36. // Negative spotlight cuts out crater insides
  37. light_source {0 color -0.9  spotlight point_at z*10
  38.   radius 5 falloff 9.5
  39. }
  40.  
  41. // Dim negative spotlight counteracts dim positive light in center
  42. light_source {0 color -.25  spotlight point_at z*10
  43.   radius 3 falloff 8
  44. }
  45.  
  46.