Amiga MA Magazine 1998 #3/amigamamagazinepolishissue1998.iso/wfmh_localepl_1.53/instaluj_localepl

Text File | 1998-02-03 | 25KB | 966 lines

;
;             LocalePL © 1994-1998 Marcin Orlowski
;
;        ---------------------------------------------------------
;
;        ###    ###    #########  ###    ###    ###    ###
;        ###    ###    ###        ####  ####    ###    ###
;        ###    ###    ###        ### ## ###    ###    ###
;        ###    ###    ########   ### ## ###    ##########
;        ### ## ###    ########   ###    ###    ##########
;        ### ## ###    ###        ###    ###    ###    ###
;        ####  #### ## ###     ## ###    ### ## ###    ### ##
;        ###    ### ## ###     ## ###    ### ## ###    ### ##
;
;        ---------------------------------------------------------
;
;            Mental Pictures Developed Here
;
;                Marcin Orlowski
;                ul. Radomska 38
;                71-002 Szczecin
;
;        E-mail:         [e-mail]
;       WWW:            http://wfmh.org.pl
;
;
;
;
;
;
;--------------------------------------------------------------------
;
;                       W.F.M.H. LocalePL Installer
;
;--------------------------------------------------------------------
;
;     $VER: WFMH LocalePL v1.53 (01.01.95) - Skrypt instalacyjny
;

(set WedgeHelp
    (cat    "  Pare slow na temat programu AssignWedge.\n"
        "Po jego uruchomieniu, w przypadku odwolania "
        "do nieistniejacego urzadzenia, zamiast "
        "standardowego, systemowego requestera pojawi "
        "sie okno zawierajace dodatkowe gadgety dzieki "
        "ktorym bez klopotow bedzie mozna owo urzadzenie "
        "(np: RAD, PF0) zamontowac, lub przypisac mu dowolny "
        "katalog (Assign). Kompletne archiwum z tym programem, "
        "oryginalna dokumentacja, oraz tekstem zrodlowym "
        "znajduje sie na tym dysku, w katalogu \"Archiwum\".\n"
        "  UWAGA! Podczas instalacji skopiowany zostanie "
        "jedynie program glowny, archiwum pozostanie "
        "na dysku!\n\n"
        "Konwerter tekstu PrintIt 1.1.\n"
        "Poniewaz do programu dolaczona jest instrukcja "
        "obslugi zatem od razu odsylam do niej."

    )
)

(set LSortHelp
  (cat  "\n  LSort to program sortujacy pliki tekstowe "
        "z wykorzystaniem funkcji systemu operacyjnego, "
        "konkretnie locale.library, co pozwala na poprawne "
        "sortowanie zgodnie zasadami danego jezyka.\n"
        "  LSort zainstalowany zostanie w katalogu C: "
        "Szczególowa dokumentacja znajduje sie w pliku "
        "LSORT1.0.LHA w katalogu \"Archiwum\".\n\n\n"
  )
)


(set @abort-button "Przerwij Instalacje")

(set OS_Version (/ (getversion "LIBS:locale.library") 65536))
(if (< OS_Version 37)
    (abort  "\n\n\nAby wykorzystac pakiet W.F.M.H. LocalePL\n"
        "niezbedny jest co najmniej Kickstart 2.05!"
    )
)

(complete 0)
(welcome
    "\n"
    " ###    ###    #########  ###    ###    ###    ###\n"
    " ###    ###    ###        ####  ####    ###    ###\n"
    " ###    ###    ###        ### ## ###    ###    ###\n"
    " ###    ###    ########   ### ## ###    ##########\n"
    " ### ## ###    ########   ###    ###    ##########\n"
    " ### ## ###    ###        ###    ###    ###    ###\n"
    " ####  #### ## ###     ## ###    ### ## ###    ###\n"
    " ###    ### ## ###     ## ###    ### ## ###    ###\n"
    "\n"
    "      ------------------------------------------\n"
    "           Locale PL 1.53R SE (01.03.1998)\n"
    "      ------------------------------------------"
)

(message "\n\n\n\n\n"
         "W.F.M.H. LocalePL 1.53R SE\n"
         "----------------------------\n"
         "Edycja specjalna dla Magazynu Amiga\n01.03.1998"
)

(message "\n\n\n"
         "U W A G A !\n\n"
         "Koniecznie przeczytaj plik \"PrzeczytajMnie\"\n"
         "aby dowiedzieê sië wiëcej na temat specjalnej\n"
         "promocji pakietu WFMH LocalePL v3!"
)

(run (cat ("run >nil: c/Most PrzeczytajMnie")))

(set InstallMode
       (askchoice
          (prompt  "Instalacja:")
          (help    "\n"
                   "  W chwili obecnej instalacja pakietu na dyskietkach "
                      "nie jest przewidziana.  Wszelkie pliki nalezy zatem "
                   "skopiowac samemu albo lepiej dokupic dysk twardy.")
          (choices "na dysku twardym")
       )
)




(message "\n\n"
         "UWAGA!\n"
         "--------\n"
         "Jezeli posiadasz na dysku czcionki o nazwach\n"
         "analogicznych do wystepujacych w pakiecie,\n"
         "to zalecam sporzadzenie ich kopii, gdyz\n"
         "podczas instalacji zostana zastapione przez\n"
         "czcionki z pakietu. Podobnie ma sie sprawa\n"
         "z pozostalymi plikami, jednakze tutaj\n"
         "prawdopodobienstwo jest znikome."
)

(if (= (exists "ENVARC:MagicWB" (noreq)) 1)
  (set IsMagicWB 1)
  (set IsMagicWB
      (askbool
                (prompt  "\n\n\n\n\nCzy uzywasz MagicWB?")
                (help "\n"
                      "             Tak, to moj ulubiony proszek!\n\n"
                      "   Jedyna roznica podczas instalacji pakietu\n"
                      "  dla uzytkowników MagicWB polega na skopiowaniu\n"
                      "  ikon narysowanych wlasnie na uzytek MagicWB\n"
                      "  (czyli 8 kolorow, ekran co najmniej 640x512).\n"
                      "  Jesli MagicWB nie uzywasz, zainstalowane beda\n"
                      "  klasyczne ikonki w stylu NewLook OS2.0+.\n\n")
                (choices "Tak" "Nie")
      )
  )
)

(if (< OS_Version 40)
 (
  (set LibsVersion (/ (getversion "libs:locale.library") 65536))
  (if (> LibsVersion 39)
        (if (askbool
             (prompt "\n\n\n"
                   "Wprawdzie Twoja Amiga wyposazona jest\n"
                   "w ROM z systemem wczesniejszym niz 3.1,\n"
                   "jednak masz ów system zainstalowany na dysku.\n\n"
                   "Czy chcesz zainstalowac W.F.M.H. LocalePL\n"
                   "dla systemu 3.1+?")
             (help   "\n\n\n\n"
                   " Róznica w przypadku OS3.1+ polega na uwzglednieniu\n"
                   "  zmian w katalogu systemowego programu MultiView.")
             (choices "OS3.1+" "OS2.1 - 3.0")
            )
        (set OS_Version 40)
        )
  )
 )
)


(if (= IsMagicWB 0)
    (set wynik (askoptions
                (prompt  "Czy chcesz zainstalowac:")
             (help    WedgeHelp
                      LSortHelp
                         @askoptions-help
                )
                (choices
                 " Dodatkowe polskie czcionki"
             " Program AssignWedge 1.1"
             " Konwerter tekstu PrintIt 1.1"
             " Program LSort 1.0"
             " Polskie czcionki dla MagicWB"
            )

       )
    )
    (set wynik (askoptions
                (prompt  "Czy chcesz zainstalowac:")
             (help    WedgeHelp
                      LSortHelp
                         @askoptions-help
                )
                (choices
                 " Dodatkowe polskie czcionki"
             " Program AssignWedge 1.1"
             " Konwerter tekstu PrintIt 1.1"
             " Program LSort 1.0"
            )

       )
    )
)


(set wynik2 (askoptions
        (prompt  "Czy chcesz zainstalowac polskie pliki dla:")
          (help    @askoptions-help
        )
        (choices
         " CatEdit 1.2"
         " Ced 3.5"
         " CycleToMenu 2.1"
         " DB 2.3"
         " Deft II"
         " Diavolo Backup"
         " FlexCat 1.3"
         " Most 1.56"
         " MUI-Builder 1.1"
         " New Mode 3.3"
         " ReOrg 3.11"
         " ReqTools 2.2c"
         " SnoopDos 3.0"
         " ToolsDaemon 2.1"
        )

   )
)



;(if (bitand Wynik2 1024)
; (set MUIBType
;       (askchoice
;          (prompt  "Jakiej wersji programu MUI-Builder uzywasz?")
;          (help    "\n\n\n\n\n"
;                   "      Zaleznie od Twego wyboru skopiowany zostanie\n"
;                   "             odpowiedni plik z tlumaczeniem.")
;          (choices "MUI-Builder 1.1"
;                   "MUI-Builder 2.0")
;       )
; )
;)


;********************


;                                       no to jadziem...
(copyfiles
    (source "Commodore/Fonts")
    (dest "FONTS:")
    (fonts)
    (all)
)
(complete 15)

(copyfiles
    (source "Commodore/WBStartup")
    (dest "SYS:WBStartup")
    (infos)
    (all)
)
(complete 25)

(copyfiles
       (source "Commodore/Keymaps")
       (dest "KEYMAPS:")
       (all)
)
(complete 30)


;                         I tu jest pies pogrzebany....
(copyfiles
    (source "Commodore/Locale")
    (dest "LOCALE:")
    (infos)
    (all)
)
(complete 50)


;                                       Poprawki dla 3.1
(if (< OS_Version 40)
  (
    (run "c/delete >NIL: LOCALE:Catalogs/Polski/Sys/utilities.catalog force")
    (run "c/rename >NIL: LOCALE:Catalogs/Polski/Sys/utilities3.0.catalog LOCALE:Catalogs/Polski/Sys/utilities.catalog")
  )
    (run "c/delete >NIL: LOCALE:Catalogs/Polski/Sys/utilities3.0.catalog force")
)



;                        Dodatkowe polskie fonty
(if (bitand wynik 1)
  (copyfiles
       (source "Dodatki/Fonts")
       (dest "FONTS:")
        (fonts)
     (all)
  )
)
(complete 55)


;****************************************************************


;                        CatEdit
(if (bitand Wynik2 1)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "catedit#?")
  )
)

;                        CygnusEd
(if (bitand Wynik2 2)
  (if (exists "Dodatki/Locale/catalogs/Polski/ced.catalog" (noreq))
    (copyfiles
       (source "Dodatki/Locale/catalogs/Polski/")
       (dest "Locale:catalogs/polski/")
       (pattern "#?ced#?")
    )
    (message "\n\n\n\n"
             "CygnusEditor 3.5\n"
             "dostepny jest tylko dla\n"
             "zarejestrowanych uzytkownikow.\n\n"
             "Zarejestruj sie wiec!"
    )
  )
)

;                        CycleToMenu
(if (bitand Wynik2 4)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "cycletomenu#?")
  )
)

;                        DB
(if (bitand Wynik2 8)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "db#?")
  )
)

;                        Deft
(if (bitand Wynik2 16)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "deft#?")
  )
)

;                        DiavoloBackup
(if (bitand Wynik2 32)
  (if (exists "Dodatki/Locale/catalogs/Polski/diavolo.catalog" (noreq))
    (copyfiles
          (source "Dodatki/Locale/catalogs/Polski/")
          (dest "Locale:catalogs/polski/")
          (pattern "diavolo#?")
    )
    (message "\n\n\n\n"
             "Diavolo Backup\n"
             "dostepny jest tylko dla\n"
             "zarejestrowanych uzytkownikow.\n\n"
             "Zarejestruj sie wiec!"
    )
  )
)

;                        FlexCat
(if (bitand Wynik2 64)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "FlexCat#?")
  )
)

;                        Most
(if (bitand Wynik2 128)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "most#?")
  )
)

;                        MUIBuilder ***
(if (bitand Wynik2 256)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "muibuilder#?")
  )
)

;                        New Mode
(if (bitand Wynik2 512)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "newmode#?")
  )
)

;                        ReOrg
(if (bitand Wynik2 1024)
  (if (exists "Dodatki/Locale/catalogs/Polski/ReOrg.catalog" (noreq))
    (copyfiles
          (source "Dodatki/Locale/catalogs/Polski/")
          (dest "Locale:catalogs/polski/")
          (pattern "ReOrg#?")
    )
    (message "\n\n\n\n"
             "ReOrg 3.11\n"
             "dostepny jest tylko dla\n"
             "zarejestrowanych uzytkownikow.\n\n"
             "Zarejestruj sie wiec!"
    )
  )
)

;                        ReqTools
(if (bitand Wynik2 2048)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "reqtools#?")
  )
)

;                                       SnoopDos
(if (bitand Wynik2 4096)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski/")
    (pattern "snoopdos#?")
  )
)


;                        ToolsDaemon
(if (bitand Wynik2 8192)
  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/polski")
    (pattern "tools#?")
  )
)


;********************************************


;                        AssignWedge
(if (bitand Wynik 2)
 (
  (copyfiles
    (source "Dodatki/Programy/AssignWedge/AssignWedge")
    (dest "SYS:WBStartup")
    (infos)
  )

  (copyfiles
    (source "Dodatki/Locale/catalogs/Polski/")
    (dest "Locale:catalogs/Polski/")
    (pattern "AssignWedge#?")
  )
 )
)
(complete 60)

;                        Fonty do MagicWB
(if (OR (AND (= IsMagicWB 0) (bitand Wynik 16)) (= IsMagicWB 1))
  (copyfiles
    (source "MagicWB/Fonts")
    (dest "FONTS:")
        (fonts)
    (all)
  )
)
(complete 65)

;                                       LSort
(if (bitand Wynik 8)
  (copyfiles
  (source "Dodatki/Programy/LSort/LSort")
  (dest "C:")
  )
)

;                        PrintIt
(if (bitand Wynik 4)
 (
  (set PrintIt_dest
       (tackon
        (askdir
            (default @default-dest)
            (prompt  "Gdzie zyczysz sobie zainstalowac PrintIt?")
            (help    "Z wyswietlonej listy wybierz urzadzenie lub katalog, "
                 "w ktorym chcialbys zainstalowac PrintIt v1.1. "
                 "Program instalacyjny zalozy dodatkowy katalog "
                 "o nazwie PrintIt i w nim umiesci co trzeba.\n\n"
                 @askdir-help
                        )
                )
        "PrintIt"
        )
  )

 (makedir PrintIt_dest (infos))

  (copyfiles
    (source "Dodatki/Programy/PrintIt")
    (dest PrintIt_dest)
    (infos)
    (all)
  )
 )
)
(complete 70)


;                        Poczytaj mi Mamo...
(set DOC_Type
     (askoptions
          (prompt  "Co chcesz poczytac?")
             (help    "\n\n              Wybor nalezy do Ciebie...\n\n"
                 @askoptions-help
                )
           (choices
                " Zwykle pliki tekstowe"
            " Dokument AmigaGuide"
        )

       )
)

(if (> DOC_Type 0)
 (
  (

  (set Dok_dest
     (tackon
        (askdir
            (default @default-dest)
            (prompt  "Gdzie zyczysz sobie zainstalowac zalaczona\n"
                                 "dokumentacje do pakietu W.F.M.H. LocalePL?")
            (help   "\n\n\n"
                    " Z wyswietlonej listy wybierz urzadzenie lub katalog "
                    " w ktorym chcialbys zainstalowac dokumentacje. "
                    " Program instalacyjny zalozy katalog \"LocalePL\" "
                    " a w nim podkatalogi, zaleznie \"Dokumentacja\" "
                    " oraz \"AmigaGuide\" w nim umiesci cala dokumentacje\n\n"
                        "Nie zapomnij jej potem przeczytac!"
                        "\n\n\n\n"
                        @askdir-help
                        )
                )
        "LocalePL"
    )
  )

  (makedir Dok_dest (infos))

  (if (bitand DOC_Type 1)
   (
    (makedir (tackon Dok_dest "Dokumentacja") (infos))
    (copyfiles
          (source "Dokumentacja")
          (dest (tackon Dok_dest "Dokumentacja"))
      (infos)
          (all)
    )
   )
  )

  (if (bitand DOC_Type 2)
   (
    (makedir (tackon Dok_dest "AmigaGuide") (infos))
    (copyfiles
          (source "AmigaGuide")
      (dest (tackon Dok_dest "AmigaGuide"))
      (infos)
      (all)
    )

    (if (bitand IsMagicWB 1)
     (copyfiles
          (source "MagicWB/Icons/AmigaGuide")
      (dest (tackon Dok_dest "AmigaGuide"))
      (infos)
      (all)
     )
    )

   )
  )
 )
)
(message "\n\n\n\n\n\nNie to nie... ;-)")
)
(complete 80)



;                    Ikonki MagicWB do wszystkiego
(if (bitand IsMagicWB 1)
 (
;                                                      FontPLPatch
   (copyfiles
       (source "MagicWB/Icons/FontPLPatch.info")
       (dest "SYS:WBStartup")
   )
;                                                       Dokumentacja
  (if (bitand DOC_Type 1)
   (copyfiles
      (source "MagicWB/Icons/Dokumentacja")
          (dest (tackon Dok_dest "Dokumentacja"))
          (pattern "#?.doc.info")
   )
  )
;                                                       AmigaGuide
  (if (bitand DOC_Type 2)
   (copyfiles
      (source "MagicWB/Icons/AmigaGuide")
          (dest (tackon Dok_dest "AmigaGuide"))
          (pattern "#?.doc.info")
   )
  )
;                                                       AssignWedge
   (if (bitand Wynik 2)
     (copyfiles
       (source "MagicWB/Icons")
       (dest "SYS:WBStartup")
       (pattern "AssignWedge.info")
     )
   )
;                                                       PrintIt
   (if (bitand Wynik 4)
     (copyfiles
       (source "MagicWB/Icons")
       (dest PrintIt_dest)
       (pattern "PrintIt#?")
     )
   )

 )
)
(complete 90)

;                                                       CacheFont
(set CacheHelp
  (cat   "\n  Aby operacja sie powiodla, program aktualizujacy "
         "\"MakeFontList\" powinien znajdowac sie "
         "badz w katalogu \"C:\" badz w \"C:CacheFont\" "
         "gdyz tam bedzie poszukiwany przez niniejszy "
         "skrypt instalacyjny. Jesli proba zlokalizowania "
         "programu nie powiedzie sie, bedziesz musial "
         "wskazac recznie jego lokalizacje."
  )
)

(set IsCacheFont (OR (run "c/CheckCacheFont") (= (exists "FONTS:CacheFontData" (noreq)) 2)))
(if IsCacheFont
  (if (AskBool
            (prompt "\n\nJako ze uzywasz programu CacheFont,\n"
                    "wszelkie nowe czcionki beda w pelni\n"
                    "osiagalne dopiero po aktualizacji listy\n"
                    "czcionek. Czy chcesz abym wywolal program\n"
                    "aktualizujacy ta liste, czy tez wolisz\n"
                    "zrobic to potem samodzielnie?")
           (choices "Zrob to" "Wole sama")
           (help    CacheHelp)
     )
     (if (= (exists "C:MakeFontList" (noreq)) 1)
         (
           (working "\n\n\nUaktualniam liste czcionek...")
           (run "C:MakeFontList >nil:")
         )
         (if (= (exists "C:CacheFont/MakeFontList" (noreq)) 1)
           (
              (working "\n\n\nUaktualniam liste czcionek...")
              (run "C:CacheFont/MakeFontList >nil:")
           )
           (
             (message "\n\n\n\n\n"
                    "Niestety program \"MakeFontList\" nie zostal\n"
                    "znaleziony. W tym przypadku musisz wskazac\n"
                    "recznie miejsce jego pobytu.")
             (set LastChance
                (tackon
            (askdir
                   (default "SYS:")
                     (prompt  "Wskaz katalog z programem \"MakeFontList\"")
                 (help    "\n"
                 " Z wyswietlonej listy wybierz urzadzenie lub katalog, "
                 "w ktorym znajduje sie program MakeFontList."
                 "Zostanie on wywolany w celu aktualizacji listy "
                 "istniejacych na dysku czionek."
                 "\n\n"
                 @askdir-help)
                  )
               "MakeFontList"
                )
             )
             (if (= (exists LastChance (noreq)) 1)
                 (
                  (working "\n\n\nUaktualniam liste czcionek...")
                  (run (cat LastChance " >nil:"))
                 )
             )
           )
        )
     )
  )
)

(complete 95)

(set ModKeymap
        (cat"\n\n  Nie obawiaj sie przy tym, ze twoje dotychczasowe "
                "preferencje zostana skasowane.Program instalacyjny "
                "zachowa Twoje dotychczasowe pliki preferencji, "
                "a ponadto podczas rekonfiguracji mapy klawiatury "
                "zachowa dotychczasowe ustawienie predkosci oraz "
                "przyspieszenia myszki oraz wszelkie parametry "
                "dotyczace klawiatury.")
)

(if (= 1 (askbool
    (prompt "\n\n\nCzy ustawic niezbedne parametry\n"
        "w preferencjach systemowych, tak aby\n"
        "LocalePL byly aktywne od razu po\n"
        "zainstalowaniu, czy tez wolisz zrobic to\n"
        "recznie?")
    (choices "Zrob to" "Wole sama")
    (help     "\n   Jesli wolisz miec to z glowy, to wybierz wariant "
        "\"Zrob to\" co pozwoli Ci  na zaoszczedzenie paru "
        "jakze cennych chwilek..."
        ModKeymap)

       )
      )
 (

 (set Keymap
       (askchoice
          (prompt  "Jakiej klawiatury uzywasz?")
          (help    "\n"
                   "  Zaleznie od Twego wyboru ustawiona zostanie "
                   "odpowiednia mapa klawiatury"
           ModKeymap)
          (choices "Angielskiej"
                   "Niemieckiej"
          )
       )
 )

 (if (AND (= IsMagicWB 0) (= (bitand Wynik 16) 0))
    (set prefs (askchoice
        (prompt "Ustawienie czcionek:")
          (choices "Zostaw bez zmian"
                         "TopazPropPL i TopazPL"
                )
          (help     "\n Zostaw bez zmian\n"
                         " ----------------\n\n"
                         " Nie zmienia aktualnego ustawienia czcionek...\n\n\n"
                         " Wariant 1\n"
               " ---------\n\n"
               " Proporcjonalny TopazPropPL jako czcionka "
               " ekranowa (menu) i pod ikonki, do reszty "
             " zas klasyczny TopazPL\n\n"
             " Jak widac, masz do dyspozycji jeden tylko "
             " dodatkowy wariant, a to z tego powodu, ze "
             " wyszystkie pozostale uzywaja polskich "
             " czionek z pakietu MagicWB a przeciez takich "
             " nie chciales zainstalowac...")
                )

     )
  )

 (if (OR (= IsMagicWB 1) (bitand Wynik 16))
   (set prefs (askchoice
        (prompt "Ustawienie czcionek:")
          (choices "Zostaw bez zmian"
                         "TopazPropPL i TopazPL"
               "TopazPropPL i XenPL"
               "XHelveticaPL i XenPL (1)"
               "XHelveticaPL i XenPL (2)"
               "XHelveticaPL, TopazPL i XenPL"
        )
          (help     "\n Zostaw bez zmian\n"
                         " ----------------\n\n"
                         " Nie zmienia aktualnego ustawienia czcionek...\n\n"
                         " Wariant 1\n"
               " ---------\n\n"
               " Proporcjonalny TopazPropPL jako czcionka "
               " ekranowa (menu) i pod ikonki, do reszty "
             " zas klasyczny TopazPL\n\n"
             " Wariant 2\n"
             " ---------\n\n"
             " Proporcjonalny TopazPL jako czcionka "
               " ekranowa (menu) i pod ikonki, do reszty "
             " zas XenPL. Wariant ten przeznaczony jest "
             " raczej dla uzytkownikow MagicWB.\n"
             " Moim zdaniem taki uklad jest lepszy niz...\n\n"
             " Wariant 3\n"
             " ---------\n\n"
             " ...standardowe ustawienie dla MagicWB "
             " (czyli XHelveticaPL (11) jako czcionka "
               " ekranowa (menu) i pod ikonki, do reszty "
             " zas XenPL (9)), bowiem TopazPropPL jest znacznie "
             " ladniejszy ale to kwestia gustu.\n\n"
             " Wariant 4\n"
             " ---------\n\n"
             " Jak powyzszy wariant 3 ale czcionka ekranowa "
             " ciut wieksza: XHelveticaPL (15).\n"
             " Dla niezdecydowanych pozostaje juz ostatni...\n\n"
             " Wariant 5\n"
             " ---------\n\n"
             " Pod ikonki TopazPropPL, Na ekran XHelvetica "
             " 15 punktowa, zas jako czcionka systemowa "
             " polecamy XENPL 13...\n\n\n\n\n\n\n\n\n\n\n"
             " ...do tego wszystkiego mlode ziemniaczki saute, "
             " kapustka gdzie niegdzie z groszkiem, oraz "
             " renomowane wino spoldzielni Botwina "
             " \"Janosik\" (limited edition!) z 1998 roku....\n\n"
             " Wesolych Swiat!"
        )
          )
   )
  )

       (run "SYS:Prefs/LOCALE SAVE")
       (run "SYS:Prefs/INPUT SAVE")
       (run "SYS:Prefs/FONT SAVE")


      (if ( = (exists "ENVARC:Sys/STARE_PREFERENCJE" (noreq)) 2)
       (makedir "ENVARC:Sys/STARE_PREFERENCJE")
      )

        (if (> prefs 0)
         (if (exists "ENVARC:Sys/input.prefs" (noreq))
          (copyfiles
           (source "ENVARC:Sys/input.prefs")
           (dest   "ENVARC:Sys/STARE_PREFERENCJE")
          )
         )
        )
        (if(exists "ENVARC:Sys/locale.prefs" (noreq))
         (copyfiles
          (source "ENVARC:Sys/locale.prefs")
          (dest   "ENVARC:Sys/STARE_PREFERENCJE")
         )
    )
        (if(exists "ENVARC:Sys/font.prefs" (noreq))
         (copyfiles
          (source "ENVARC:Sys/font.prefs")
          (dest   "ENVARC:Sys/STARE_PREFERENCJE")
         )
        )


        (if (> prefs 0)
          (set Env_pat "#?")
          (set Env_pat "locale.prefs")
        )

    (copyfiles
      (source (cat "Commodore/Prefs/Wariant" ("%ld" prefs)))
      (dest "ENVARC:Sys")
          (pattern Env_pat)
     )

(if (= keymap 0)
        ((run "c/ModPrefs ENVARC:Sys/input.prefs ENVARC:Sys/input.prefs AmigaPL-USA"))
        (run "c/ModPrefs ENVARC:Sys/input.prefs ENVARC:Sys/input.prefs AmigaPL-D")
)
        (run "SYS:Prefs/LOCALE ENVARC:Sys/locale.prefs USE")
        (run "SYS:Prefs/INPUT ENVARC:Sys/input.prefs USE")
        (if (> prefs 0)
         (run "SYS:Prefs/FONT ENVARC:Sys/font.prefs USE")
        )
 )
)
(complete 100)

(set sys (cat (getassign 'sys') "WBStartup\""))
(set progs "FontPLPatch")
(set koncowka ":")
(if (bitand Wynik 2)
    (
    (set progs (cat progs " i AssignWedge"))
        (set koncowka "y:")
    )
)

(if (> DOC_Type 0)
  (message "Gotowe!\n"
     "---------\n\n"
     "Teraz najlepiej \"zresetuj\" Amige, lub uruchom\n"
     "wlasnorecznie program"
     koncowka
   "\n"
     progs
     "\nz systemowego katalogu:\n\""
     sys
     "\noraz przeczytaj bardzo dokladnie zalaczona\n"
     "dokumentacje, umieszczona w katalogu:\n\""
     Dok_dest
   "\"\n\nLocalePL © 1994-1998 Marcin Orlowski"
  )
  (message "\nGotowe!\n"
     "---------\n"
     "Teraz najlepiej \"zresetuj\" Amige, lub uruchom\n"
     "wlasnorecznie program"
     koncowka
   "\n"
     progs
     "\nz systemowego katalogu:\n\""
     sys
     "\n\nPoniewaz nie chciales instalowac dokumentacji,"
   "to poczytaj sobie teraz cos innego..."
   "\n\nLocalePL © 1994-1995 Marcin Orlowski\n"
     "MR SOFT / World Federation of Mad Hackers"
  )
)

(message "\nWszelkie uwagi i sugestie na temat niniejszego\n"
     "pakietu oraz ewentualne, zauwazone bledy a takze\n"
         "oplaty licencyjne prosze przesylac na jeden\n"
         "z ponizszych adresow:\n\n"
     "W.F.M.H. LocalePL\n"
     "ul. Radomska 38\n"
     "71-002  Szczecin\n\n"
     "tel: [phone]\n\n"
     "Internet: [e-mail]\n"
     "WWW: http://amiga.com.pl"
)

(run (cat ("run >nil: c/Most Dokumentacja/LocalePL.doc")))
(exit (QUIET))