home *** CD-ROM | disk | FTP | other *** search
/ Amiga MA Magazine 1998 #3 / amigamamagazinepolishissue1998.iso / szachy / gnu / amyboard-3.2.pl2 / configure.in < prev    next >
Text File  |  1995-03-08  |  7KB  |  252 lines
  1. dnl: You can process this file with autoconf to produce a configure script.
  2. dnl: However, normally the supplied configure script will work fine.
  3.  
  4. AC_INIT(xboard.c)
  5.  
  6. PRODUCT=xboard
  7. VERSION=3.2
  8. PATCHLEVEL=2
  9.  
  10. if test -z "$CFLAGS" ; then
  11. dnl: Prevent the next macro from setting CFLAGS to -g
  12.   CFLAGS=" "
  13. fi
  14. AC_PROG_CC
  15. AC_ISC_POSIX
  16. AC_PROG_INSTALL
  17. AC_CHECK_PROGS(LEX, lex flex, lex)
  18. AC_CHECK_PROGS(RSH, remsh rsh, rsh)
  19. AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
  20. AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
  21. AC_SUBST(NROFFFLAGS)
  22. AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
  23. AC_PATH_PROGS(PERLPATH, perl)
  24.  
  25. AC_HEADER_STDC
  26. AC_HEADER_TIME
  27. AC_HEADER_SYS_WAIT
  28. AC_TYPE_SIGNAL
  29. AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
  30. AC_CHECK_HEADER(fcntl.h,
  31.   AC_DEFINE(HAVE_FCNTL_H), AC_CHECK_HEADERS(sys/fcntl.h))
  32. AC_CHECK_HEADER(sys/socket.h,
  33.   AC_DEFINE(HAVE_SYS_SOCKET_H), AC_CHECK_HEADERS(lan/socket.h))
  34. AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
  35.  
  36. AC_CHECK_FUNCS(_getpty grantpt)
  37. AC_CHECK_FUNC(gettimeofday,
  38.   AC_DEFINE(HAVE_GETTIMEOFDAY), AC_CHECK_FUNCS(ftime))
  39. AC_CHECK_FUNC(random,
  40.   AC_DEFINE(HAVE_RANDOM), AC_CHECK_FUNCS(rand48))
  41. AC_CHECK_FUNC(gethostname,
  42.   AC_DEFINE(HAVE_GETHOSTNAME), AC_CHECK_FUNCS(sysinfo))
  43. AC_CHECK_FUNC(setlocale, [],
  44.   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
  45.  
  46. AC_CHECK_LIB(seq, getpseudotty)
  47.  
  48. AC_PATH_XTRA
  49.  
  50. AC_CANONICAL_HOST
  51.  
  52. dnl: The following info is mostly gathered from GNU Emacs 19.24.  Basically,
  53. dnl: we are trying to find out whether this is a System-V derivative (in
  54. dnl: which case we must use ptys) and if so, whether there is anything
  55. dnl: strange about the way to open a pty.  Some of the work was done above
  56. dnl: by looking for _getpty, grantpt, and getpseudotty.  A few other strange
  57. dnl: properties of particular systems are also handled here.
  58.  
  59. USE_PTYS=0
  60. case "$host" in
  61.   *-*-hpux* )
  62.     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
  63.     [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
  64.     AC_DEFINE(PTY_NAME_SPRINTF,
  65.     [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
  66.     USE_PTYS=1
  67.     if test "$GCC" = yes; then
  68.       CONF_CFLAGS="-fwritable-strings"
  69.     else
  70.  
  71. dnl: Note: You might be able to build xboard even if your compiler does not
  72. dnl: support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
  73. dnl: know whether the X header files on HP-UX require it.
  74.  
  75.       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
  76.     fi
  77.  
  78. dnl: HP doesn't supply a full set of X header files and libraries.  People
  79. dnl: often have some things installed in one place and some in another. 
  80. dnl: AC_PATH_XTRA will find only one place, so we try to add all the
  81. dnl: likely ones that might be missing here.  It might be better to
  82. dnl: change AC_PATH_XTRA to try to extract this information from imake,
  83. dnl: since folks who install the missing bits often configure their
  84. dnl: imake to find them, but I don't want to delve into autoconf deeply
  85. dnl: enough to make it do that right.
  86.  
  87.     if test -d /usr/include/X11R5; then
  88.       X_CFLAGS="-I/usr/include/X11R5 $X_CFLAGS"
  89.       X_LIBS="-L/usr/lib/X11R5 -L/usr/lib/X11R4 $X_LIBS"
  90.     elif test -d /usr/include/X11R4; then
  91.       X_CFLAGS="-I/usr/include/X11R4 $X_CFLAGS"
  92.       X_LIBS="-L/usr/lib/X11R4 $X_LIBS"
  93.     fi
  94.     if test -d /MIT/X11R5/include; then
  95.       X_CFLAGS="-I/MIT/X11R5/include $X_CFLAGS"
  96.       X_LIBS="-L/MIT/X11R5/lib $X_LIBS"
  97.     elif test -d /usr/local/include/X11R5; then
  98.       X_CFLAGS="-I/usr/local/include/X11R5 $X_CFLAGS"
  99.       X_LIBS="-L/usr/local/lib/X11R5 $X_LIBS"
  100.     fi
  101.   ;;
  102.  
  103.   romp-ibm-aix* )
  104.     AC_DEFINE(IBMRTAIX, 1)
  105.     USE_PTYS=1
  106.   ;;
  107.  
  108.   i386-ibm-aix )
  109.     USE_PTYS=1
  110.     if test "$GCC" = yes; then
  111.       CONF_CFLAGS="-fwritable-strings"
  112.     fi
  113.   ;;
  114.  
  115.   *-*-aix3* | *-*-bosx* )
  116.     AC_DEFINE(PTY_INTERATION, [])
  117.     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
  118.     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
  119.     USE_PTYS=1
  120.   ;;
  121.  
  122.   *-*-cxux* )
  123.     AC_DEFINE(FIRST_PTY_LETTER, 'A')
  124.     AC_DEFINE(LAST_PTY_LETTER, 'P')
  125.     USE_PTYS=1
  126.   ;;
  127.  
  128.   *-*-uniplus* )
  129.     AC_DEFINE(UNIPLUS, 1)
  130.     USE_PTYS=1
  131.   ;;
  132.  
  133.   *-*-rtu* )
  134.     AC_DEFINE(FIRST_PTY_LETTER, 'z')
  135.     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
  136.         [sprintf (pty_name, "/dev/ttyp%x", i);])
  137.     AC_DEFINE(PTY_NAME_SPRINTF,
  138.     [sprintf (pty_name, "/dev/pty%x", i);])
  139.     AC_DEFINE(RTU, 1)
  140.   ;;
  141.  
  142.   *-*-iris* | *-*-irix3* )
  143.     AC_DEFINE(PTY_ITERATION, [])
  144.     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
  145.     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
  146.     [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
  147.     USE_PTYS=1
  148.   ;;
  149.  
  150.   *-*-irix* )
  151.     USE_PTYS=1
  152.   ;;
  153.  
  154.   *-*-sunos4* | *-*-solaris1* )
  155.  
  156. dnl: Work around a bug in the SunOS 4.x linker.  Not needed if you have 
  157. dnl:  patches 100512-02 and 100573-03 from Sun.
  158.  
  159.     if test "$GCC" = yes; then
  160.       PRE_XMULIB="-static"
  161.       POST_XMULIB="-dynamic"
  162.     else
  163.       PRE_XMULIB="-Bstatic"
  164.       POST_XMULIB="-Bdynamic"
  165.     fi
  166.   ;;
  167.  
  168.   *-*-sunos5* | *-*-solaris2* )
  169.     USE_PTYS=1
  170.  
  171. dnl: I'm not sure -lelf is needed, but it was in the old Imakefile.
  172. dnl: The other libraries should all be found by Ac_PATH_XTRA or other
  173. dnl: code above.
  174.  
  175.     X_LIBS="$X_LIBS -lelf"
  176.   ;;
  177.  
  178.   *-*-sco* )
  179.     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
  180.     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
  181.     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
  182.     USE_PTYS=1
  183.   ;;
  184.     
  185.   *-*-dynix* | *-*-ptx* )
  186.     USE_PTYS=1
  187.   ;;
  188.  
  189.   *-*-esix* )
  190.     USE_PTYS=1
  191.   ;;
  192.  
  193.   *-*-usg5-4* | *-*-sysvr4* )
  194.     USE_PTYS=1
  195.   ;;
  196.  
  197.   *-*-usg* | *-*-sysv* | *-*-aix* )
  198.     USE_PTYS=1
  199.   ;;
  200.  
  201.   vax-*-ultrix )
  202.     if test "$GCC" = yes; then
  203.       CONF_CFLAGS="-fwritable-strings"
  204.     fi
  205.   ;;
  206. esac
  207.  
  208. AC_SUBST(PRE_XMULIB)
  209. AC_SUBST(POST_XMULIB)
  210. AC_SUBST(CONF_CFLAGS)
  211. AC_SUBST(CONF_LDFLAGS)
  212.  
  213. AC_MSG_CHECKING(whether ptys or pipes should be used)
  214. AC_ARG_ENABLE(ptys, 
  215. [  --enable-ptys   Force use of pseudo-ttys to communicate with child processes
  216.   --disable-ptys  Force use of pipes to communicate with child processes],
  217. [if test "$enableval" = yes; then
  218.   USE_PTYS=1
  219.   AC_MSG_RESULT([ptys (user override)])
  220. fi
  221. if test "$enableval" = no; then
  222.   USE_PTYS=0
  223.   AC_MSG_RESULT([pipes (user override)])
  224. fi],
  225. [if test "$USE_PTYS" = 1; then
  226.   AC_MSG_RESULT(ptys)
  227. else
  228.   AC_MSG_RESULT(pipes)
  229. fi])
  230. AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
  231.  
  232. AC_ARG_ENABLE(zippy, [],
  233. [if test "$enableval" = yes; then
  234. dnl: Extra software not included in the standard xboard distribution
  235.   PATCHLEVEL="$PATCHLEVEL"-zippy
  236.   AC_DEFINE(ZIPPY, 1)
  237.   ZIPPY_O=zippy.o
  238. fi])
  239. AC_SUBST(ZIPPY_O)  
  240.  
  241. AC_DEFINE_UNQUOTED(PRODUCT, "$PRODUCT")
  242. AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
  243. AC_DEFINE_UNQUOTED(PATCHLEVEL, "$PATCHLEVEL")
  244. AC_SUBST(PRODUCT)
  245. AC_SUBST(VERSION)
  246. AC_SUBST(PATCHLEVEL)
  247.  
  248. AC_OUTPUT(Makefile comment.awk:comment.in cmail,
  249. [test -z "$CONFIG_HEADERS" || date > stamp-h
  250. chmod 755 comment.awk cmail
  251. ])
  252.