home *** CD-ROM | disk | FTP | other *** search
/ DOS/V Power Report 1999 April / VPR9904A.BIN / Wintex / Ams / jamstex.lzh / AMSFONTS / SOURCES / CYRILLIC / CYRTI.MF < prev    next >
Text File  |  1993-02-25  |  48KB  |  1,056 lines
  1. %% @metafontfile{
  2. %%     filename="cyrti.mf",
  3. %%     version="2.1",
  4. %%     date="30-MAY-1991",
  5. %%     filetype="Metafont: driver",
  6. %%     copyright="Copyright (C) Humanities and Arts Computing Center,
  7. %%            University of Washington;
  8. %%            all rights reserved.  Copying of this file is
  9. %%            authorized only if either:
  10. %%            (1) you make absolutely no changes to your copy
  11. %%                including name; OR
  12. %%            (2) if you do make changes, you first rename it to some
  13. %%                other name.",
  14. %%     author="American Mathematical Society",
  15. %%     address="American Mathematical Society,
  16. %%            Technical Support Department,
  17. %%            P. O. Box 6248,
  18. %%            Providence, RI 02940,
  19. %%            USA",
  20. %%     telephone="401-455-4080 or (in the USA) 800-321-4AMS",
  21. %%     email="Internet: Tech-Support@Math.AMS.org",
  22. %%     codetable="ISO/ASCII",
  23. %%     checksumtype="line count",
  24. %%     checksum="1056",
  25. %%     keywords="amsfonts, tex, metafont , cyrillic ",
  26. %%     abstract="This is the driver file for use with 
  27. %%            the cyrillic italic fonts in AMSFonts 2.1."
  28. %%     }
  29. %
  30. %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
  31. %cyrti.mf
  32.  
  33. cmchar "Italic Serbian letter Soft n (looks like hb)";
  34. beginchar(oct"010",6u#,x_height#,0);
  35. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  36. adjust_fit(5u#,0); pickup tiny.nib; w:=6u;
  37. pos1(stem,0); pos2(stem,0); x1=x2;
  38. lft x1l=hround(u-.5stem); top y1=h; y2=.6bar_height;
  39. filldraw stroke z1e--z2e;  % stem
  40. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  41. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  42. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  43. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-u+.5curve);
  44. bot y3r=-oo; top y5r=1.2bar_height+oo; y4=y2;
  45. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  46.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  47. x80=-5u; x82-.5stem=hround(-2u-.5stem); hook_in(80,81,82); 
  48. z83=z82; x84=x83; y84-.5stem=-oo;
  49. pos83(stem,0); pos84(stem,0); filldraw circ_stroke z84e--z83e;
  50. x85=x83; y85=y86=bar_height; x86=x0; pos85(hair,90); pos86(hair,90);
  51. filldraw stroke z85e--z86e;
  52. %y11=y1; x11=x1-4.5u; x12=x11; pos11(stem,0); x14=-.5u;
  53. %hook_out(12,13,14);
  54. %sloped_serif.l(11,12,b,1/3,jut,serif_drop);  % serif
  55. %filldraw stroke z11e--z12e;
  56. %x89=x11; y89=.75[y2,y3]; x90=x0; y90=y89; pos89(hair,90); pos90(hair,90);
  57. %filldraw stroke z89e--z90e;
  58. endchar;
  59.  
  60. cmchar "Italic Serbian letter soft l";
  61. beginchar(oct"011",12u#,x_height#,0);
  62. adjust_fit(.5u#,.5u#); pickup fine.nib; w:=9u;
  63. y1+.375stem=h; x1=.5[x3,x1']; x2=x3=3u; y3=.35h; y2=.75h;
  64. bot y4r=-oo; y1'=.8h; x1'l=w-2u;
  65. x4=.5[x6,x3]; y6-.5flare=.1h; pos6(flare,-180);
  66. pos5(hair,-180); lft x6r=-.25u; z5r=z6r;
  67. pos4(vair,-90); pos2(hair,0); pos3(hair,0); pos1(.75stem,-90); 
  68. x7=x1'; pos1'(stem,180); pos7(stem,0); 
  69. z11=z1'; pos11(stem,0); y7=.6bar_height; 
  70. bulb(4,5,6); 
  71. filldraw stroke pulled_arc.e(4,3) &  super_arc.e(3,1) & super_arc.e(1,1');
  72. filldraw stroke z11e..z7e; w:=12u;
  73. x23=x25=.5[x7,x24]; rt x24r=hround(w-u+.5curve);
  74. bot y23r=-oo; top y25r=1.2bar_height+oo; y24=y7; z7'=z7; pos7'(stem,-180);
  75. z20=z7; pos20(hair,180); pos23(vair,-90); pos24(curve,0); pos25(vair,90);
  76. filldraw stroke pulled_arc.e(7',23) & pulled_arc.e(23,24)
  77.  & pulled_arc.e(24,25) & super_arc.e(25,20);  % bowl
  78. endchar;
  79.  
  80. cmchar "Italic Serbian letter hard dj";
  81. beginchar(oct"012",9.5u#,x_height#,desc_depth#);
  82. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  83. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  84. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  85. hook_in(0,1,2)(skewed);  % opening hook
  86. pos2'(stem,-180); z2'=z2;
  87. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  88. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  89. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  90. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  91. filldraw stroke z2'e{-u,-x_height}
  92.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  93. filldraw circ_stroke z6e--z7e;  % right stem
  94. %
  95. %x31=x7; y31=-.25d; x32=x3; y32=-.8d; x33=.25[x32,x31]; y33=-d;
  96. %pos31(vair,180); pos32(slab,270); pos33(hair,360);
  97. %filldraw stroke z4e{2,-1}...{down}z31e{down}...{down}z32e...{right}z33e;
  98. x31=x7; y31=-.25d; x32=x3; y32=-.8d; x33=x32-1.5u; y33=y32+u;
  99. pos31(vair,-180); pos32(.7stem,-270); pos33(hair,-360);
  100. filldraw stroke z4e{2,-1}...z31e...{left}z32e...z33e;
  101. %
  102. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  103. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  104.  
  105. cmchar "Italic Russian letter reverse e (looks like backwards c)";
  106. beginchar(oct"013",8u#,x_height#,0);
  107. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  108. adjust_fit(0,0); pickup fine.nib;
  109. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  110. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  111. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-.25u))+eps;
  112. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  113. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  114. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  115. path p; p=z4{right}..z5..z6;
  116. filldraw stroke pulled_arc.e(2,3)
  117.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  118. x77=x4; y77=.5h; x78=2x77-x3; y78=2y77-y3;
  119. flip(77); 
  120. y79=y78; x79=x78-(x1-x3);
  121. pos78(hair,90); pos79(hair,90); 
  122. filldraw stroke z78e--z79e; 
  123. endchar;
  124.  
  125. cmchar "Italic Ukrainian letter i";
  126. beginchar(oct"014",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  127. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  128. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  129. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  130. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  131. filldraw stroke z2e--z3e;  % stem
  132. pos8(flare,0); pos9(flare,90);
  133. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  134. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  135. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  136. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  137. penlabels(0,1,2,3,4,5,8,9); endchar;
  138.  
  139. cmchar "Italic Ukrainian letter ye (looks like c with mid-line)";
  140. beginchar(oct"015",8u#,x_height#,0);
  141. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  142. adjust_fit(0,0); pickup fine.nib;
  143. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  144. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  145. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-.25u))+eps;
  146. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  147. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  148. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  149. path p; p=z4{right}..z5..z6;
  150. filldraw stroke pulled_arc.e(2,3)
  151.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  152. x78=x3; y78=y3; y79=y78; x79=x1;
  153. pos78(hair,90); pos79(hair,90); 
  154. filldraw stroke z78e--z79e; 
  155. endchar;
  156.  
  157. cmchar "Italic Serbian letter dj (looks like barred h with tail)";
  158. beginchar(oct"016",8u#,asc_height#,desc_depth#);
  159. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  160. adjust_fit(1.5u#,0); pickup tiny.nib;
  161. pos1(stem,0); pos2(stem,0); x1=x2;
  162. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  163. filldraw circ_stroke z2e--z1e;  % left stem
  164. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  165. pickup fine.nib; x4+.5stem=hround(w-.75u+.5stem);
  166. x5=x4; %x5=x4-.25u; 
  167. ital_arch(2,3,4);  % arch
  168. x7=.45[x2,x4]; bot y7r=-d; pos7(hair,-90);
  169. filldraw stroke pulled_arc.e(4,7);
  170. x98=-u; x99=x4; y98=y99=.5x_height+.5h; pos98(bar,90); pos99(bar,90);
  171. filldraw stroke z98e--z99e;
  172. %x7=w; hook_out(5,6,7)(skewed);  % closing hook
  173. %filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  174. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  175.  
  176. cmchar "Italic Serbian letter soft t (looks like barred h)";
  177. beginchar(oct"017",9u#,asc_height#,0);
  178. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  179. adjust_fit(1.5u#,0); pickup tiny.nib;
  180. pos1(stem,0); pos2(stem,0); x1=x2;
  181. lft x1l=hround(1.5u-.5stem); top y1=h; y2-.5stem=-oo;
  182. filldraw circ_stroke z2e--z1e;  % left stem
  183. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  184. pickup fine.nib; x4+.5stem=hround(w-2.5u+.5stem);
  185. x5=x4-.25u; ital_arch(2,3,4);  % arch
  186. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  187. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  188. x98=-u; x99=x4; y98=y99=.5x_height+.5h; pos98(bar,90); pos99(bar,90);
  189. filldraw stroke z98e--z99e;
  190. math_fit(0,ic#); penlabels(1,2,3,4,5,6,7); endchar;
  191.  
  192. cmchar "Italic Russian letter yu (looks like io)";
  193. beginchar(oct"030",12u#,x_height#,0);
  194. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  195. adjust_fit(0,0); pickup fine.nib;
  196. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  197. x1=x3=.5[x2,x4]; lft x2r=hround(5.5u-.5curve); x4=w-hround(1.5u-.5curve);
  198. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  199. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  200.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  201. x0=0; x22-.5stem=hround(3u-.5stem); hook_in(0,21,22); 
  202. z23=z22; x24=x23; y24-.5stem=-oo;
  203. pos23(stem,0); pos24(stem,0); filldraw circ_stroke z24e--z23e;
  204. x25=x23; y25=y26=bar_height; x26=x2; pos25(hair,90); pos26(hair,90);
  205. filldraw stroke z25e--z26e;
  206. penlabels(0,1,2,3,4,21,23,24,25,26); endchar;
  207.  
  208. cmchar "Italic Russian letter zhe";
  209. beginchar(oct"031",20u#,x_height#,0);
  210. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  211. adjust_fit(0,0); pickup fine.nib;
  212. w:=8u;
  213. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  214. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  215. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  216. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  217. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  218. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  219. path p; p=z4{right}..z5..z6;
  220. filldraw stroke pulled_arc.e(2,3)
  221.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  222. path mypath; mypath= pulled_arc.r(2,3) & pulled_arc.r(3,4);
  223. x200=0; y200=.75x_height; x201=18u; y201=y200;
  224. path newpath; newpath= z200--z201;
  225. z178r= newpath intersectionpoint mypath;
  226. x77=x4; y77=.5h; z78r=z178r rotatedaround(z77,180);
  227. x78r:=x78r-hair;
  228. flip(77); w:=20u;
  229. pos50(flare,0); pos51(hair,0); pos52(vair,90);
  230. pos53(curve,180); pos54(vair,270); pos55(hair,320);
  231. x52=x54=w-3.5u; rt x51r=max(rt x52,hround(w-u))+eps;
  232. lft x53r=hround(w-6.5u-.5curve); x55r=good.x(w-eps); x56=x55;
  233. y51=.5[bar_height,h]; top y52r=h+oo; bulb(52,51,50);  % bulb
  234. bot y54r=-oo; y53=.5[y52,y54]; top y55l=vround .5bar_height; y56=bar_height;
  235. path p; p=z54{right}..z55..z56;
  236. filldraw stroke pulled_arc.e(52,53)
  237.  & pulled_arc.e(53,54)...{direction 1 of p}z55e;  % arc
  238. path mynewpath; mynewpath= pulled_arc.r(52,53) & pulled_arc.r(53,54);
  239. x80=x81=.5[x78,x53]; y80=h-.5stem; y81=0; 
  240. z79l=mynewpath intersectionpoint newpath;
  241. pos78(hair,0); pos79(hair,0); pos80(stem,0); pos81(stem,0); 
  242. filldraw stroke z78e--z80e; filldraw circ_stroke z80e--z81e; filldraw stroke z79e--z81e;
  243. endchar;
  244.  
  245. cmchar "Italic Russian letter short i (looks like breve u)";
  246. beginchar(oct"032",9.5u#,asc_height#,0);
  247. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  248. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super; h:=x_height;
  249. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  250. hook_in(0,1,2)(skewed);  % opening hook
  251. pos2'(stem,-180); z2'=z2;
  252. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  253. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  254. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  255. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  256. filldraw stroke z2'e{-u,-x_height}
  257.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  258. filldraw circ_stroke z6e--z7e;  % right stem
  259. h:=asc_height;
  260. pickup crisp.nib; pos38_1(vair,-180); pos38_3(vair,0);
  261. top y38_1=top y38_3=y38_2r+cyrspread; lft x38_1r+.5u=lft x3r; rt x38_3r-.5u=rt x6r;
  262. numeric mid_thickness; mid_thickness=vround 1/3[vair,stem];
  263. pos38_2(mid_thickness,-90); x38_2=x4;
  264. bot y38_2r=x_height+.5dot_size;
  265. filldraw stroke z38_1e{down}...z38_2e{right}...{up}z38_3e;  % stroke
  266. %% ngb changes:
  267. if square_dots: % relax
  268. else:
  269.   pos38_11(dot_size,0); pos38_12(dot_size,90); pos38_13(dot_size,0); pos38_14(dot_size,90);
  270.   lft x38_11l=lft x38_1r; rt x38_13r=rt x38_3r; y38_11=y38_12=y38_13=y38_14=y38_2r+cyrspread;
  271.   x38_12=x38_11; x38_14=x38_13; dot(38_11,38_12); 
  272.   if altaccent: % relax
  273.   else: dot(38_13,38_14); fi
  274. fi
  275. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  276. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  277.  
  278. cmchar "Italic Russian letter yo (looks like e umlaut)";
  279. beginchar(oct"033",8u#,asc_height#,0);
  280. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  281. adjust_fit(0,0); pickup fine.nib; h:=x_height;
  282. numeric heavy_hair; heavy_hair=hround .2[hair,stem];
  283. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  284. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  285. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  286. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  287. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  288. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  289. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  290.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  291. umlaut(2,q);
  292. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  293. penlabels(0,1,2,3,4,5,6); endchar;
  294.  
  295. %cmchar "Italic letter v";
  296. %beginchar(oct"034",9.5u#,x_height#,0);
  297. %italcorr x_height#*slant;
  298. %adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  299. %x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  300. %hook_in(0,1,2)(skewed);  % opening hook
  301. %pos2'(stem,-180); z2'=z2; pos4(vair,-90); pos5(hair,0);
  302. %x4=5u; rt x5r=hround(w-2u); y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  303. %filldraw stroke z2'e{-u,-x_height}...super_arc.e(3,4)
  304. % ..tension atleast 1.05..{up}z5e; % left stem and arc
  305. %w:=10u; v_bulb(5,6);  % closing bulb
  306. %math_fit(-2/3x_height#*slant+.5hair#+.5u#,2/3ic#);
  307. %penlabels(0,1,2,3,4,5,6); endchar;
  308.  
  309. cmchar "Italic Old Russian letter izhitsa (looks like v)";
  310. beginchar(oct"034",9u#,x_height#,0);
  311. italcorr x_height#*slant+.25u#;
  312. adjust_fit(serif_fit#,serif_fit#);
  313. numeric left_stem,right_stem,outer_jut,alpha;
  314. left_stem=stem-stem_corr;
  315. right_stem=min(hair if hefty:-2stem_corr fi,left_stem);
  316. outer_jut=.75jut; x1l=w-x4r-1.125u=l+letter_fit+outer_jut+.25u; y1=y4+.1h=h;
  317. x2-x1=x4-x3; x2l+apex_corr=x3l; y2=y3=-apex_o;
  318. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  319. penpos1(alpha*left_stem,0); penpos2(alpha*left_stem,0);
  320. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  321. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  322. x5=x4+1.125u; top y5r=h+oo; penpos5(hair,90); 
  323. rt x6r=hround(w-.5u-.5); y6+.5flare=.95h; penpos6(hair,0);
  324. penpos7(flare,0); if serifs: bulb(5,6,7); fi
  325. if y0>notch_cut: y0:=notch_cut;
  326.   fill z0+.5right{up}...{z4-z3}z4l...{right}z5r--z5l{left}
  327.     ...z4r{z3-z4}...z3r...z3l--diag_end(2l,1l,1,1,1r,2r){z2-z1}
  328.     ...{down}z0+.5left--cycle; % left and right diagonals
  329. else: fill z0--z4l{z4-z3}...{right}z5r--z5l{left}...{z3-z4}z4r--z3r{-10,-1}...{-10,1}z3l
  330.     --diag_end(2l,1l,1,1,1r,0)--cycle; fi % left and right diagonals
  331. if serifs: numeric inner_jut; pickup tiny.nib;
  332.  prime_points_inside(1,2); prime_points_inside(4,3);
  333.  if rt x1'r+jut+.5u+1<=lft x4'l-jut: inner_jut=jut;
  334.  else: rt x1'r+inner_jut+.5u+1=lft x4'l-inner_jut; fi
  335.  dish_serif(1',2,a,1/3,.3outer_jut,b,1/2,.3inner_jut);  % left serif
  336. fi % dish_serif(4',3,c,.6,inner_jut,d,1/2,outer_jut)(dark); fi  % right serif
  337. math_fit(.75u#-height#*slant,ic#-4u#); penlabels(0,1,2,3,4); endchar;
  338.  
  339. cmchar "Italic Old Russian letter fita (looks like theta)";
  340. beginchar(oct"035",10u#,x_height#,0);
  341. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  342. adjust_fit(u#,0); pickup fine.nib; w:=9u;
  343. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  344. x1=x3=.5w; lft x2r=hround(2.5u-.5curve); x4=w-x2;
  345. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  346. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  347.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  348. w:=10u; x31=0; x32=w-hround u; y31=y32=y2;
  349. pos31(bar,90); pos32(bar,90); filldraw circ_stroke z31e--z32e;
  350. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  351.  
  352. cmchar "Italic Macedonian letter zelo (looks like s)";
  353. beginchar(oct"036",5.25u#+max(1.75u#,flare#),x_height#,0);
  354. italcorr x_height#*slant-.5u#;
  355. adjust_fit(0,0); pickup fine.nib;
  356. numeric theta; theta=90-angle(40u,h); slope:=-h/40u;  % angle at middle
  357. pos2(vair,-90); pos0(max(fine.breadth,ess),theta); pos7(vair,-90);
  358. x2l=x0=x7=.5w; top y2l=h+oo; bot y7r=-oo;
  359. y0-.5ess=y7l+.55(y2r-y7l-ess);
  360. lft x3l=hround u-eps; rt x6r=hround(w-.5u)+eps;
  361. x3r-x3l=x6r-x6l=hround .5[vair,ess]-fine;
  362. ellipse_set(2l,3l,4l,0l); ellipse_set(2r,3r,4r,0r); y3=y3r;
  363. ellipse_set(7l,6l,5l,0l); ellipse_set(7r,6r,5r,0r); y6=y6r;
  364. interim superness:=more_super;
  365. filldraw stroke super_arc.e(2,3) & z3e{down}
  366.  ..z4e---z5e..z6e{down} & super_arc.e(6,7);  % main stroke
  367. pos1(hair,0); pos10(hround .75[hair,flare],0);
  368. pos2'(vair,90); z2'=z2;
  369. pos8(hair,-180); pos9(flare,-180);
  370. rt x10r=hround(w-u)+2eps; lft x9r=hround .5u-2eps; y10=.78h; y9=.25h;
  371. bulb(2',1,10); bulb(7,8,9);  % bulbs
  372. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  373.  
  374. cmchar "Italic Russian letter ya (looks like small backward R)";
  375. beginchar(oct"037",9u#,x_height#,0);
  376. italcorr x_height#*slant;
  377. adjust_fit(0,0); pickup fine.nib; slantswitch;
  378. x0=.25u; top y0r=h; x2-.5stem=hround(2.5u-.5stem); %hook_in(0,1,2);
  379. y2=y0; pos2(stem,0); x11=x2; pos0(vair,90);
  380. y11-.5stem=-oo; pos11(stem,0);
  381. filldraw circ_stroke z11e--z2e;  % left stem
  382. pos3(vair,90); x3=x11; y3=bar_height;
  383. x4=x2; rt x16r=hround(w-1.5u+.4curve); x17=.5[x4,x16]; z15=z3;
  384. %x15=x17; bot y15r=bar_height; 
  385. top y17r=h; y4=y16=.5[y15,y17];
  386. pos4(hair,-180); pos15(vair,-90); pos16(curve,0); pos17(vair,90);
  387. filldraw circ_stroke z0e--z17e;
  388. %filldraw stroke super_arc.e(4,15) & pulled_arc.e(15,16)
  389. filldraw stroke pulled_arc.e(15,16) & pulled_arc.e(16,17) & super_arc.e(17,4);
  390. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  391. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  392. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  393. filldraw stroke z3e{right}...z7e{down}
  394.  ...z8e{right}...{up}z9e;  % lower diagonal
  395. mirror(.5w);
  396. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  397. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  398. % this one /w hook-in is pretty ugly
  399. %cmchar "Italic letter ya";
  400. %beginchar(oct"037",9u#,x_height#,0);
  401. %italcorr x_height#*slant;
  402. %adjust_fit(0,0); pickup fine.nib; slantswitch;
  403. %x0=.25u; top y0r=h; x2-.5stem=hround(2.5u-.5stem); %hook_in(0,1,2);
  404. %y2=y0; pos2(stem,0); x11=x2;
  405. %y11-.5stem=-oo; pos11(stem,0);
  406. %filldraw circ_stroke z11e--z2e;  % left stem
  407. %filldraw circ_stroke z0e--z17e;
  408. %pos3(vair,90); x3=x11; y3=bar_height;
  409. %x4=x2; rt x16r=hround(w-1.5u+.4curve); x17=.5[x4,x16]; z15=z3;
  410. %%x15=x17; bot y15r=bar_height; 
  411. %top y17r=h; y4=y16=.5[y15,y17];
  412. %pos4(hair,-180); pos15(vair,-90); pos16(curve,0); pos17(vair,90);
  413. %%filldraw stroke super_arc.e(4,15) & pulled_arc.e(15,16)
  414. %filldraw stroke pulled_arc.e(15,16) & pulled_arc.e(16,17) & super_arc.e(17,4);
  415. %pos7(stem,0); pos8(vair,90); pos9(hair,180);
  416. %x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  417. %lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  418. %filldraw stroke z3e{right}...z7e{down}
  419. % ...z8e{right}...{up}z9e;  % lower diagonal
  420. %mirror(.5w);
  421. %math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  422. %penlabels(1,2,3,4,5,6,7,8,9); endchar;
  423.  
  424. boolean modernyat; modernyat=false;
  425. % the modern yat is a modified slanted version of yat in upright font
  426. % the real italic yat is completely different
  427. % I wouldn't even know the real one existed were it not for Dimitri Vulis
  428. iff modernyat:
  429.   cmchar "Italic Old Russian letter yat";
  430.   beginchar(oct"053",8u#,asc_height#,0);
  431.   italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  432.   adjust_fit(1.75u#,0); pickup tiny.nib;
  433.   pos1(stem,0); pos2(stem,0); x1=x2;
  434.   lft x1l=hround(1.5u-.5stem); top y1=h; y2=.5x_height;
  435.   filldraw stroke z1e--z2e;  % stem
  436.   sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  437.   pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  438.   pos4(curve,0); pos5(vair,90); pos0(hair,180);
  439.   z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  440.   bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  441.   filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  442.    & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  443.   x31=-1.25u; x32=2x1-x31; y31=y32=.5[y5,y1];
  444.   pos31(bar,90); pos32(bar,90); filldraw stroke z31e--z32e;
  445.   penlabels(0,1,2,3,4,5,31,32); endchar;
  446. iff not modernyat:
  447.   cmchar "Italic Old Russian letter yat";
  448.   beginchar(oct"053",12u#,x_height#,0);
  449.   italcorr 1/3x_height#*slant+.5hair#+.5u#;
  450.   adjust_fit(0,0); pickup fine.nib; w:=10u;
  451.   x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  452.   hook_in(0,a,1);  % opening hook
  453.   filldraw circ_stroke z2e--z1e;  % left stem
  454.   x4+.5stem=hround(w-2.5u+.5stem); x5=x4; ital_arch(2,3,4);  % arch
  455.   y5=.5bar_height; pos5(stem,0);
  456.   filldraw stroke z4e{down}..z5e;  % right stem
  457.   w:=12u;
  458.   x23=x25=.5[x5,x24]; rt x24r=hround(w-u+.5curve);
  459.   bot y23r=-oo; top y25r=1.2bar_height+oo; y24=y5; z7'=z5; pos7'(stem,-180);
  460.   z20=z5; pos20(hair,180); pos23(vair,-90); pos24(curve,0); pos25(vair,90);
  461.   filldraw stroke pulled_arc.e(7',23) & pulled_arc.e(23,24)
  462.    & pulled_arc.e(24,25) & super_arc.e(25,20);  % bowl
  463.   math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  464.   endchar;
  465.  
  466. cmchar "Italic letter dotless i";
  467. beginchar("=",5u#,min(asc_height#,10/7x_height#+.5flare#),0);
  468. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  469. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  470. x0=0; x5=w; x2=.5w+.25u; x3=.5w-.25u;
  471. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  472. filldraw stroke z2e--z3e;  % stem
  473. pos8(flare,0); pos9(flare,90);
  474. x8=.5w if not monospace:-.4(h-x_height)*slant fi; top y9r=h+1;
  475. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  476. x8=x9; y8=.5[y9l,y9r]; % dot(8,9);  % no dot
  477. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  478. penlabels(0,1,2,3,4,5,8,9); endchar;
  479.  
  480. cmchar "Italic Russian letter a";
  481. beginchar("a",9u#,x_height#,0);
  482. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  483. adjust_fit(0,0); pickup fine.nib;
  484. pos0(hair,0); pos1(vair,90); pos2(curve,180); pos3(vair,270);
  485. pos4(stem,0); x4=x0; y4+.5stem=vround .98h;
  486. x1=x3=.5[x0,x2]; lft x2r=hround(1.5u-.5curve);
  487. rt x4r=hround(w-2.5u+.5stem);
  488. top y1r=h+oo; bot y3r=-oo; y0=y2=.5[y1,y3];
  489. filldraw stroke super_arc.e(0,1) & pulled_arc.e(1,2)
  490.  & pulled_arc.e(2,3) & super_arc.e(3,0);  % bowl
  491. x5=x4; x7=w; hook_out(5,6,7);  % closing hook
  492. filldraw circ_stroke z4e--z5e;  % stem
  493. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  494. penlabels(0,1,2,3,4,5,6,7); endchar;
  495.  
  496. cmchar "Italic Russian letter be";
  497. beginchar("b",8u#,asc_height#,0);
  498. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  499. adjust_fit(0,0); pickup tiny.nib;
  500. pos50(stem,-90); x50=.5w; y50=.95h; x100=w-u; y100=h; pos100(hair,0);
  501. pos1(hair,0); pos2(stem,0); x1=x2+.5u; pos52(hair,0);
  502. lft x1l=hround(1.5u-.5stem); top y1=1.2x_height; y2=.5x_height;
  503. x52l=x2l; y52=y2;
  504. filldraw stroke z100e...{left}z50e & pulled_arc.e(50,1) & z1e...{down}z52e;  % stem
  505. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  506. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  507. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-1.5u+.5curve);
  508. bot y3r=-oo; top y5r=x_height+oo; y4=y2;
  509. z72=z2; pos72(stem,180);
  510. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  511.  & pulled_arc.e(4,5) & super_arc.e(5,72); %(5,0);  % bowl
  512. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  513. penlabels(0,1,2,3,4,5); endchar;
  514.  
  515. cmchar "Italic Russian letter tse";
  516. beginchar("c",9.5u#,x_height#,desc_depth#);
  517. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  518. adjust_fit(0,.75u#); pickup fine.nib; interim superness:=more_super;
  519. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  520. hook_in(0,1,2)(skewed);  % opening hook
  521. pos2'(stem,-180); z2'=z2;
  522. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  523. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  524. x5=x6=x7; %x9=w; hook_out(7,8,9);  % closing hook
  525. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  526. filldraw stroke z2'e{-u,-x_height}
  527.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  528. pos7(stem,0);
  529. x9=w; y9=y8=.4bar_height; x8=x6; pos8(hair,0); pos9(hair,180);
  530. y7=y8;
  531. filldraw circ_stroke z6e--z7e;  % right stem
  532. filldraw circ_stroke z7e{down}...{up}z9e;
  533. pickup crisp.nib;
  534. y10=0; x10=x9-.1u; y12=-d; x12=x9-.75u; z11=.5[z10,z12]; 
  535. pos10(hair,90); pos11(1.25stem,135);
  536. filldraw stroke z9{down}...z10e...z11e--z12;
  537. penlabels(0,1,2,3,4,5,6,7,8,9,10,11); endchar;
  538.  
  539. cmchar "Italic Russian letter de";
  540. beginchar("d",9u#,asc_height#,0);
  541. italcorr .7asc_height#*slant+.5curve#-1.5u#;
  542. adjust_fit(0,0);
  543. numeric top_thickness,bot_thickness,side_thickness,pull;
  544. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  545. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  546. side_thickness=max(fine.breadth,hround 1/4[curve,cap_curve]);
  547. pull=min(.25,1.5superpull);
  548. pickup fine.nib; pos2(top_thickness,90);
  549. pos3(side_thickness,0); pos4(bot_thickness,-90);
  550. pos5(side_thickness,-180); pos6(vair,-270);
  551. lft x5r=w-rt x3r=hround max(.75u,1.5u-.5side_thickness);
  552. x4=x6+.1u=x2+3.5u=.5w;
  553. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  554. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  555. path p; p=pulled_super_arc.l(3,4)(pull);
  556. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  557. pos7(thin_join,0); z7l=point t of p;
  558. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  559. filldraw stroke pulled_super_arc.e(2,3)(pull)
  560.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  561.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  562.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  563. %pos1(hair,180); pos0(flare,180);
  564. %lft x0r=min(lft x2-eps,hround 1.2u);
  565. %y0=vround min(.85h-.5flare,.8h+.5flare)+o;
  566. %{{less_tense; bulb(2,1,0)}};  % arc and bulb
  567. math_fit(-.3x_height#*slant+.5curve#-u#,ic#-u#);
  568. penlabels(0,1,2,3,4,5,6,7); endchar;
  569.  
  570. cmchar "Italic Russian letter e";
  571. beginchar("e",8u#,x_height#,0);
  572. italcorr max(1/3x_height#*slant,x_height#*slant+.5(.2[hair#,stem#])-u#);
  573. adjust_fit(0,0); pickup fine.nib;
  574. numeric heavy_hair; heavy_hair=hround .2[hair,stem];
  575. pos0(vair,-90); pos1(heavy_hair,0); pos2(vair,90);
  576. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  577. x0=rt x3l; rt x1r=hround(w-1.5u+.5heavy_hair); x2=x4=.5(w+u);
  578. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  579. y0=y3=y6=bar_height; y1=.5[y0,y2]; top y2r=h+oo; bot y4r=-oo;
  580. top y5l=vround .5bar_height; path p; p=z4{right}..z5..z6;
  581. filldraw stroke z0e{right}...z1e{up}...pulled_arc.e(2,3)
  582.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  583. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  584. penlabels(0,1,2,3,4,5,6); endchar;
  585.  
  586. cmchar "Italic Russian letter ef (looks like phi)";
  587. beginchar("f",max(1.5u#,stem#)+max(3.5u#,2flare#),asc_height#,asc_height#-x_height#);
  588. italcorr asc_height#*slant+.75u#;
  589. adjust_fit(if monospace:3u#,3u# else: 2.5u#,2.5u# fi); pickup fine.nib;
  590. numeric theta; z88=(.5w-.5u,h); z89=(.5w+.5u,-d); theta=angle(z88-z89);
  591. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  592. pos3(.5[hair,stem],180); pos4(stem,theta+90);
  593. pos5(stem,theta-90); pos6(.5[hair,stem],0);
  594. pos7(vair,-90); pos8(hair,-180); pos9(flare,-180);
  595. rt x1r=hround(w+.25u); lft x8r=hround-.35u; x2=.6[x1,x4]; x7=.6[x8,x5];
  596. y9-.5flare=vround -.85d; y2-y0=y9-y7; top y2r=h+oo; bot y7r=-d-oo;
  597. y4=.25[x_height,h]; y5=.5[-d,y4];
  598. z4=whatever[z88,z89]; z5=whatever[z88,z89];
  599. x3=.8[x2+x4-x88,x88]; x6=.8[x7+x5-x89,x89]; y3=.8[y4,y2]; y6=.8[y5,y7];
  600. bulb(2,1,0); bulb(7,8,9);  % bulbs
  601. filldraw stroke z2e{left}...z3e...{z89-z88}z4e;  % upper arc
  602. filldraw z4r--z5l--z5r--z4l--cycle;  % stem
  603. filldraw stroke z5e{z89-z88}...z6e...{left}z7e;  % lower arc
  604. pickup crisp.nib; pos20(bar,90); pos21(bar,90);
  605. top y20r=top y21r=x_height;
  606. lft x20=lft x4r-.5stem-u; rt x21=rt x4l+.5stem+1.5u;
  607. %filldraw stroke z20e--z21e;  %  crossbar
  608. x100=x5; y100=y102=.5[y101,y103]; top y101r=x_height+oo; bot y103r=-oo;
  609. x101=x103=.5[x102,x100]; x102=x100-4u; pos100(hair,0); pos101(vair,90);
  610. pos102(curve,180); pos103(vair,270);
  611. filldraw stroke super_arc.e(100,101) & pulled_arc.e(101,102) 
  612.  & pulled_arc.e(102,103) & super_arc.e(103,100);
  613. y201=y101; y202=y102; y203=y103; x201-x100=x100-x101; x202-x100=x100-x102; 
  614. x203-x100=x100-x103; pos201(vair,-90); pos202(curve,-180); pos203(vair,-270);
  615. filldraw stroke super_arc.e(100,201) & pulled_arc.e(201,202) 
  616.  & pulled_arc.e(202,203) & super_arc.e(203,100);
  617. math_fit(desc_depth#*slant+u#,x_height#*slant);
  618. penlabels(0,1,2,3,4,5,6,7,8,9,20,21,88,89); endchar;
  619.  
  620. cmchar "Italic Russian letter ghe";
  621. beginchar("g",7u#,x_height#,0);
  622. italcorr max(1/3x_height#*slant+.5hair#+.5u#,h#*slant+.5flare#-2u#);
  623. adjust_fit(if monospace:u#,u# else: 0,0 fi); pickup fine.nib;
  624. x0=0; x5=w; x2=.5w+1.5u; x3=.5w-1.5u;
  625. hook_in(0,1,2)(skewed); hook_out(3,4,5)(skewed);  % hooks
  626. filldraw stroke z2e{down}...{down}z3e;  % stem
  627. penlabels(0,1,2,3,4,5,8,9); endchar;
  628.  
  629. cmchar "Italic Russian letter kha (looks like x)";
  630. beginchar("h",6.5u#+max(1.5u#,flare#),x_height#,0);
  631. italcorr max(1/3x_height#*slant+.5hair#+.5u#,x_height#*slant+.25u#);
  632. adjust_fit(0,0); pickup fine.nib;
  633. pos0(hair,180); pos1(vair,90); pos2(stem,0);
  634. pos3(stem,-180); pos4(vair,-90); pos5(hair,0);
  635. y0=y2=2/3h; y3=y5=1/3h; top y1r=h+oo; bot y4r=-oo;
  636. rt x2r=hround(.5w+.5stem-eps); x2=x3;
  637. x0-.5hair=hround-.5hair; x5+.5hair=hround(w+.5hair-eps);
  638. x1=.5[x0,x2]; x4=.5[x3,x5];
  639. filldraw stroke z0e{up}...pulled_arc.e(1,2); % opening hook
  640. filldraw z2l--z3r--z3l--z2r--cycle;  % stem
  641. filldraw stroke pulled_arc.e(3,4)...{up}z5e;  % closing hook
  642. pos3'(hair,180); pos6(hair,180); pos7(vair,90);
  643. pos8(hair,0); pos9(flare,0);
  644. x3'l=x6l=x3l; y3'=y3; y6=3/4h; x7=.5[x8,x2]; top y7r=h+oo;
  645. rt x8r=hround(w-.25u); y8+.5flare=vround(bot y7l-.03x_height);
  646. filldraw stroke z3'e---z6e...{right}z7e; bulb(7,8,9);  % upper link and bulb
  647. pos2'(hair,0); pos16(hair,0); pos17(vair,-90);
  648. pos18(hair,-180); pos19(flare,-180);
  649. x2'l=x16l=x2l; y2'=y2; y16=1/4h; x17=.5[x18,x3]; bot y17r=-oo;
  650. lft x18r=hround.25u; y18-.5flare=vround(top y17l+.03x_height);
  651. filldraw stroke z2'e---z16e...{left}z17e; bulb(17,18,19); % lower link and bulb
  652. math_fit(0,ic#); penlabels(0,1,2,3,4,5,6,7,8,9,16,17,18,19); endchar;
  653.  
  654. cmchar "Italic Russian letter i (looks like u)";
  655. beginchar("i",9.5u#,x_height#,0);
  656. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  657. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  658. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  659. hook_in(0,1,2)(skewed);  % opening hook
  660. pos2'(stem,-180); z2'=z2;
  661. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  662. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  663. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  664. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  665. filldraw stroke z2'e{-u,-x_height}
  666.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  667. filldraw circ_stroke z6e--z7e;  % right stem
  668. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  669. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  670.  
  671. cmchar "Italic Serbian letter je";
  672. beginchar("j",5u#,min(asc_height#,10/7x_height#+.5flare#),desc_depth#);
  673. italcorr h#*slant+.5stem#-u#;
  674. adjust_fit(if monospace:2u#,.5u# else: 0,0 fi); pickup fine.nib;
  675. x0=0; x2=x3; pos3(stem,0); lft x3l=hround(w-1.5u-.5stem);
  676. hook_in(0,1,2);  % opening hook
  677. pos4(vair,-90); pos5(hair,-180); pos6(flare,-180);
  678. bot y3=-1/3d; bot y4r=-d-oo; y6-.5flare=-vround.9d;
  679. x4=1/3(w-u); lft x5r=min(hround-.5u,lft x5r+x4-x5l-eps);
  680. filldraw stroke z2e---z3e...{left}z4e;  % stem and arc
  681. bulb(4,5,6);  % bulb
  682. pos8(flare,0); pos9(flare,90);
  683. rt x8r=rt x2r if not monospace:-.6(h-x_height)*slant fi; top y9r=h+1;
  684. if bot y9l-top y1<slab: y9l:=min(y9r-eps,y1+fine+slab); fi
  685. x8=x9; y8=.5[y9l,y9r]; dot(8,9);  % dot
  686. math_fit(desc_depth#*slant,x_height#*slant+.5stem#-u#);
  687. penlabels(0,1,2,3,4,5,6,8,9); endchar;
  688.  
  689. cmchar "Italic Russian letter ka";
  690. beginchar("k",9u#,x_height#,0);
  691. italcorr x_height#*slant;
  692. adjust_fit(0,0); pickup fine.nib;
  693. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);
  694. z2'=z2;
  695. pos2'(stem,0); x11=x2';
  696. y11-.5stem=-oo; pos11(stem,0);
  697. filldraw circ_stroke z11e--z2'e;  % left stem
  698. pos3(vair,90); x3=x11; y3=bar_height;
  699. pos4(vair,90); x4=w-2u; top y4r=x_height+oo;
  700. filldraw stroke z3e{right}..{right}z4e;  % upper diagonal
  701. pos5(hair,0); pos6(flare,0);
  702. rt x5r=hround(w-.5u); y5+.5flare=vround(bot y4l-.03x_height);
  703. bulb(4,5,6);  % bulb
  704. pos7(stem,0); pos8(vair,90); pos9(hair,180);
  705. x9+.5hair=hround(w+.5hair-eps); y9=1/3x_height;
  706. lft x7l=hround(w-2.75u-.5stem); y7=1/2y3; x8=w-1.2u; bot y8l=-oo;
  707. filldraw stroke z3e{right}...z7e{down}
  708.  ...z8e{right}...{up}z9e;  % lower diagonal
  709. math_fit(0,1/3x_height#*slant+.5hair#+.5u#);
  710. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  711.  
  712.  
  713. cmchar "Italic Russian letter el";
  714. beginchar("l",9u#,x_height#,0);
  715. adjust_fit(.5u#,.5u#); pickup fine.nib;
  716. y1+.375stem=h; x1=.5[x3,x1']; x2=x3=3u; y3=.35h; y2=.75h; bot y4r=-oo; y1'=.8h; x1'l=w-2u;
  717. x4=.5[x6,x3]; y6-.5flare=.1h; pos6(flare,-180); pos5(hair,-180); lft x6r=-.25u; z5r=z6r;
  718. pos4(vair,-90); pos2(hair,0); pos3(hair,0); pos1(.75stem,-90); 
  719. x7=x1'; pos1'(stem,180); %pos7(stem,0); %hook_out provides pos7 statement
  720. z11=z1'; pos11(stem,0);
  721. bulb(4,5,6); 
  722. filldraw stroke pulled_arc.e(4,3) &  super_arc.e(3,1) & super_arc.e(1,1');
  723. %filldraw stroke pulled_arc.e(4,3) & z3e..z2e{up}...{right}z1e;
  724. x9=w;
  725. hook_out(7,8,9);
  726. filldraw stroke z11e..z7e;
  727. endchar;
  728.  
  729. cmchar "Italic Russian letter em";
  730. beginchar("m",13u#,x_height#,0);
  731. adjust_fit(.5u#,.5u#); pickup fine.nib;
  732. x3=3u; y3=.35h; bot y4r=-oo; x7r=w-2u;
  733. x4=.5[x6,x3]; y6-.5flare=.1h; pos6(flare,-180); pos5(hair,-180); lft x6r=-.25u; z5r=z6r;
  734. pos4(vair,-90); pos3(hair,0);  
  735. bulb(4,5,6); 
  736. x9=w;
  737. hook_out(7,8,9);
  738. pos1'(hair,0); x1'l=x1l; y1'=y1=h;
  739. x1l=x3; bot y10l=-oo; x10l=.48[x1,x7]; bot y11l=-oo; x11l=x10l; x13=x7; x12=x13l; y12r=y13=h;
  740. pos1(stem,0); pos11(hair,90); pos12(hair,90); pos13(stem,0); pos10(stem,angle(z12-z11)); 
  741. filldraw stroke pulled_arc.e(4,3) & z3e--z1'e;
  742. filldraw stroke z1e--z10e; filldraw stroke z11e--z12e;
  743. filldraw stroke z13e--z7e;
  744. endchar;
  745.  
  746. cmchar "Italic Russian letter en (looks like h)";
  747. beginchar("n",10u#,x_height#,desc_depth#);
  748. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  749. adjust_fit(0,.25u#); pickup fine.nib; 
  750. x0=0; x2=x3; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  751. hook_in(0,1,2);  % opening hook
  752. y3-.5stem=-oo; z2'=z2; pos2'(stem,-180); filldraw circ_stroke z3e--z2'e;
  753. x10=x3l; y10=y11=.55h; pos10(hair,90); pos11(hair,90);
  754. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem); y6+.5stem=h;
  755. x7=x6; x9=w; hook_out(7,8,9);  z7'=z7; pos7'(stem,0);
  756. filldraw circ_stroke z6e--z7'e; x11=x6l; filldraw stroke z10e{1,1}...{1,1}z11e;
  757. endchar;
  758.  
  759. cmchar "Italic Russian letter o";
  760. beginchar("o",9u#,x_height#,0);
  761. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  762. adjust_fit(0,0); pickup fine.nib;
  763. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  764. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2;
  765. top y1r=h+oo; y2=y4=.5[y1,y3]; bot y3r=-oo;
  766. filldraw stroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  767.  & pulled_arc.e(3,4) & pulled_arc.e(4,1); % bowl
  768. math_fit(-.3x_height#*slant+.5curve#-u#,ic#); penlabels(1,2,3,4); endchar;
  769.  
  770. cmchar "Italic Russian letter pe (looks like pi)";
  771. beginchar("p",10u#,x_height#,0);
  772. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  773. adjust_fit(0,0); pickup fine.nib;
  774. x0=0; x1=x2; pos2(stem,0); lft x2l=hround(2.5u-.5stem); y2-.5stem=-oo;
  775. hook_in(0,a,1);  % opening hook
  776. filldraw circ_stroke z2e--z1e;  % left stem
  777. x4+.5stem=hround(w-2.5u+.5stem); x5=x4-.25u; ital_arch(2,3,4);  % arch
  778. x7=w; hook_out(5,6,7)(skewed);  % closing hook
  779. filldraw stroke z4e{down}..{-u,-x_height}z5e;  % right stem
  780. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  781. penlabels(0,a,1,2,3,4,5,6,7); endchar;
  782.  
  783. cmchar "Italic Russian letter che";
  784. beginchar("q",9.5u#,x_height#,0);
  785. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  786. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  787. x0=0; x2=x3; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  788. hook_in(0,1,2)(skewed);  % opening hook
  789. pos2'(stem,-180); z2'=z2;
  790. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  791. pos6(stem,0); rt x6r=hround(w-2.5u+.5stem);
  792. x5=x6=x7; x9=w; hook_out(7,8,9);  % closing hook
  793. y3=.7[y4,y5]; bot y4r=.75bar_height; y5=.75h; y6+.5stem=h;
  794. filldraw stroke z2'e...super_arc.e(3,4)...{up}z5e; % left stem and arc
  795. filldraw circ_stroke z6e--z7e;  % right stem
  796. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  797. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  798.  
  799. cmchar "Italic Russian letter er (looks like p)";
  800. beginchar("r",9u#,x_height#,desc_depth#);
  801. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  802. adjust_fit(0,0); pickup fine.nib;
  803. x0=0; x2-.5stem=hround(2.5u-.5stem); hook_in(0,1,2);  % opening hook
  804. pos4(hair,-180); pos5(vair,-90); pos6(curve,0); pos7(vair,90);
  805. x4=x2; rt x6r=hround(w-1.5u+.5curve); x5=x7=.5[x4,x6];
  806. bot y5r=-oo; top y7r=h+oo; y4=y6=.5[y5,y7];
  807. filldraw stroke super_arc.e(4,5) & pulled_arc.e(5,6)
  808.  & pulled_arc.e(6,7) & super_arc.e(7,4);  % bowl
  809. pickup tiny.nib; pos2'(stem,0); pos3(stem,0);
  810. z2=z2'; x3=x2; bot y3=-d; filldraw stroke z2'e--z3e;  % stem
  811. dish_serif(3,2',a,1/3,.75jut,b,1/3,jut);  % serif
  812. math_fit(-min(2/3x_height#*slant-.5hair#-.5u#,
  813.  2u#-.5stem#-desc_depth#*slant),ic#);
  814. penlabels(0,1,2,3,4,5,6,7); endchar;
  815.  
  816. cmchar "Italic Russian letter es (looks like c)";
  817. beginchar("s",8u#,x_height#,0);
  818. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  819. adjust_fit(0,0); pickup fine.nib;
  820. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  821. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  822. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  823. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  824. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  825. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  826. path p; p=z4{right}..z5..z6;
  827. filldraw stroke pulled_arc.e(2,3)
  828.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  829. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  830. penlabels(0,1,2,3,4,5,6); endchar;
  831.  
  832. cmchar "Italic Russian letter te (looks like m)";
  833. beginchar("t",15u#,x_height#,0);
  834. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  835. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  836. numeric shaved_stem; shaved_stem=mfudged.stem;
  837. save stem; stem=shaved_stem;
  838. pos2(stem,0); x1=x2;
  839. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  840. else: x0=0; lft x2l=hround(2.5u-.5stem);
  841.  hook_in(0,a,1); fi  % opening hook
  842. y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
  843. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  844. pos5(stem,0); y5=y2; x5=x4;
  845. filldraw circ_stroke z5e--z4e;  % middle stem
  846. x7+.5stem=hround(w-2.5u+.5stem);
  847. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  848. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  849.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  850. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  851. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  852. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  853. penlabels(0,a,1,2,3,4,5,6,7,8,9); endchar;
  854.  
  855. cmchar "Italic Russian letter u (looks like y)";
  856. beginchar("u",8.5u#,x_height#,desc_depth#);
  857. italcorr x_height#*slant+.5stem#-u#;
  858. adjust_fit(0,0); pickup fine.nib; interim superness:=more_super;
  859. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  860. hook_in(0,1,2)(skewed);  % opening hook
  861. pos2'(stem,-180); z2'=z2;
  862. pos4(vair,-90); pos5(hair,0); x4=.5[x3,x5];
  863. pos6(stem,0); rt x6r=hround(w-1.5u+.5stem);
  864. pos7(stem,0); pos8(vair,-90);
  865. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h; y6+.5stem=h;
  866. y7=0; bot y8r=-d-oo; x5=x6=x7; x8=.5w;
  867. pos9(hair,-180); pos10(flare,-180); y9=-.5d;
  868. lft x9r=hround(2.75u-.5flare); bulb(8,9,10);  % bulb
  869. filldraw stroke z2'e{-u,-x_height}
  870.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  871. filldraw circ_stroke z6e---z7e...{left}z8e;  % right stem and link
  872. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#-1/3x_height#*slant);
  873. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  874.  
  875. cmchar "Italic Russian letter ve (looks like B)";
  876. beginchar("v",9u#,x_height#,0);
  877. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  878. adjust_fit(0,.5u#); pickup fine.nib;
  879. pos1(vair,90); pos2(curve,180); pos3(vair,270); pos4(curve,360);
  880. x1=x3=.5w; lft x2r=hround(1.5u-.5curve); x4=w-x2; x5=x4+.5u;
  881. top y1r=h+oo; y2=.5[y1,y3]-u; bot y3r=-oo; y4=.65h; y5=.28h; y7=y6; y6=y2+u;
  882. x6=x4-2.5u; x7=x2l; pos5(curve,360); pos6(hair,90); z6'=z6; pos6'(hair,-90);
  883. pos7(hair,90);
  884. filldraw stroke pulled_arc.e(6',4) & pulled_arc.e(4,1) & pulled_arc.e(1,2) & pulled_arc.e(2,3)
  885.  & pulled_arc.e(3,5) & pulled_arc.e(5,6); % bowl
  886. filldraw stroke z7e--z6e;
  887. penlabels(1,2,3,4,5,6); endchar;
  888.  
  889. cmchar "Italic Russian letter shcha";
  890. beginchar("w",12u#,x_height#,desc_depth#);
  891. italcorr x_height#*slant;
  892. adjust_fit(if monospace:-1.5u#,-u# else: 0,2.5u# fi);
  893. pickup fine.nib; interim superness:=more_super; begingroup
  894. forsuffixes $=hair,stem: shaved$:=mfudged$; save $; $=shaved$; endfor
  895. x0=0; x2=x3+.25u; pos3(stem,-180); lft x3r=hround(2.5u-.5stem);
  896. if monospace: pos1(vair,90); x1=good.x .5[x0,x2]; top y1r=h; y2=2/3h;
  897.  pos2(stem,0); filldraw stroke z1e{right}...{-u,-x_height}z2e;
  898. else: hook_in(0,1,2)(skewed); fi  % opening hook
  899. pos2'(stem,-180); z2'=z2;
  900. pos4(vair,-90); pos5(hair,0);
  901. x4=.6[x2,x5]; x5=x6=x7; pos6(stem,-180); pos7(stem,-180);
  902. y3=.7[y4,y5]; bot y4r=-oo; y5=.57h;
  903. rt x6l=hround(rt x6l+.5w+.75u-x6); y6+.5stem=h; y7=y3;
  904. pos8(vair,-90); pos9(hair,0);
  905. x8=w-2.75u; rt x9r=hround(w-.5u); bot y8r=-oo; y9=y5;
  906. filldraw stroke z2'e{-u,-x_height}
  907.  ...super_arc.e(3,4)...{up}z5e; % left stem and arc
  908. filldraw circ_stroke z6e..super_arc.e(7,8)...{up}z9e;  % middle stem and arc
  909. %v_bulb(9,10);  % closing bulb
  910. pos26(stem,0); x26=x27=x9; y26+.5stem=h; y27=y28=y29=.4bar_height;
  911. pos27(stem,0); filldraw circ_stroke z26e--z27e;
  912. x29=r-.5u; x28=x26; pos28(hair,0); pos29(hair,180);
  913. filldraw circ_stroke z27e{down}...{up}z29e;
  914. pickup crisp.nib;
  915. %y30=0; x30=.5[x28,x29]; y32=-d; x32=x26-u; z31=.5[z30,z32]; 
  916. y30=0; x30=x29-.1u; y32=-d; x32=x29-.75u; z31=.5[z30,z32]; 
  917. pos30(hair,90); pos31(1.25stem,135);
  918. filldraw stroke z29{down}...z30e...z31e--z32;
  919. endgroup;
  920. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  921.  
  922. cmchar "Italic Russian letter sha";
  923. beginchar("x",15u#,x_height#,0);
  924. italcorr 1/3x_height#*slant+.5hair#+.5u#;
  925. adjust_fit(if monospace:-1.5u#,-2u# else: 0,0 fi); pickup fine.nib;
  926. numeric shaved_stem; shaved_stem=mfudged.stem;
  927. save stem; stem=shaved_stem;
  928. pos2(stem,0); x1=x2;
  929. if monospace: pos1(stem,0); lft x1l=hround(2.5u-.5stem); top y1=h;
  930. else: x0=0; lft x2l=hround(2.5u-.5stem);
  931.  hook_in(0,a,1); fi  % opening hook
  932. y2-.5stem=-oo; filldraw circ_stroke z2e--z1e;  % left stem
  933. x4+.5stem=hround(.5w+.5stem); ital_arch(2,3,4);  % left arch
  934. pos5(stem,0); y5=y2; x5=x4;
  935. filldraw circ_stroke z5e--z4e;  % middle stem
  936. x7+.5stem=hround(w-2.5u+.5stem);
  937. x8=x7-.25u; ital_arch(5,6,7);  % right arch
  938. if monospace: pos9(vair,90); x9=good.x .5[x8,w]; bot y9l=0; y8=1/3h;
  939.  pos8(stem,0); filldraw stroke z8e{-u,-x_height}...{right}z9e; % terminal
  940. else: x9=w; hook_out(8,b,9)(skewed); fi  % closing hook
  941. filldraw stroke z7e{down}..{-u,-x_height}z8e;  % right stem
  942. x77=.5w; y77=.5h; flip(77);
  943. math_fit(-2/3x_height#*slant+.5hair#+.5u#,ic#);
  944. endchar;
  945.  
  946. cmchar "Italic Russian letter ery";
  947. beginchar("y",11u#,x_height#,0);
  948. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  949. adjust_fit(u#,0); pickup tiny.nib; w:=6u;
  950. pos1(stem,0); pos2(stem,0); x1=x2;
  951. lft x1l=hround(u-.5stem); top y1=h; y2=.6bar_height;
  952. filldraw stroke z1e--z2e;  % stem
  953. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  954. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  955. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  956. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-u+.5curve);
  957. bot y3r=-oo; top y5r=1.2bar_height+oo; y4=y2;
  958. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  959.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  960. w:=11u;
  961. y11=y1; x11=x1+6.5u; x12=x11; pos11(stem,0); x14=w-.5u;
  962. hook_out(12,13,14);
  963. sloped_serif.l(11,12,b,1/3,jut,serif_drop);  % serif
  964. filldraw stroke z11e--z12e;
  965. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  966. penlabels(0,1,2,3,4,5); endchar;
  967.  
  968. cmchar "Italic Russian letter ze (looks like reversed epsilon)";
  969. beginchar("z",7u#,x_height#,0);
  970. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  971. adjust_fit(0,0); pickup fine.nib; w:=8u;
  972. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  973. pos33(curve,180); pos34(curve,180); pos4(vair,270); pos5(hair,320);
  974. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  975. lft x33r=hround(1.5u-.5curve); x5r=good.x(w-u-eps); x6=x5; x34=x33;
  976. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  977. bot y4r=-oo; y33=.25[y2,y4]; y34=.7[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  978. x3=x2; y3=.5[y2,y4]; pos3(hair,270); z3'=z3; pos3'(hair,90);
  979. path p; p=z4{right}..z5..z6;
  980. filldraw stroke pulled_arc.e(2,33) & pulled_arc.e(33,3);
  981. filldraw stroke pulled_arc.e(3',34) & pulled_arc.e(34,4)...{direction 1 of p}z5e;  % arc
  982. x77=x4-.5u; y77=.5h; flip(77);
  983. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  984. endchar;
  985.  
  986. cmchar "Italic Russian letter soft sign";
  987. beginchar(oct"176",6u#,x_height#,0);
  988. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  989. adjust_fit(u#,0); pickup tiny.nib; 
  990. pos1(stem,0); pos2(stem,0); x1=x2;
  991. lft x1l=hround(u-.5stem); top y1=h; y2=.6bar_height;
  992. filldraw stroke z1e--z2e;  % stem
  993. sloped_serif.l(1,2,a,1/3,jut,serif_drop);  % serif
  994. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  995. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  996. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-u+.5curve);
  997. bot y3r=-oo; top y5r=1.2bar_height+oo; y4=y2;
  998. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  999.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  1000. math_fit(-.3x_height#*slant+.5curve#-u#,ic#);
  1001. endchar;
  1002.  
  1003. cmchar "Italic lowercase hard sign";
  1004. beginchar(oct"177",6u#,x_height#,0);
  1005. italcorr .7x_height#*slant+.5curve#-u# if math_fitting:-.5u# fi;
  1006. adjust_fit(u#,0); pickup tiny.nib; 
  1007. pos1(hair,0); pos1'(hair,-45); pos2(stem,0); rt x1r=hround(w-u);
  1008. x1'=x1-.25u; y1'=y1-.75u;
  1009. lft x2l=hround(u-.5stem); top y1=h; y2=.6bar_height;
  1010. filldraw stroke z2e{up}...{3,1}z1'e..z1e;  % stem
  1011. pos100(hair,180); pos101(.6[hair,curve],60); pos102(hair,90);
  1012. z102r=z1r; x100=lft x2l-.5u; y100=.675[y2,y1]; x101=.385[x100,x102];
  1013. top y101r=top y102r;
  1014. filldraw stroke z100e{up}...{5,-1}z101e...{1,1}z102e; % fillip
  1015. pickup fine.nib; pos2'(stem,-180); pos3(vair,-90);
  1016. pos4(curve,0); pos5(vair,90); pos0(hair,180);
  1017. z0=z2=z2'; x3=x5=.5[x2,x4]; rt x4r=hround(w-u+.5curve);
  1018. bot y3r=-oo; top y5r=1.2bar_height+oo; y4=y2;
  1019. filldraw stroke pulled_arc.e(2',3) & pulled_arc.e(3,4)
  1020.  & pulled_arc.e(4,5) & super_arc.e(5,0);  % bowl
  1021. endchar;
  1022.  
  1023. endinput;                    %%%%%%%%%%%%%%%%%%%%
  1024.  
  1025. cmchar "Italic Russian letter zhe (alternate to oct"031");
  1026. beginchar(oct"226",19u#,x_height#,0);
  1027. italcorr if math_fitting:1/3x_height#*slant else:x_height#*slant-u# fi;
  1028. adjust_fit(0,0); pickup fine.nib;
  1029. w:=8u;
  1030. pos0(flare,0); pos1(hair,0); pos2(vair,90);
  1031. pos3(curve,180); pos4(vair,270); pos5(hair,320);
  1032. x2=x4=.5(w+u); rt x1r=max(rt x2,hround(w-u))+eps;
  1033. lft x3r=hround(1.5u-.5curve); x5r=good.x(w-eps); x6=x5;
  1034. y1=.5[bar_height,h]; top y2r=h+oo; bulb(2,1,0);  % bulb
  1035. bot y4r=-oo; y3=.5[y2,y4]; top y5l=vround .5bar_height; y6=bar_height;
  1036. path p; p=z4{right}..z5..z6;
  1037. filldraw stroke pulled_arc.e(2,3)
  1038.  & pulled_arc.e(3,4)...{direction 1 of p}z5e;  % arc
  1039. x77=x4; y77=.5h; x78=2x77-x3; %y78=2y77-y3;
  1040. y78=bar_height;
  1041. flip(77); w:=19u;
  1042. pos50(flare,0); pos51(hair,0); pos52(vair,90);
  1043. pos53(curve,180); pos54(vair,270); pos55(hair,320);
  1044. x52=x54=w-3.5u; rt x51r=max(rt x52,hround(w-u))+eps;
  1045. lft x53r=hround(w-6.5u-.5curve); x55r=good.x(w-eps); x56=x55;
  1046. y51=.5[bar_height,h]; top y52r=h+oo; bulb(52,51,50);  % bulb
  1047. bot y54r=-oo; y53=.5[y52,y54]; top y55l=vround .5bar_height; y56=bar_height;
  1048. path p; p=z54{right}..z55..z56;
  1049. filldraw stroke pulled_arc.e(52,53)
  1050.  & pulled_arc.e(53,54)...{direction 1 of p}z55e;  % arc
  1051. x80=x81=.5[x78,x53]; y80=h; y81=0; y79=y78; x79=x53;
  1052. pos78(hair,90); pos79(hair,90); pos80(stem,0); pos81(stem,0);
  1053. filldraw stroke z78e--z79e; filldraw stroke z80e--z81e;
  1054. %addto currentpicture also V shifted(10u,0);
  1055. endchar;
  1056.