home *** CD-ROM | disk | FTP | other *** search
/ DOS/V Power Report 1997 November / VPR9711A.ISO / VPR_DATA / Special / movemn8s / movemn8s.lzh / RIGHT2.MAC < prev    next >
Text File  |  1997-03-06  |  3KB  |  153 lines
  1. //  右寄せマクロ2 ver.8.00
  2. //  (折り返し文字数分右寄せ・改行なし）
  3. //  by ＪＲくん(GFB03426)  97.3.7
  4.  
  5.     if (readonly) {
  6.         message "右寄せ２：「上書き禁止」なので実行を中止します。";
  7.         endmacro;
  8.     }
  9.     if (browsemode) {
  10.         message "右寄せ２：「閲覧モード」なので実行を中止します。";
  11.         endmacro;
  12.     }
  13.  
  14.     $b=searchbuffer;
  15.     #s=searchoption;
  16.  
  17.     $space80 = "                                                                               ";
  18.  
  19. //  ワードラップ使用時には警告
  20.     if ( kinsokustate ) {
  21.         if ( getininum("hidemaru.ini","Env","Wordwrap") == 1 ) {
  22.         question "右寄せ２：\n"
  23.                + "現在この秀丸はワードラップ機能を使用していますが、\n"
  24.                + "このまま処理を続けると、レイアウトが崩れたり、\n"
  25.                + "行の最後が２文字程度欠落したりする場合があります。\n"
  26.                + "\nこのまま処理を続けますか？";
  27.         if ( result == no ) endmacro;
  28.         }
  29.     }
  30.  
  31.     disableinvert;
  32.  
  33. //  処理範囲を取得
  34.  
  35.     if ((selecting) || (rectselecting)) {
  36.         #y2 = seltopy;
  37.         #y1 = selendy;
  38.         if (selendx == 0) #y1 = #y1 - 1;
  39.         escape;
  40.     } else {
  41.         #y1 = y;
  42.         #y2 = y;
  43.     }
  44.  
  45. //  １行分の文字列を処理するルーチン
  46. OneLineLoop:
  47.     moveto 0, #y1;
  48.  
  49. //  （EOF対策）
  50.     #IsEof = ( #y1 == linecount - 1 );
  51.  
  52. //  その行の開始x座標を取得
  53.  
  54.     #xstart = 0;
  55.     #Code = code;
  56.     if (#Code == 0x0d) {
  57.         //  改行だけだった場合
  58.         goto OneLineEnd;
  59.     } else if ((#Code == 0x20) || (#Code == 0x8140)
  60.         || (#Code == 0)    || (#Code == 0x09))  {
  61.         //  半角/全角スペース・ヌル文字・タブ
  62.         searchdown "[^ 　\t]",regular;
  63.         if ((y > #y1) || (code == 0x0d) || (code == eof)) {
  64.             //  その行すべてがスペース等だった場合
  65.             goto AllChrDel;
  66.         } else {
  67.             #xstart = x;
  68.         }
  69.     }
  70.  
  71. //  終了x座標を取得
  72.  
  73.     golineend;
  74.     #Code = code;
  75.     if ((#Code == 0x20) || (#Code == 0x8140) || (#Code == 0)
  76.       + (#Code == 0x09) || (#Code == 0x0d)   || (#Code == eof))  {
  77.         //  半角/全角スペース・ヌル文字・タブ・改行・EOFの場合
  78.         searchup "[^ 　\t]",regular;
  79.     }
  80.     right;
  81.     #xend = x;
  82.     #yend = y;
  83.  
  84.  
  85. //  タブ処理
  86.     moveto 0, #y1;
  87.     beginsel;
  88.     golineend;
  89.     tospace;
  90.     escape;
  91.  
  92. //  カット後の文字列を取得
  93.     $tcutted = gettext(#xstart, #y1, #xend, #yend);
  94.  
  95.  
  96. //  左側のスペースを計算
  97.     #len = strlen($tcutted);
  98.     #space = width - #len;    //  右寄せ2
  99.  
  100.  
  101.     $space = "";
  102.     if (#space > 0) {
  103.  
  104.         #sp1 = #space / 80;
  105.         #sp2 = #space % 80;
  106.  
  107.         while (#sp1 > 0) {
  108.             $space = $space + $space80;
  109.             #sp1 = #sp1 - 1;
  110.         }
  111.         $space = $space + leftstr($space80, #sp2);
  112.     }
  113.  
  114.     moveto 0, #y1;
  115.  
  116. //  前行末に半角分の空きがある場合には改行を追加挿入するための下準備
  117.     $preface = "";
  118.     if (column != 0) {
  119.         up;
  120.         if (linelen < width) $preface = "\n";
  121.         down;
  122.     }
  123.  
  124. //  文字列挿入処理
  125.     beginsel;
  126.     if (#IsEof) golineend;
  127.            else down;
  128.     insert $preface + $space + $tcutted;
  129.  
  130.     goto OneLineEnd;
  131.  
  132. //  その行すべてがスペース等の場合は、改行と置き換える、または削除
  133.     AllChrDel:
  134.     moveto 0, #y1;
  135.     beginsel;
  136.     if (#IsEof) {
  137.         golineend;
  138.         delete;
  139.     } else {
  140.         down;
  141.         insert "\n";
  142.     }
  143.  
  144. //  ループ
  145.     OneLineEnd:
  146.     #y1 = #y1 - 1;
  147.     if (#y1 >= #y2) goto OneLineLoop;
  148.  
  149. //  終了処理
  150.     setsearch $b,#s;
  151.     enableinvert;
  152.     endmacro;
  153.